MA on CHO

ÿþ//+------------------------------------------------------------------+

//|                                                    MA on CHO.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.000"

#property indicator_separate_window

#property indicator_buffers 2

#property indicator_plots   2

//--- plot CHO

#property indicator_label1  "CHO"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrLightSeaGreen

#property indicator_style1  STYLE_SOLID

#property indicator_width1  2

//--- plot MA on CHO

#property indicator_label2  "MA on CHO"

#property indicator_type2   DRAW_LINE

#property indicator_color2  clrYellowGreen

#property indicator_style2  STYLE_SOLID

#property indicator_width2  2

//--- input parameters

input group             "Chaikin Oscillator, CHO"

input int                  Inp_CHO_fast_ma_period  = 3;           // CHO: fast period

input int                  Inp_CHO_slow_ma_period  = 10;          // CHO: slow period

input ENUM_MA_METHOD       Inp_CHO_ma_method       = MODE_EMA;    // CHO: smoothing type

input ENUM_APPLIED_VOLUME  Inp_CHO_applied_volume  = VOLUME_TICK; // CHO: type of volume

input group             "MA"

input int                  Inp_MA_ma_period        = 6;           // MA: averaging period

input ENUM_MA_METHOD       Inp_MA_ma_method        = MODE_EMA;    // MA: smoothing type

//--- indicator buffers

double   CHOBuffer[];

double   MAonCHOBuffer[];

//---

int      handle_iChaikin;                       // variable for storing the handle of the iChaikin indicator

int      handle_iMA;                            // variable for storing the handle of the iMA indicator

int      bars_calculated   = 0;                 // we will keep the number of values in the CHO and MA indicators

bool     m_init_error      = false;             // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,CHOBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,MAonCHOBuffer,INDICATOR_DATA);

//--- set accuracy

   IndicatorSetInteger(INDICATOR_DIGITS,0);

//--- set labels for the line

   PlotIndexSetString(0,PLOT_LABEL,"CHO"+"("+IntegerToString(Inp_CHO_fast_ma_period)+","+IntegerToString(Inp_CHO_slow_ma_period)+")");

   PlotIndexSetString(1,PLOT_LABEL,"MA"+"("+IntegerToString(Inp_MA_ma_period)+")"+" on CHO"+"("+IntegerToString(Inp_CHO_fast_ma_period)+","+IntegerToString(Inp_CHO_slow_ma_period)+")");

//--- create handle of the indicator iChaikin

   handle_iChaikin=iChaikin(Symbol(),Period(),Inp_CHO_fast_ma_period,

                            Inp_CHO_slow_ma_period,Inp_CHO_ma_method,Inp_CHO_applied_volume);

//--- if the handle is not created

   if(handle_iChaikin==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iChaikin indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//--- create handle of the indicator iMA

   handle_iMA=iMA(Symbol(),Period(),Inp_MA_ma_period,0,

                  Inp_MA_ma_method,handle_iChaikin);

//--- if the handle is not created

   if(handle_iMA==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iMA indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_FAILED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(m_init_error)

      return(0);

//--- number of values copied from the iMA indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated_cho=BarsCalculated(handle_iChaikin);

   if(calculated_cho<=0)

     {

      PrintFormat("BarsCalculated(CHO) returned %d, error code %d",calculated_cho,GetLastError());

      return(0);

     }

//--- determine the number of values calculated in the indicator

   int calculated_ma=BarsCalculated(handle_iMA);

   if(calculated_ma<=0)

     {

      PrintFormat("BarsCalculated(MA) returned %d, error code %d",calculated_ma,GetLastError());

      return(0);

     }

   if(calculated_cho!=calculated_ma)

     {

      PrintFormat("BarsCalculated(CHO) returned %d, BarsCalculated(MA) returned %d",calculated_cho,calculated_ma);

      return(0);

     }

   int calculated=calculated_cho;

//--- if it is the first start of calculation of the indicator or if the number of values in the indicator changed

//--- or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iMABuffer array is greater than the number of values in the iMA indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the MAonCHOBuffer array with values of the Moving Average indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBufferMA(MAonCHOBuffer,0,handle_iMA,values_to_copy))

      return(0);

//--- fill the CHOBuffer array with values of the Chaikin Oscillator indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(CHOBuffer,handle_iChaikin,values_to_copy))

      return(0);

//--- memorize the number of values in the Moving Average indicator

   bars_calculated=calculated;

//--- return the prev_calculated value for the next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the MA indicator                  |

//+------------------------------------------------------------------+

bool FillArrayFromBufferMA(double &values[],   // indicator buffer of Moving Average values

                           int shift,          // shift

                           int ind_handle,     // handle of the iMA indicator

                           int amount          // number of copied values

                          )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iMABuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,-shift,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iMA indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iChaikin indicator            |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],  // indicator buffer of Chaikin Oscillator values

                         int ind_handle,    // handle of the iChaikin indicator

                         int amount         // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iChaikinBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iChaikin indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iChaikin!=INVALID_HANDLE)

      IndicatorRelease(handle_iChaikin);

   if(handle_iMA!=INVALID_HANDLE)

      IndicatorRelease(handle_iMA);

  }

//+------------------------------------------------------------------+