RSI Four Colors

ÿþ//+------------------------------------------------------------------+

//|                                              RSI Four Colors.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43161 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43161"

#property version   "1.000"

#property indicator_separate_window

#property indicator_buffers 4

#property indicator_plots   2

//--- plot RSI

#property indicator_label1  "RSI"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrDodgerBlue

#property indicator_style1  STYLE_SOLID

#property indicator_width1  2

//--- plot RSI Color

#property indicator_label2  "RSI Color"

#property indicator_type2   DRAW_COLOR_HISTOGRAM2

#property indicator_color2  clrSilver,clrRed,clrBlue,clrOrange,clrYellow

#property indicator_style2  STYLE_SOLID

#property indicator_width2  3

//--- input parameters

input group             "RSI"

input int                  Inp_RSI_ma_period    = 6;           // RSI: averaging period

input ENUM_APPLIED_PRICE   Inp_RSI_applied_price= PRICE_CLOSE; // RSI: type of price

input double               Inp_RSI_LevelUP      = 65;          // RSI: Level UP (default 65)

input double               Inp_RSI_LevelDOWN    = 25;          // RSI: Level DOWN (default 25)

//--- indicator buffers

double   RSIBuffer[];

double   RSIBuffer1[];

double   RSIBuffer2[];

double   RSIBufferColors[];



//---

int      handle_iRSI;                  // variable for storing the handle of the iRSI indicator

int      bars_calculated= 0;           // we will keep the number of values in the Relative Strength Index indicator

bool     m_init_error   = false;       // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,RSIBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,RSIBuffer1,INDICATOR_DATA);

   SetIndexBuffer(2,RSIBuffer2,INDICATOR_DATA);

   SetIndexBuffer(3,RSIBufferColors,INDICATOR_COLOR_INDEX);

//--- set an empty value

   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0.0);

//--- set levels

   IndicatorSetInteger(INDICATOR_LEVELS,2);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,0,Inp_RSI_LevelUP);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,1,Inp_RSI_LevelDOWN);

//--- set accuracy

   IndicatorSetInteger(INDICATOR_DIGITS,2);

//--- sets first bar from what index will be drawn

   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,Inp_RSI_ma_period);

   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,Inp_RSI_ma_period);

//--- sets labels for the line

   PlotIndexSetString(0,PLOT_LABEL,"RSI("+IntegerToString(Inp_RSI_ma_period)+")");

   PlotIndexSetString(1,PLOT_LABEL,"RSI Four Colors("+IntegerToString(Inp_RSI_ma_period)+")");

//--- name for DataWindow and indicator subwindow label

   IndicatorSetString(INDICATOR_SHORTNAME,"RSI Four Colors("+IntegerToString(Inp_RSI_ma_period)+")");

//--- create handle of the indicator iRSI

   handle_iRSI=iRSI(Symbol(),Period(),Inp_RSI_ma_period,Inp_RSI_applied_price);

//--- if the handle is not created

   if(handle_iRSI==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iRSI indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(m_init_error)

      return(0);

//--- number of values copied from the iMACD indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iRSI);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iRSI indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iRSIBuffer array is greater than the number of values in the iRSI indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the array with values of the iRSI indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(RSIBuffer,handle_iRSI,values_to_copy))

      return(0);

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      RSIBuffer1[0]=0.0;

      RSIBuffer2[0]=0.0;

      RSIBufferColors[0]=0.0;

      limit=1;

     }

   for(int i=limit; i<rates_total; i++)

     {

      RSIBuffer1[i]=0.0;

      RSIBuffer2[i]=0.0;

      RSIBufferColors[i]=0.0;

      /*

       'RSI' > previous RSI && 'RSI' < RSI: Level DOWN -> 'Color'=1.0

       'RSI' > previous RSI && 'RSI' > RSI: Level UP   -> 'Color'=2.0

       'RSI' < previous RSI && 'RSI' > RSI: Level UP   -> 'Color'=3.0

       'RSI' < previous RSI && 'RSI' < RSI: Level DOWN -> 'Color'=4.0

      */

      if(RSIBuffer[i]>RSIBuffer[i-1] && RSIBuffer[i]<Inp_RSI_LevelDOWN)

        {

         RSIBuffer1[i]=RSIBuffer[i];

         RSIBuffer2[i]=Inp_RSI_LevelDOWN;

         RSIBufferColors[i]=1.0;

        }

      else

         if(RSIBuffer[i]>RSIBuffer[i-1] && RSIBuffer[i]>Inp_RSI_LevelUP)

           {

            RSIBuffer1[i]=RSIBuffer[i];

            RSIBuffer2[i]=Inp_RSI_LevelUP;

            RSIBufferColors[i]=2.0;

           }

         else

            if(RSIBuffer[i]<RSIBuffer[i-1] && RSIBuffer[i]>Inp_RSI_LevelUP)

              {

               RSIBuffer1[i]=RSIBuffer[i];

               RSIBuffer2[i]=Inp_RSI_LevelUP;

               RSIBufferColors[i]=3.0;

              }

            else

               if(RSIBuffer[i]<RSIBuffer[i-1] && RSIBuffer[i]<Inp_RSI_LevelDOWN)

                 {

                  RSIBuffer1[i]=RSIBuffer[i];

                  RSIBuffer2[i]=Inp_RSI_LevelDOWN;

                  RSIBufferColors[i]=4.0;

                 }

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iRSI indicator                |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &rsi_buffer[],  // indicator buffer of Relative Strength Index values

                         int ind_handle,        // handle of the iRSI indicator

                         int amount             // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iRSIBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,rsi_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iRSI indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iRSI!=INVALID_HANDLE)

      IndicatorRelease(handle_iRSI);

  }

//+------------------------------------------------------------------+