TRIX Color

ÿþ//+------------------------------------------------------------------+

//|                                                   TRIX Color.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.002"

#property indicator_separate_window

#property indicator_buffers 4

#property indicator_plots   3

//--- plot TRIX

#property indicator_label1  "TRIX"

#property indicator_type1   DRAW_COLOR_LINE

#property indicator_color1  clrRed,clrYellowGreen

#property indicator_style1  STYLE_SOLID

#property indicator_width1  2

//--- plot BUY

#property indicator_label2  "BUY"

#property indicator_type2   DRAW_ARROW

#property indicator_color2  clrYellowGreen

#property indicator_width2  1

//--- plot SELL

#property indicator_label3  "SELL"

#property indicator_type3   DRAW_ARROW

#property indicator_color3  clrRed

#property indicator_width3  1

//--- input parameters

input group             "TriX"

input int                  Inp_TriX_ma_period      = 9;           // TriX: averaging period

input ENUM_APPLIED_PRICE   Inp_TriX_applied_price  = PRICE_CLOSE; // TriX: type of price

input group             "BUY"

input uchar                InpBuyCode              = 233;         // Arrow code for style DRAW_ARROW (font Wingdings)

input int                  InpBuyShift             = 10;          // Vertical shift of arrows in pixels

input group             "SELL"

input uchar                InpSellCode             = 234;         // Arrow code for style DRAW_ARROW (font Wingdings)

input int                  InpSellShift            = 10;          // Vertical shift of arrows in pixels

//--- indicator buffers

double   TRIXBuffer[];

double   ColorBuffer[];

double   BuyBuffer[];

double   SellBuffer[];

//---

int      handle_iTriX;        // variable for storing the handle of the iTriX indicator

int      bars_calculated=0;   // we will keep the number of values in the Triple Exponential Moving Averages Oscillator

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,TRIXBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,ColorBuffer,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(2,BuyBuffer,INDICATOR_DATA);

   SetIndexBuffer(3,SellBuffer,INDICATOR_DATA);

//--- sets first bar from what index will be drawn

   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,3*Inp_TriX_ma_period-3);

//--- name for indicator label

   IndicatorSetString(INDICATOR_SHORTNAME,"TRIX Color("+IntegerToString(Inp_TriX_ma_period)+")");

//--- indicator digits

   IndicatorSetInteger(INDICATOR_DIGITS,5);

//--- setting a code from the Wingdings charset as the property of PLOT_ARROW

   PlotIndexSetInteger(1,PLOT_ARROW,InpBuyCode);

   PlotIndexSetInteger(2,PLOT_ARROW,InpSellCode);

//--- set the vertical shift of arrows in pixels

   PlotIndexSetInteger(1,PLOT_ARROW_SHIFT,InpBuyShift);

   PlotIndexSetInteger(2,PLOT_ARROW_SHIFT,-InpSellShift);

//--- set as an empty value 0.0

   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,EMPTY_VALUE);

   PlotIndexSetDouble(2,PLOT_EMPTY_VALUE,EMPTY_VALUE);

//--- create handle of the indicator

   handle_iTriX=iTriX(Symbol(),Period(),Inp_TriX_ma_period,Inp_TriX_applied_price);

//--- if the handle is not created

   if(handle_iTriX==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iTriX indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- number of values copied from the iTriX indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iTriX);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iTriX indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iTriXBuffer array is greater than the number of values in the iTriX indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the array with values from the Triple Exponential Moving Averages Oscillator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(TRIXBuffer,handle_iTriX,values_to_copy))

      return(0);

//--- memorize the number of values in the Triple Exponential Moving Averages Oscillator

   bars_calculated=calculated;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      BuyBuffer[0]=0.0;

      SellBuffer[0]=0.0;

      limit=1;

     }

   for(int i=limit; i<rates_total; i++)

     {

      if(TRIXBuffer[i]<0.0)

         ColorBuffer[i]=0.0;

      else

         ColorBuffer[i]=1.0;

      //--- Buy

      if(TRIXBuffer[i-1]<0.0 && TRIXBuffer[i]>0.0)

         BuyBuffer[i]=0.0;

      else

         BuyBuffer[i]=EMPTY_VALUE;

      //--- Sell

      if(TRIXBuffer[i-1]>0.0 && TRIXBuffer[i]<0.0)

         SellBuffer[i]=0.0;

      else

         SellBuffer[i]=EMPTY_VALUE;

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iTriX indicator               |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &trix_buffer[], // indicator buffer of values of Triple Exponential Moving Averages Oscillator

                         int ind_handle,        // handle of the iTriX indicator

                         int amount             // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iTriXBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,trix_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iTriX indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iTriX!=INVALID_HANDLE)

      IndicatorRelease(handle_iTriX);

  }

//+------------------------------------------------------------------+