MA Color N Bars Force Arrow

ÿþ//+------------------------------------------------------------------+

//|                                  MA Color N Bars Force Arrow.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43161 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43161"

#property version   "1.002"

#property indicator_chart_window

#property indicator_buffers 6

#property indicator_plots   3

//--- plot Force

#property indicator_label1  "Buy stop"

#property indicator_type1   DRAW_ARROW

#property indicator_color1  clrCornflowerBlue

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot Force

#property indicator_label2  "Sell stop"

#property indicator_type2   DRAW_ARROW

#property indicator_color2  clrTomato

#property indicator_style2  STYLE_DASH

#property indicator_width2  1

//--- plot MAColor

#property indicator_label3  "MAColor"

#property indicator_type3   DRAW_COLOR_LINE

#property indicator_color3  clrYellowGreen,clrBlue,clrRed

#property indicator_style3  STYLE_SOLID

#property indicator_width3  2

//--- input parameters

input group             "MA Color N Bars"

input int                  Inp_MA_ma_period           = 12;          // MA: averaging period

input int                  Inp_MA_ma_shift            = 0;           // MA: horizontal shift

input ENUM_MA_METHOD       Inp_MA_ma_method           = MODE_EMA;    // MA: smoothing type

input ENUM_APPLIED_PRICE   Inp_MA_applied_price       = PRICE_CLOSE; // MA: type of price

input uchar                Inp_MA_trend_n_bars        = 3;           // MA: trend N Bars

input group             "Force Index"

input int                  Inp_Force_ma_period        = 2;           // Force: averaging period

input ENUM_MA_METHOD       Inp_Force_ma_method        = MODE_EMA;    // Force: smoothing type

input ENUM_APPLIED_VOLUME  Inp_Force_applied_volume   = VOLUME_TICK; // Force: volume type for calculation

input group             "Arrow Up"

input uchar                InpUpCode                  = 174;         // Arrow Up: code for style DRAW_ARROW (font Wingdings)

input int                  InpUpShift                 = 10;          // Arrow Up: vertical shift of arrows in pixels

input group             "Arrow Down"

input uchar                InpDownCode                = 174;         // Arrow Down: code for style DRAW_ARROW (font Wingdings)

input int                  InpDownShift               = 10;          // Arrow Down: vertical shift of arrows in pixels

//--- indicator buffers

double   BuyStopBuffer[];

double   SellStopBuffer[];

double   MAColorBuffer[];

double   MAColorColors[];

double   iForceBuffer[];

//---

int      handle_iCustom;               // variable for storing the handle of the iCustom indicator

int      handle_iForce;                // variable for storing the handle of the iForce indicator

int      bars_calculated   = 0;        // we will keep the number of values in the Force indicator

bool     m_init_error      = false;    // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,BuyStopBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,SellStopBuffer,INDICATOR_DATA);

   SetIndexBuffer(2,MAColorBuffer,INDICATOR_DATA);

   SetIndexBuffer(3,MAColorColors,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(4,iForceBuffer,INDICATOR_CALCULATIONS);

//--- setting a code from the Wingdings charset as the property of PLOT_ARROW

   PlotIndexSetInteger(0,PLOT_ARROW,InpUpCode);

   PlotIndexSetInteger(1,PLOT_ARROW,InpDownCode);

//--- set the vertical shift of arrows in pixels

   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,-InpUpShift);

   PlotIndexSetInteger(1,PLOT_ARROW_SHIFT,InpDownShift);

//--- set as an empty value 0.0

   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,EMPTY_VALUE);

   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,EMPTY_VALUE);

//--- sets first bar from what index will be drawn

   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,Inp_Force_ma_period);

//--- create handle of the indicator iCustom

   handle_iCustom=iCustom(Symbol(),Period(),"MA Color N Bars",

                          Inp_MA_ma_period,

                          Inp_MA_ma_shift,

                          Inp_MA_ma_method,

                          Inp_MA_applied_price,

                          Inp_MA_trend_n_bars);

//--- if the handle is not created

   if(handle_iCustom==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iCustom indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//--- create handle of the indicator

   handle_iForce=iForce(Symbol(),Period(),Inp_Force_ma_period,Inp_Force_ma_method,Inp_Force_applied_volume);

//--- if the handle is not created

   if(handle_iForce==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iForce indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(m_init_error)

      return(0);

//--- number of values copied from the iForce indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated_custom=BarsCalculated(handle_iCustom);

   if(calculated_custom<=0)

     {

      PrintFormat("BarsCalculated(handle_iCustom) returned %d, error code %d",calculated_custom,GetLastError());

      return(0);

     }

   int calculated_force=BarsCalculated(handle_iForce);

   if(calculated_force<=0)

     {

      PrintFormat("BarsCalculated(handle_iForce) returned %d, error code %d",calculated_force,GetLastError());

      return(0);

     }

   if(calculated_custom!=calculated_force)

     {

      PrintFormat("BarsCalculated(handle_iCustom) returned %d, BarsCalculated(handle_iForce) returned %d",calculated_custom,calculated_force);

      return(0);

     }

   int calculated=calculated_custom;

//--- if it is the first start of calculation of the indicator or if the number of values in the iForce indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iForceBuffer array is greater than the number of values in the iForce indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iMABuffer array with values of the Moving Average indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArraysFromBuffers(MAColorBuffer,MAColorColors,Inp_MA_ma_shift,handle_iCustom,values_to_copy))

      return(0);

//--- fill the iForceBuffer array with values of the Force indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(iForceBuffer,handle_iForce,values_to_copy))

      return(0);

//--- memorize the number of values

   bars_calculated=calculated;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      BuyStopBuffer[0]=EMPTY_VALUE;

      SellStopBuffer[0]=EMPTY_VALUE;

      limit=1;

     }

   for(int i=limit; i<rates_total; i++)

     {

      BuyStopBuffer[i]=EMPTY_VALUE;

      SellStopBuffer[i]=EMPTY_VALUE;

      if(MAColorColors[i]==1.0)

         if(iForceBuffer[i-1]>0.0 && iForceBuffer[i]<0.0)

            BuyStopBuffer[i]=high[i];

      if(MAColorColors[i]==2.0)

         if(iForceBuffer[i-1]<0.0 && iForceBuffer[i]>0.0)

            SellStopBuffer[i]=low[i];

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iMACD indicator               |

//+------------------------------------------------------------------+

bool FillArraysFromBuffers(double &ma_color_buffer[], // indicator buffer

                           double &ma_color_colors[], // color buffer

                           int shift,                 // shift

                           int ind_handle,            // handle of indicator

                           int amount                 // number of copied values

                          )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the MAColorBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,MAColorBuffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the 'MA Color N Bars indicator', error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- fill a part of the MAColorColors array with values from the indicator buffer that has index 1

   if(CopyBuffer(ind_handle,1,0,amount,MAColorColors)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the 'MA Color N Bars indicator' indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iForce indicator              |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],  // indicator buffer of Force Index values

                         int ind_handle,    // handle of the iForce indicator

                         int amount         // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iForceBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iForce indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iCustom!=INVALID_HANDLE)

      IndicatorRelease(handle_iCustom);

   if(handle_iForce!=INVALID_HANDLE)

      IndicatorRelease(handle_iForce);

  }

//+------------------------------------------------------------------+