Accelerator Oscillator and Volumes ARROW

Author: Copyright © 2020, Vladimir Karputov
Indicators Used
Bill Williams Accelerator/Decelerator oscillator
0 Views
0 Downloads
0 Favorites
Accelerator Oscillator and Volumes ARROW
ÿþ//+------------------------------------------------------------------+

//|                     Accelerator Oscillator and Volumes ARROW.mq5 |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.000"

#property indicator_chart_window

#property indicator_buffers 12

#property indicator_plots   4

//--- plot 'AC Up'

#property indicator_label1  "AC Up"

#property indicator_type1   DRAW_COLOR_ARROW

#property indicator_color1  clrLimeGreen,clrRed

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot 'Volumes Up'

#property indicator_label2  "Volumes Up"

#property indicator_type2   DRAW_COLOR_ARROW

#property indicator_color2  clrLimeGreen,clrRed

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- plot 'AC Down'

#property indicator_label3  "AC Down"

#property indicator_type3   DRAW_COLOR_ARROW

#property indicator_color3  clrLimeGreen,clrRed

#property indicator_style3  STYLE_SOLID

#property indicator_width3  1

//--- plot 'Volumes Down'

#property indicator_label4  "Volumes Down"

#property indicator_type4   DRAW_COLOR_ARROW

#property indicator_color4  clrLimeGreen,clrRed

#property indicator_style4  STYLE_SOLID

#property indicator_width4  1

//--- input parameters

//--- iVolumes

input ENUM_APPLIED_VOLUME  Inp_Volumes_applied_volume = VOLUME_TICK; // Volumes: volume type for calculation

//--- Arrows

input uchar    Inp_AC_Code       = 174;         // Arrow code of arrows 'AC'(font Wingdings)

input uchar    Inp_Volumes_Code  = 169;         // Arrow code of arrows 'Volumes'(font Wingdings)

input int      Inp_AC_Shift      = 10;          // Vertical shift of arrows 'AC' in pixel

input int      Inp_Volumes_Shift = 20;          // Vertical shift of arrows 'Volumes' in pixel

//--- indicator buffers

double   ACUpBuffer[];

double   ACUpColors[];

double   VolumesUpBuffer[];

double   VolumesUpColors[];



double   ACDownBuffer[];

double   ACDownColors[];

double   VolumesDownBuffer[];

double   VolumesDownColors[];



double   iACBuffer[];

double   iACColors[];

double   iVolumesBuffer[];

double   iVolumesColors[];

//---

int      handle_iAC;                            // variable for storing the handle of the iAC indicator

int      handle_iVolumes;                       // variable for storing the handle of the iVolumes indicator

int      bars_calculated=0;                     // we will keep the number of values in the Accelerator Oscillator indicator

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,ACUpBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,ACUpColors,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(2,VolumesUpBuffer,INDICATOR_DATA);

   SetIndexBuffer(3,VolumesUpColors,INDICATOR_COLOR_INDEX);



   SetIndexBuffer(4,ACDownBuffer,INDICATOR_DATA);

   SetIndexBuffer(5,ACDownColors,INDICATOR_COLOR_INDEX);;

   SetIndexBuffer(6,VolumesDownBuffer,INDICATOR_DATA);

   SetIndexBuffer(7,VolumesDownColors,INDICATOR_COLOR_INDEX);



   SetIndexBuffer(8,iACBuffer,INDICATOR_CALCULATIONS);

   SetIndexBuffer(9,iACColors,INDICATOR_CALCULATIONS);

   SetIndexBuffer(10,iVolumesBuffer,INDICATOR_CALCULATIONS);

   SetIndexBuffer(11,iVolumesColors,INDICATOR_CALCULATIONS);

//--- setting a code from the Wingdings charset as the property of PLOT_ARROW

   PlotIndexSetInteger(0,PLOT_ARROW,Inp_AC_Code);              // plot 'AC Up'

   PlotIndexSetInteger(1,PLOT_ARROW,Inp_Volumes_Code);         // plot 'Volumes Up'

   PlotIndexSetInteger(2,PLOT_ARROW,Inp_AC_Code);              // plot 'AC Down'

   PlotIndexSetInteger(3,PLOT_ARROW,Inp_Volumes_Code);         // plot 'Volumes Down'

//--- set the vertical shift of arrows in pixels

   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,-Inp_AC_Shift);      // shift 'AC Up'

   PlotIndexSetInteger(1,PLOT_ARROW_SHIFT,-Inp_Volumes_Shift); // shift 'Volumes Up'

   PlotIndexSetInteger(2,PLOT_ARROW_SHIFT,Inp_AC_Shift);       // shift 'AC Down'

   PlotIndexSetInteger(3,PLOT_ARROW_SHIFT,Inp_Volumes_Shift);  // shift 'Volumes Down'

//--- an empty value for plotting, for which there is no drawing

   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0.0);

//--- create handle of the indicator iAC

   handle_iAC=iAC(Symbol(),Period());

//--- if the handle is not created

   if(handle_iAC==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iAC indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//--- create handle of the indicator

   handle_iVolumes=iVolumes(Symbol(),Period(),Inp_Volumes_applied_volume);

//--- if the handle is not created

   if(handle_iVolumes==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iVolumes indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(rates_total<40)

      return(0);

//--- number of values copied from the iAC indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicators

   int calculated_ac=BarsCalculated(handle_iAC);

   if(calculated_ac<=0)

     {

      PrintFormat("BarsCalculated(handle_iAC) returned %d, error code %d",calculated_ac,GetLastError());

      return(0);

     }

   int calculated_volumes=BarsCalculated(handle_iVolumes);

   if(calculated_volumes<=0)

     {

      PrintFormat("BarsCalculated(handle_iVolumes) returned %d, error code %d",calculated_volumes,GetLastError());

      return(0);

     }

   if(calculated_ac!=calculated_volumes)

      return(0);

   int calculated=calculated_ac;

//--- if it is the first start of calculation of the indicator or if the number of values in the iAC indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iACBuffer array is greater than the number of values in the iAC indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iACBuffer and iACColors arrays with values from the Accelerator Oscillator indicator

//--- if FillArraysFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArraysFromBuffer(iACBuffer,iACColors,handle_iAC,values_to_copy))

      return(0);

//--- fill the arrays with values of the iVolumes indicator

//--- if FillArraysFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArraysFromBuffers(iVolumesBuffer,iVolumesColors,handle_iVolumes,values_to_copy))

      return(0);

//--- form the message

//--- memorize the number of values in the Accelerator Oscillator indicator

   bars_calculated=calculated;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      for(int i=0; i<40; i++)

        {

         ACUpBuffer[i]=0.0;

         ACUpColors[i]=0.0;

         ACDownBuffer[i]=0.0;

         ACDownColors[i]=0.0;

        }

      limit = 40;

     }



   for(int i=limit; i<rates_total; i++)

     {

      if(iACBuffer[i]>0.0)

        {

         ACUpBuffer[i]=high[i];

         ACUpColors[i]=iACColors[i];

         VolumesUpBuffer[i]=high[i];

         VolumesUpColors[i]=iVolumesColors[i];



         ACDownBuffer[i]=0.0;

         ACDownColors[i]=0.0;

         VolumesDownBuffer[i]=0.0;

         VolumesDownColors[i]=0.0;

        }

      else

        {

         ACUpBuffer[i]=0.0;

         ACUpColors[i]=0.0;

         VolumesUpBuffer[i]=0.0;

         VolumesUpColors[i]=0.0;



         ACDownBuffer[i]=low[i];

         ACDownColors[i]=iACColors[i];

         VolumesDownBuffer[i]=low[i];

         VolumesDownColors[i]=iVolumesColors[i];

        }

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iAC indicator                 |

//+------------------------------------------------------------------+

bool FillArraysFromBuffer(double &values[],        // indicator buffer of Accelerator Oscillator values

                          double &color_indexes[], // color buffer (for storing of color indexes)

                          int ind_handle,          // handle of the iAC indicator

                          int amount               // number of copied values

                         )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iACBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iAC indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- now copy the indexes of colors

   if(CopyBuffer(ind_handle,1,0,amount,color_indexes)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy color values from the iAC indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iVolumes indicator            |

//+------------------------------------------------------------------+

bool FillArraysFromBuffers(double &volume_buffer[],   // indicator buffer of Volumes values

                           double &color_buffer[],    // indicator buffer of colors

                           int ind_handle,            // handle of the iVolumes indicator

                           int amount                 // number of copied values

                          )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iVolumesBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,volume_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iVolumes indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- fill a part of the iVolumesColors array with values from the indicator buffer that has index 1

   if(CopyBuffer(ind_handle,1,0,amount,color_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iVolumes indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iAC!=INVALID_HANDLE)

      IndicatorRelease(handle_iAC);

   if(handle_iVolumes!=INVALID_HANDLE)

      IndicatorRelease(handle_iVolumes);

  }

//+------------------------------------------------------------------+

Comments

Markdown supported. Formatting help

Markdown Formatting Guide

Element Markdown Syntax
Heading # H1
## H2
### H3
Bold **bold text**
Italic *italicized text*
Link [title](https://www.example.com)
Image ![alt text](image.jpg)
Code `code`
Code Block ```
code block
```
Quote > blockquote
Unordered List - Item 1
- Item 2
Ordered List 1. First item
2. Second item
Horizontal Rule ---