OsMA_Divergence_v1
Download scriptThis script is a technical analysis tool designed for the MetaTrader platform. It identifies specific types of market behavior by analyzing the relationship between price movements and a momentum-based indicator known as the OsMA (Oscillator Moving Average).
Core Logic Overview
The primary purpose of this script is to detect Divergences. In trading, a divergence occurs when the price of an asset moves in one direction, but the momentum indicator suggests that the strength behind that move is weakening or changing. This can often serve as an early warning signal for potential trend reversals.
Key Functional Components
1. Indicator Foundation (OsMA)
The script starts by calculating the OsMA. This is a derivative of a moving average oscillator. It provides a smoothed view of market momentum, helping to filter out "noise" and show whether the underlying strength of a move is increasing or decreasing.
2. Peak and Trough Detection
The script scans the OsMA line to identify specific "turning points":
- Peaks: High points where the momentum reaches a local maximum before turning downward.
- Troughs: Low points where the momentum reaches a local minimum before turning upward.
- Sensitivity Filters: It uses specific thresholds (Sensitivity settings) and a "buffer" of bars to ensure that only significant peaks and troughs are registered, rather than every minor fluctuation in the line.
3. Divergence Identification
This is the core intelligence of the script. It compares two consecutive peaks (or troughs) against the actual Highs and Lows of the price chart:
- Bearish Divergence: If the price makes a higher high, but the OsMA indicator makes a lower peak, it suggests that the upward move is losing steam. The script highlights these points to warn of a potential downward turn.
- Bullish Divergence: If the price makes a lower low, but the OsMA indicator makes a higher trough, it suggests that the downward pressure is fading. The script highlights these to hint at a potential upward bounce.
4. Visual Feedback
To make this data easy for a human to read, the script performs several visual actions:
- Signal Arrows: It places specific arrow markers on the chart when a divergence condition is met.
- Trend Lines: It automatically draws connecting lines between the identified peaks and troughs.
- It can draw these lines in the Indicator Window to show momentum trends.
- It can also project these lines onto the Main Price Chart (Price Windows) to visually link the price action with the momentum data.
- Dynamic Coloring: It uses distinct colors (such as Red, Deep Pink, Lime Green, and Yellow-Green) to differentiate between different types of signals and trends.
Summary for the User
Instead of you having to manually compare complex moving averages against price highs and lows, this script automates that math. It constantly "watches" the market for moments where the price is lying—where the visual move on the chart doesn't match the internal momentum of the market—and marks those specific locations with lines and arrows for your review.
//+------------------------------------------------------------------+
//| OsMA_Divergence_v1.mq4 |
//| * |
//| * |
//+------------------------------------------------------------------+
#property copyright "*"
#property link "*"
#property indicator_separate_window
#property indicator_buffers 3
#property indicator_color1 Orange
#property indicator_color2 Silver
#property indicator_color3 SlateGray
#property indicator_width2 1
#property indicator_width3 1
//---- input parameters
extern int OsMAFastPeriod=12;
extern int OsMASlowPeriod=26;
extern int OsMASignalPeriod=9;
extern int OsMAPrice=0;
extern int ExtrLeftBars=2; // áàðîâ ñëåâà îò ýêñòðåìóìà
extern int ExtrRightBars=1; // áàðîâ ñïðàâà îò ýêñòðåìóìà
extern double PlusSens=0.0001;
extern double MinusSens=-0.0001;
extern bool DrawLinesSW=true;
extern bool DrawLinesChW=true;
extern color Col_Peak_1=Red;
extern color Col_Peak_2=DeepPink;
extern color Col_Trough_1=LimeGreen;
extern color Col_Trough_2=YellowGreen;
extern string ShortName="OsMA_Divergence_v1";
//---- buffers
double osma[];
double Sig1[];
double Sig2[];
double peack_1_i[];
double peack_2_i[];
double trogh_1_i[];
double trogh_2_i[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int init()
{
//---- indicators
IndicatorBuffers(7);
SetIndexStyle(0,DRAW_LINE);
SetIndexBuffer(0,osma);
SetIndexStyle(1,DRAW_ARROW);
SetIndexArrow(1,159);
SetIndexBuffer(1,Sig1);
SetIndexStyle(2,DRAW_ARROW);
SetIndexArrow(2,159);
SetIndexBuffer(2,Sig2);
SetIndexBuffer(3,peack_1_i);
SetIndexBuffer(4,peack_2_i);
SetIndexBuffer(5,trogh_1_i);
SetIndexBuffer(6,trogh_2_i);
IndicatorShortName(ShortName);
//----
return(0);
}
//+------------------------------------------------------------------+
//| Custom indicator deinitialization function |
//+------------------------------------------------------------------+
int deinit()
{
//----
if(DrawLinesSW || DrawLinesChW)fObjDeleteByPrefix(ShortName);
//----
return(0);
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function |
//+------------------------------------------------------------------+
int start(){
int limit=Bars-IndicatorCounted();
for(int i=limit-1;i>=0;i--){
osma[i]=iOsMA(NULL,0,OsMAFastPeriod,OsMASlowPeriod,OsMASignalPeriod,OsMAPrice,i);
int extri=i+ExtrRightBars;
Sig1[i]=EMPTY_VALUE;
Sig2[i]=EMPTY_VALUE;
peack_1_i[i]=peack_1_i[i+1];
peack_2_i[i]=peack_2_i[i+1];
trogh_1_i[i]=trogh_1_i[i+1];
trogh_2_i[i]=trogh_2_i[i+1];
bool PeackNow=false;
bool TroghNow=false;
double extrv=osma[extri];
if(extrv>PlusSens){
for(int j=i;j<extri;j++){
if(extrv<=osma[j]){
break;
}
}
if(j==extri){
int extril=extri+ExtrLeftBars;
for(j=extril;j>extri;j--){
if(extrv<=osma[j]){
break;
}
}
if(j==extri){
PeackNow=true;
if(peack_1_i[i]==EMPTY_VALUE){
peack_1_i[i]=Time[extri];
}
else{
if(osma[extri]>osma[iBarShift(NULL,0,peack_1_i[i],false)]){
peack_1_i[i]=Time[extri];
}
}
}
}
}
if(extrv<MinusSens){
for(j=i;j<extri;j++){
if(extrv>=osma[j]){
break;
}
}
if(j==extri){
extril=extri+ExtrLeftBars;
for(j=extril;j>extri;j--){
if(extrv>=osma[j]){
break;
}
}
if(j==extri){
TroghNow=true;
if(trogh_1_i[i]==EMPTY_VALUE){
trogh_1_i[i]=Time[extri];
}
else{
if(osma[extri]<osma[iBarShift(NULL,0,trogh_1_i[i],false)]){
trogh_1_i[i]=Time[extri];
}
}
}
}
}
if(osma[i]>0 && osma[i+1]<=0){
peack_2_i[i]=peack_1_i[i];
peack_1_i[i]=EMPTY_VALUE;
}
if(osma[i]<0 && osma[i+1]>=0){
trogh_2_i[i]=trogh_1_i[i];
trogh_1_i[i]=EMPTY_VALUE;
}
string ObjName1=ShortName+"_PeakIW_"+Time[extri];
string ObjName2=ShortName+"_PeakPW_"+Time[extri];
ObjectDelete(ObjName1);
ObjectDelete(ObjName2);
if(PeackNow){
if(peack_1_i[i]!=EMPTY_VALUE){
if(peack_2_i[i]!=EMPTY_VALUE){
if(osma[extri]>=osma[iBarShift(NULL,0,peack_1_i[i],false)]){
int z2=iBarShift(NULL,0,peack_2_i[i],false);
int z1=extri;
if(osma[z2]<osma[z1] && High[z2]>High[z1]){
Sig1[i]=osma[i]+Point/4;
if(DrawLinesSW)fObjTrendLine(ObjName1,peack_2_i[i],osma[z2],Time[extri],osma[z1],false,Col_Peak_1,1,WindowFind(ShortName),0,true);
if(DrawLinesChW)fObjTrendLine(ObjName2,peack_2_i[i],High[z2],Time[extri],High[z1],false,Col_Peak_1,1,0,0,false);
}
if(osma[z2]>osma[z1] && High[z2]<High[z1]){
Sig2[i]=osma[i]+Point/4;
if(DrawLinesSW)fObjTrendLine(ObjName1,peack_2_i[i],osma[z2],Time[extri],osma[z1],false,Col_Peak_2,1,WindowFind(ShortName),0,true);
if(DrawLinesChW)fObjTrendLine(ObjName2,peack_2_i[i],High[z2],Time[extri],High[z1],false,Col_Peak_2,1,0,0,false);
}
}
}
}
}
ObjName1=ShortName+"_TroghIW_"+Time[extri];
ObjName2=ShortName+"_TroghPW_"+Time[extri];
ObjectDelete(ObjName1);
ObjectDelete(ObjName2);
if(TroghNow){
if(trogh_1_i[i]!=EMPTY_VALUE){
if(trogh_2_i[i]!=EMPTY_VALUE){
if(osma[extri]<=osma[iBarShift(NULL,0,trogh_1_i[i],false)]){
z2=iBarShift(NULL,0,trogh_2_i[i],false);
z1=extri;
if(osma[z2]>osma[z1] && Low[z2]<Low[z1]){
Sig1[i]=osma[i]-Point/4;
if(DrawLinesSW)fObjTrendLine(ObjName1,trogh_2_i[i],osma[z2],Time[extri],osma[z1],false,Col_Trough_1,1,WindowFind(ShortName),0,true);
if(DrawLinesChW)fObjTrendLine(ObjName2,trogh_2_i[i],Low[z2],Time[extri],Low[z1],false,Col_Trough_1,1,0,0,false);
}
if(osma[z2]<osma[z1] && Low[z2]>Low[z1]){
Sig2[i]=osma[i]-Point/4;
if(DrawLinesSW)fObjTrendLine(ObjName1,trogh_2_i[i],osma[z2],Time[extri],osma[z1],false,Col_Trough_2,1,WindowFind(ShortName),0,true);
if(DrawLinesChW)fObjTrendLine(ObjName2,trogh_2_i[i],Low[z2],Time[extri],Low[z1],false,Col_Trough_2,1,0,0,false);
}
}
}
}
}
}
return(0);
}
//+------------------------------------------------------------------+
void fObjTrendLine(
string aObjectName, // 1 èìÿ
datetime aTime_1, // 2 âðåìÿ 1
double aPrice_1, // 3 öåíà 1
datetime aTime_2, // 4 âðåìÿ 2
double aPrice_2, // 5 öåíà 2
bool aRay=false, // 6 ëó÷
color aColor=Red, // 7 öâåò
int aWidth=1, // 8 òîëùèíà
int aWindowNumber=0, // 9 îêíî
int aStyle=0, // 10 0-STYLE_SOLID, 1-STYLE_DASH, 2-STYLE_DOT, 3-STYLE_DASHDOT, 4-STYLE_DASHDOTDOT
bool aBack=false // 11 ôîí
){
if(ObjectFind(aObjectName)!=aWindowNumber){
ObjectCreate(aObjectName,OBJ_TREND,aWindowNumber,aTime_1,aPrice_1,aTime_2,aPrice_2);
}
ObjectSet(aObjectName,OBJPROP_TIME1,aTime_1);
ObjectSet(aObjectName,OBJPROP_PRICE1,aPrice_1);
ObjectSet(aObjectName,OBJPROP_TIME2,aTime_2);
ObjectSet(aObjectName,OBJPROP_PRICE2,aPrice_2);
ObjectSet(aObjectName,OBJPROP_RAY,aRay);
ObjectSet(aObjectName,OBJPROP_COLOR,aColor);
ObjectSet(aObjectName,OBJPROP_WIDTH,aWidth);
ObjectSet(aObjectName,OBJPROP_BACK,aBack);
ObjectSet(aObjectName,OBJPROP_STYLE,aStyle);
}
void fObjDeleteByPrefix(string aPrefix){
//fObjDeleteByPrefix("");
for(int i=ObjectsTotal()-1;i>=0;i--){
if(StringFind(ObjectName(i),aPrefix,0)==0){
ObjectDelete(ObjectName(i));
}
}
}
Comments