CCI Level Filling

ÿþ//+------------------------------------------------------------------+

//|                                            CCI Level Filling.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                      https://www.mql5.com/en/users/barabashkakvn |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/en/users/barabashkakvn"

#property version   "1.001"

#property indicator_separate_window

#property indicator_buffers 5

#property indicator_plots   3

//--- plot CCI

#property indicator_label1  "CCI"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrLightSeaGreen

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot CCI Filling Up

#property indicator_label2  "CCI Filling Up"

#property indicator_type2   DRAW_FILLING

#property indicator_color2  clrDeepSkyBlue,clrNONE

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- plot CCI Filling Dn

#property indicator_label3  "CCI Filling Dn"

#property indicator_type3   DRAW_FILLING

#property indicator_color3  clrTomato,clrNONE

#property indicator_style3  STYLE_SOLID

#property indicator_width3  1

//--- input parameters

input group             "CCI"

input int                  Inp_CCI_ma_period             = 14;             // CCI: averaging period

input ENUM_APPLIED_PRICE   Inp_CCI_applied_price         = PRICE_TYPICAL;  // CCI: type of price

input group             "Levels"

input double               InpCCILevelUp                 = 100;            // CCI Level Up (100)

input double               InpCCILevelDown               = -100;           // CCI Level Down (-100)

//--- indicator buffers

double   CCIBuffer[];

double   CCIFillingUpBuffer1[];

double   CCIFillingUpBuffer2[];

double   CCIFillingDnBuffer1[];

double   CCIFillingDnBuffer2[];

//---

int      handle_iCCI;               // variable for storing the handle of the iCCI indicator

int      bars_calculated   = 0;     // we will keep the number of values in the Commodity Channel Index indicator

bool     m_init_error      = false; // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,CCIBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,CCIFillingUpBuffer1,INDICATOR_DATA);

   SetIndexBuffer(2,CCIFillingUpBuffer2,INDICATOR_DATA);

   SetIndexBuffer(3,CCIFillingDnBuffer1,INDICATOR_DATA);

   SetIndexBuffer(4,CCIFillingDnBuffer2,INDICATOR_DATA);

//--- set levels

   IndicatorSetInteger(INDICATOR_LEVELS,2);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,0,InpCCILevelUp);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,1,InpCCILevelDown);

//--- indicator name

   IndicatorSetString(INDICATOR_SHORTNAME,"CCI Level Filling("+IntegerToString(Inp_CCI_ma_period)+","+StringSubstr(EnumToString(Inp_CCI_applied_price),6,-1)+")");

//--- indexes draw begin settings

   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,Inp_CCI_ma_period-1);

   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,Inp_CCI_ma_period-1);

   PlotIndexSetInteger(2,PLOT_DRAW_BEGIN,Inp_CCI_ma_period-1);

//--- number of digits of indicator value

   IndicatorSetInteger(INDICATOR_DIGITS,2);

//--- create handle of the indicator iCCI

   handle_iCCI=iCCI(Symbol(),Period(),Inp_CCI_ma_period,PRICE_TYPICAL);

//--- if the handle is not created

   if(handle_iCCI==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iCCI indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(m_init_error)

      return(0);

//--- number of values copied from the iCCI indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iCCI);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iCCI indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the CCI array is greater than the number of values in the iCCI indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the CCI array with values of the Commodity Channel Index indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(CCIBuffer,handle_iCCI,values_to_copy))

      return(0);

//--- main loop

   int limit=rates_total-values_to_copy;

   for(int i=limit; i<rates_total; i++)

     {

      CCIFillingUpBuffer1[i]=CCIBuffer[i];

      CCIFillingUpBuffer2[i]=InpCCILevelUp;

      CCIFillingDnBuffer1[i]=InpCCILevelDown;

      CCIFillingDnBuffer2[i]=CCIBuffer[i];

     }

//--- memorize the number of values in the Commodity Channel Index indicator

   bars_calculated=calculated;

//--- return the prev_calculated value for the next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iCCI indicator                |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],  // indicator buffer of Commodity Channel Index values

                         int ind_handle,    // handle of the iCCI indicator

                         int amount         // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the CCI array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iCCI indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iCCI!=INVALID_HANDLE)

      IndicatorRelease(handle_iCCI);

  }

//+------------------------------------------------------------------+