Accelerator Oscillator Reverse ARROW

ÿþ//+------------------------------------------------------------------+

//|                         Accelerator Oscillator Reverse ARROW.mq5 |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.000"

#property indicator_chart_window

#property indicator_buffers 4

#property indicator_plots   2

//--- plot AC

#property indicator_label1  "Reverse Down Up"

#property indicator_type1   DRAW_ARROW

#property indicator_color1  clrBlue

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

#property indicator_label2  "Reverse Up Down"

#property indicator_type2   DRAW_ARROW

#property indicator_color2  clrRed

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- input parameters

//--- Arrows

input uchar    InpSignalCode     = 178;         // Arrow code (font Wingdings)

input int      InpShift          = 10;          // Vertical shift of arrows in pixel

//--- indicator buffers

double   ReverseDownUpBuffer[];

double   ReverseUpDownBuffer[];

double   iACBuffer[];

double   iACColors[];

//---

int      handle_iAC;                            // variable for storing the handle of the iAC indicator

int      bars_calculated   = 0;                 // we will keep the number of values in the Accelerator Oscillator indicator

bool     m_init_error      = false;             // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,ReverseDownUpBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,ReverseUpDownBuffer,INDICATOR_DATA);

   SetIndexBuffer(2,iACBuffer,INDICATOR_CALCULATIONS);

   SetIndexBuffer(3,iACColors,INDICATOR_CALCULATIONS);

//--- setting a code from the Wingdings charset as the property of PLOT_ARROW

   PlotIndexSetInteger(0,PLOT_ARROW,InpSignalCode);

   PlotIndexSetInteger(1,PLOT_ARROW,InpSignalCode);

//--- set the vertical shift of arrows in pixels

   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,InpShift);

   PlotIndexSetInteger(1,PLOT_ARROW_SHIFT,-InpShift);

//--- an empty value for plotting, for which there is no drawing

   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0.0);

//--- create handle of the indicator iAC

   handle_iAC=iAC(Symbol(),Period());

//--- if the handle is not created

   if(handle_iAC==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iAC indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);;

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(m_init_error)

      return(0);

   if(rates_total<40)

      return(0);

//--- number of values copied from the iAC indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iAC);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iAC indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iACBuffer array is greater than the number of values in the iAC indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iACBuffer and iACColors arrays with values from the Accelerator Oscillator indicator

//--- if FillArraysFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArraysFromBuffer(iACBuffer,iACColors,handle_iAC,values_to_copy))

      return(0);

//--- memorize the number of values in the Accelerator Oscillator indicator

   bars_calculated=calculated;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      for(int i=0; i<40; i++)

        {

         ReverseDownUpBuffer[i]=0.0;

         ReverseUpDownBuffer[i]=0.0;

        }

      limit=40;

     }

   for(int i=limit; i<rates_total; i++)

     {

      ReverseDownUpBuffer[i]=0.0;

      if(iACColors[i-1]==1.0 && iACColors[i]==0.0)

         ReverseDownUpBuffer[i]=low[i];

      ReverseUpDownBuffer[i]=0.0;

      if(iACColors[i-1]==0.0 && iACColors[i]==1.0)

         ReverseUpDownBuffer[i]=high[i];

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iAC indicator                 |

//+------------------------------------------------------------------+

bool FillArraysFromBuffer(double &values[],        // indicator buffer of Accelerator Oscillator values

                          double &color_indexes[], // color buffer (for storing of color indexes)

                          int ind_handle,          // handle of the iAC indicator

                          int amount               // number of copied values

                         )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iACBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iAC indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- now copy the indexes of colors

   if(CopyBuffer(ind_handle,1,0,amount,color_indexes)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy color values from the iAC indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iAC!=INVALID_HANDLE)

      IndicatorRelease(handle_iAC);

  }

//+------------------------------------------------------------------+