CCI Four Arrows

ÿþ//+------------------------------------------------------------------+

//|                                              CCI Four Arrows.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                      https://www.mql5.com/en/users/barabashkakvn |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/en/users/barabashkakvn"

#property version   "1.000"

#property indicator_chart_window

#property indicator_buffers 5

#property indicator_plots   4

//--- plot InMinus100

#property indicator_label1  "InMinus100"

#property indicator_type1   DRAW_ARROW

#property indicator_color1  clrYellowGreen

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot OutMinus100

#property indicator_label2  "OutMinus100"

#property indicator_type2   DRAW_ARROW

#property indicator_color2  clrBlue

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- plot InPlus100

#property indicator_label3  "InPlus100"

#property indicator_type3   DRAW_ARROW

#property indicator_color3  clrYellowGreen

#property indicator_style3  STYLE_SOLID

#property indicator_width3  1

//--- plot OutPlus100

#property indicator_label4  "OutPlus100"

#property indicator_type4   DRAW_ARROW

#property indicator_color4  clrRed

#property indicator_style4  STYLE_SOLID

#property indicator_width4  1

//--- input parameters

input group             "CCI"

input int                  Inp_CCI_ma_period             = 7;              // CCI: averaging period

input ENUM_APPLIED_PRICE   Inp_CCI_applied_price         = PRICE_TYPICAL;  // CCI: type of price

input group             "Levels"

input double               InpCCILevelUp                 = 100;            // CCI Level Up (100)

input double               InpCCILevelDown               = -100;           // CCI Level Down (-100)

input group             "Arrows"

input uchar                Inp_InMinus100_Code           = 248;            // InMinus100: symbol code from the Wingdings font

input uchar                Inp_OutMinus100_Code          = 246;            // OutMinus100: symbol code from the Wingdings font

input uchar                Inp_InPlus100_Code            = 246;            // InPlus100: symbol code from the Wingdings font

input uchar                Inp_OutPlus100_Code           = 248;            // OutPlus100: symbol code from the Wingdings font

input int                  Inp_Shift                     = 10;             // Vertical shift of arrows in pixels

//--- indicator buffers

double   InMinus100Buffer[];

double   OutMinus100Buffer[];

double   InPlus100Buffer[];

double   OutPlus100Buffer[];

double   CCIBuffer[];

//---

int      handle_iCCI;               // variable for storing the handle of the iCCI indicator

int      bars_calculated   = 0;     // we will keep the number of values in the Commodity Channel Index indicator

bool     m_init_error      = false; // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,InMinus100Buffer,INDICATOR_DATA);

   SetIndexBuffer(1,OutMinus100Buffer,INDICATOR_DATA);

   SetIndexBuffer(2,InPlus100Buffer,INDICATOR_DATA);

   SetIndexBuffer(3,OutPlus100Buffer,INDICATOR_DATA);

   SetIndexBuffer(4,CCIBuffer,INDICATOR_CALCULATIONS);

//--- set accuracy

   IndicatorSetInteger(INDICATOR_DIGITS,Digits());

//--- define the symbol code for drawing in PLOT_ARROW

   PlotIndexSetInteger(0,PLOT_ARROW,Inp_InMinus100_Code);

   PlotIndexSetInteger(1,PLOT_ARROW,Inp_OutMinus100_Code);

   PlotIndexSetInteger(2,PLOT_ARROW,Inp_InPlus100_Code);

   PlotIndexSetInteger(3,PLOT_ARROW,Inp_OutPlus100_Code);

//--- set the vertical shift of arrows in pixels

   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,Inp_Shift);

   PlotIndexSetInteger(1,PLOT_ARROW_SHIFT,Inp_Shift);

   PlotIndexSetInteger(2,PLOT_ARROW_SHIFT,-Inp_Shift);

   PlotIndexSetInteger(3,PLOT_ARROW_SHIFT,-Inp_Shift);

//--- set as an empty value 0

   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(2,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(3,PLOT_EMPTY_VALUE,0.0);

//--- create handle of the indicator iCCI

   handle_iCCI=iCCI(Symbol(),Period(),Inp_CCI_ma_period,PRICE_TYPICAL);

//--- if the handle is not created

   if(handle_iCCI==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iCCI indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(m_init_error)

      return(0);

//--- number of values copied from the iCCI indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iCCI);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iCCI indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the CCI array is greater than the number of values in the iCCI indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the CCI array with values of the Commodity Channel Index indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(CCIBuffer,handle_iCCI,values_to_copy))

      return(0);

//--- main loop

   int limit=rates_total-values_to_copy;

   for(int i=limit; i<rates_total; i++)

     {

      InMinus100Buffer[i]  = 0.0;

      OutMinus100Buffer[i] = 0.0;

      InPlus100Buffer[i]   = 0.0;

      OutPlus100Buffer[i]  = 0.0;

      //---

      if(i>0)

        {

         //--- InMinus100

         if(CCIBuffer[i-1]>InpCCILevelDown && CCIBuffer[i]<InpCCILevelDown)

           {

            InMinus100Buffer[i]=low[i];

            continue;

           }

         //--- OutMinus100

         if(CCIBuffer[i-1]<InpCCILevelDown && CCIBuffer[i]>InpCCILevelDown)

           {

            OutMinus100Buffer[i]=low[i];

            continue;

           }

         //--- InPlus100

         if(CCIBuffer[i-1]<InpCCILevelUp && CCIBuffer[i]>InpCCILevelUp)

           {

            InPlus100Buffer[i]=high[i];

            continue;

           }

         //--- OutPlus100

         if(CCIBuffer[i-1]>InpCCILevelUp && CCIBuffer[i]<InpCCILevelUp)

            OutPlus100Buffer[i]=high[i];

        }

     }

//--- memorize the number of values in the Commodity Channel Index indicator

   bars_calculated=calculated;

//--- return the prev_calculated value for the next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iCCI indicator                |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],  // indicator buffer of Commodity Channel Index values

                         int ind_handle,    // handle of the iCCI indicator

                         int amount         // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the CCI array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iCCI indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iCCI!=INVALID_HANDLE)

      IndicatorRelease(handle_iCCI);

  }

//+------------------------------------------------------------------+