Momentum smoothing

ÿþ//+------------------------------------------------------------------+

//|                                           Momentum smoothing.mq5 |

//|                              Copyright © 2019, Vladimir Karputov |

//|                                           http://wmua.ru/slesar/ |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2019, Vladimir Karputov"

#property link      "http://wmua.ru/slesar/"

#property version   "1.001"

#include <MovingAverages.mqh>

#property indicator_separate_window

#property indicator_buffers 2

#property indicator_plots   1

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrDodgerBlue

#property indicator_style1  STYLE_SOLID

#property indicator_width1  2

//---- input parameters

input int                  Inp_Momentum_mom_period    = 14;          // averaging period 

input ENUM_MA_METHOD       Inp_Momentum_ma_method     = MODE_SMA;    // type of smoothing

input ENUM_APPLIED_PRICE   Inp_Momentum_applied_price = PRICE_CLOSE; // type of price 

//--- indicator buffers

double MomentumBuffer[];

double MomentumBufferTemp[];

//--- 

int    handle_iMomentum;      // variable for storing the handle of the iMomentum indicator

string short_name;            // name of the indicator on a chart 

int    bars_calculated=0;     // we will keep the number of values in the Standard Deviation indicator 

int    m_weightsum;

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

   m_weightsum=0;

//--- indicator buffers mapping

   SetIndexBuffer(0,MomentumBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,MomentumBufferTemp,INDICATOR_CALCULATIONS);

//--- create handle of the indicator iMomentum

   handle_iMomentum=iMomentum(Symbol(),Period(),Inp_Momentum_mom_period,

                              Inp_Momentum_applied_price);

//--- if the handle is not created 

   if(handle_iMomentum==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code 

      PrintFormat("Failed to create handle of the iMomentum indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early 

      return(INIT_FAILED);

     }

//--- 

   short_name=StringFormat("Momentum smoothing(%d)",Inp_Momentum_mom_period);

   IndicatorSetString(INDICATOR_SHORTNAME,short_name);

//--- sets drawing line empty value

   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);

//--- digits

   IndicatorSetInteger(INDICATOR_DIGITS,2);

//--- normal initialization of the indicator   

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- number of values copied from the iMomentum indicator 

   int values_to_copy;

//--- determine the number of values calculated in the indicator 

   int calculated=BarsCalculated(handle_iMomentum);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iMomentum indicator changed 

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history) 

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iMomentumBuffer array is greater than the number of values in the iMomentum indicator for symbol/period, then we don't copy everything  

      //--- otherwise, we copy less than the size of indicator buffers 

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate() 

      //--- for calculation not more than one bar is added 

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iMomentumBuffer array with values of the Momentum indicator 

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation 

   if(!FillArrayFromBuffer(MomentumBufferTemp,handle_iMomentum,values_to_copy))

      return(0);

/*  if(prev_calculated==0)

      for(int i=0;i<Inp_Momentum_mom_period-1;i++)

         MomentumBuffer[i]=0.0;*/

   switch(Inp_Momentum_ma_method)

     {

      case  MODE_SMA:

         SimpleMAOnBuffer(rates_total,prev_calculated,Inp_Momentum_mom_period+1,3,MomentumBufferTemp,MomentumBuffer);

         break;

      case  MODE_EMA:

         ExponentialMAOnBuffer(rates_total,prev_calculated,Inp_Momentum_mom_period+1,3,MomentumBufferTemp,MomentumBuffer);

         break;

      case  MODE_SMMA:

         SmoothedMAOnBuffer(rates_total,prev_calculated,Inp_Momentum_mom_period+1,3,MomentumBufferTemp,MomentumBuffer);

         break;

      default:

         LinearWeightedMAOnBuffer(rates_total,prev_calculated,Inp_Momentum_mom_period+1,9,MomentumBufferTemp,MomentumBuffer,m_weightsum);

         break;

     }

//--- memorize the number of values in the Momentum indicator 

   bars_calculated=calculated;

//--- return the prev_calculated value for the next call 

   return(rates_total);

  }

//+------------------------------------------------------------------+ 

//| Filling indicator buffers from the iMomentum indicator           | 

//+------------------------------------------------------------------+ 

bool FillArrayFromBuffer(double &values[],  // indicator buffer of Momentum values 

                         int ind_handle,    // handle of the iMomentum indicator 

                         int amount         // number of copied values 

                         )

  {

//--- reset error code 

   ResetLastError();

//--- fill a part of the iMomentumBuffer array with values from the indicator buffer that has 0 index 

   if(CopyBuffer(ind_handle,0,0,amount,values)<0)

     {

      //--- if the copying fails, tell the error code 

      PrintFormat("Failed to copy data from the iMomentum indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated 

      return(false);

     }

//--- everything is fine 

   return(true);

  }

//+------------------------------------------------------------------+