ATR Histogram Percentages

ÿþ//+------------------------------------------------------------------+

//|                                    ATR Histogram Percentages.mq5 |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.000"

#property indicator_separate_window

#property indicator_buffers 3

#property indicator_plots   1

//--- plot ATR

#property indicator_label1  "ATR"

#property indicator_type1   DRAW_COLOR_HISTOGRAM

#property indicator_color1  clrDeepSkyBlue,clrTomato

#property indicator_style1  STYLE_SOLID

#property indicator_width1  3

//--- input parameters

input group             "ATR"

input int               Inp_ATR_ma_period = 14; // ATR: averaging period

//--- indicator buffers

double   ATRBuffer[];

double   ATRColors[];

double   iATRBuffer[];

//---

int      handle_iATR;                           // variable for storing the handle of the iATR indicator

int      bars_calculated=0;                     // we will keep the number of values in the Average True Range indicator

int      m_start=0;

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,ATRBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,ATRColors,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(2,iATRBuffer,INDICATOR_CALCULATIONS);

//--- set an empty value

   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);

//--- set accuracy

   IndicatorSetInteger(INDICATOR_DIGITS,2);

//--- set maximum and minimum for subwindow

   IndicatorSetDouble(INDICATOR_MINIMUM,0);

//--- name for DataWindow and indicator subwindow label

   string short_name="ATR("+string(Inp_ATR_ma_period)+")";

   IndicatorSetString(INDICATOR_SHORTNAME,short_name);

//--- create handle of the indicator iATR

   handle_iATR=iATR(Symbol(),Period(),Inp_ATR_ma_period);

//--- if the handle is not created

   if(handle_iATR==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iATR indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//---

   m_start=Inp_ATR_ma_period;

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(rates_total<=m_start)

      return(0);

//---

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iATR);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iATR indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iATRBuffer array is greater than the number of values in the iATR indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iATRBuffer array with values of the Average True Range indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(iATRBuffer,handle_iATR,values_to_copy))

      return(0);

//--- memorize the number of values in the Average True Range indicator

   bars_calculated=calculated;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      limit=m_start;

      for(int i=0; i<limit; i++)

        {

         ATRBuffer[i]=0.0;

         ATRColors[i]=0.0;

        }

     }

   for(int i=limit; i<rates_total; i++)

     {

      /*

      iATRBuffer[i-1]   -> 100%

      iATRBuffer[i]     -> x%

      */

      if(iATRBuffer[i-1]!=0)

        {

         ATRBuffer[i]=iATRBuffer[i]*100.0/iATRBuffer[i-1];

         if(ATRBuffer[i]>ATRBuffer[i-1])

            ATRColors[i]=0.0;

         else

            ATRColors[i]=1.0;

        }

      else

        {

         ATRBuffer[i]=0.0;

         ATRColors[i]=0.0;

        }

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iATR indicator                |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],  // indicator buffer for ATR values

                         int ind_handle,    // handle of the iATR indicator

                         int amount         // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iATRBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iATR indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iATR!=INVALID_HANDLE)

      IndicatorRelease(handle_iATR);

  }

//+------------------------------------------------------------------+