Three TRIX

ÿþ//+------------------------------------------------------------------+

//|                                                   Three TRIX.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.00"

#property indicator_separate_window

#property indicator_buffers 3

#property indicator_plots   3

//--- plot TRIX_0

#property indicator_label1  "TRIX Fast"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrOrange

#property indicator_style1  STYLE_SOLID

#property indicator_width1  3

//--- plot TRIX_1

#property indicator_label2  "TRIX Medium"

#property indicator_type2   DRAW_LINE

#property indicator_color2  clrBlueViolet

#property indicator_style2  STYLE_SOLID

#property indicator_width2  2

//--- plot TRIX_2

#property indicator_label3  "TRIX Slow"

#property indicator_type3   DRAW_LINE

#property indicator_color3  clrLawnGreen

#property indicator_style3  STYLE_SOLID

#property indicator_width3  1

//--- input parameters

input group             "TRIX Fast, Medium, Slow"

input int                  Inp_TriX_Fast_ma_period    = 5;           // TriX Fast: averaging period

input int                  Inp_TriX_Medium_ma_period  = 15;          // TriX Medium: averaging period

input int                  Inp_TriX_Slow_ma_period    = 25;          // TriX Slow: averaging period

input ENUM_APPLIED_PRICE   Inp_TriX_applied_price     = PRICE_CLOSE; // TriX: type of price

//--- indicator buffers

double   TRIX_Fast_Buffer[];

double   TRIX_Medium_Buffer[];

double   TRIX_Slow_Buffer[];

//---

int      handle_iTriX_Fast;   // variable for storing the handle of the iTriX indicator

int      handle_iTriX_Medium; // variable for storing the handle of the iTriX indicator

int      handle_iTriX_Slow;   // variable for storing the handle of the iTriX indicator

int      bars_calculated=0;   // we will keep the number of values in the Triple Exponential Moving Averages Oscillator

bool     m_init_error=false;  // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- forced initialization of variables

   m_init_error               = false;    // error on InInit

//--- indicator buffers mapping

   SetIndexBuffer(0,TRIX_Fast_Buffer,INDICATOR_DATA);

   SetIndexBuffer(1,TRIX_Medium_Buffer,INDICATOR_DATA);

   SetIndexBuffer(2,TRIX_Slow_Buffer,INDICATOR_DATA);

//--- name for indicator label

   IndicatorSetString(INDICATOR_SHORTNAME,"TRIX("+IntegerToString(Inp_TriX_Fast_ma_period)+","+IntegerToString(Inp_TriX_Medium_ma_period)+","+IntegerToString(Inp_TriX_Slow_ma_period)+")");

//--- indicator digits

   IndicatorSetInteger(INDICATOR_DIGITS,5);

//--- create handle of the indicator

   handle_iTriX_Fast=iTriX(Symbol(),Period(),Inp_TriX_Fast_ma_period,Inp_TriX_applied_price);

//--- if the handle is not created

   if(handle_iTriX_Fast==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iTriX indicator ('Fast') for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//--- create handle of the indicator

   handle_iTriX_Medium=iTriX(Symbol(),Period(),Inp_TriX_Medium_ma_period,Inp_TriX_applied_price);

//--- if the handle is not created

   if(handle_iTriX_Medium==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iTriX indicator ('Medium') for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//--- create handle of the indicator

   handle_iTriX_Slow=iTriX(Symbol(),Period(),Inp_TriX_Slow_ma_period,Inp_TriX_applied_price);

//--- if the handle is not created

   if(handle_iTriX_Slow==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iTriX indicator ('Slow') for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(m_init_error)

      return(0);

//--- number of values copied from the iTriX indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iTriX_Fast);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iTriX indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iTriXBuffer array is greater than the number of values in the iTriX indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the array with values from the Triple Exponential Moving Averages Oscillator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(TRIX_Fast_Buffer,handle_iTriX_Fast,values_to_copy))

      return(0);

   if(!FillArrayFromBuffer(TRIX_Medium_Buffer,handle_iTriX_Medium,values_to_copy))

      return(0);

   if(!FillArrayFromBuffer(TRIX_Slow_Buffer,handle_iTriX_Slow,values_to_copy))

      return(0);

//--- memorize the number of values in the Triple Exponential Moving Averages Oscillator

   bars_calculated=calculated;

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iTriX indicator               |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &trix_buffer[], // indicator buffer of values of Triple Exponential Moving Averages Oscillator

                         int ind_handle,        // handle of the iTriX indicator

                         int amount             // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iTriXBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,trix_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iTriX indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iTriX_Fast!=INVALID_HANDLE)

      IndicatorRelease(handle_iTriX_Fast);

   if(handle_iTriX_Medium!=INVALID_HANDLE)

      IndicatorRelease(handle_iTriX_Medium);

   if(handle_iTriX_Slow!=INVALID_HANDLE)

      IndicatorRelease(handle_iTriX_Slow);

  }

//+------------------------------------------------------------------+