Two Rivers

ÿþ//+------------------------------------------------------------------+

//|                                                   Two Rivers.mq5 |

//|                              Copyright © 2019, Vladimir Karputov |

//|                                           http://wmua.ru/slesar/ |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2019, Vladimir Karputov"

#property link      "http://wmua.ru/slesar/"

#property version   "1.000"

#property indicator_chart_window

#property indicator_buffers 4

#property indicator_plots   2

//--- plot Up

#property indicator_label1  "Up"

#property indicator_type1   DRAW_ARROW

#property indicator_color1  clrBlue

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot Down

#property indicator_label2  "Down"

#property indicator_type2   DRAW_ARROW

#property indicator_color2  clrRed

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- input parameters

input int                  Inp_MA_ma_period     = 20;           // MA's: averaging period

input int                  Inp_MA_ma_shift      = 0;            // MA's: horizontal shift

input ENUM_MA_METHOD       Inp_MA_ma_method     = MODE_LWMA;    // MA's: smoothing type

//--- indicator buffers

double   UpBuffer[];

double   DownBuffer[];

double   iMAHighBuffer[];

double   iMALowBuffer[];

//---

int      handle_iMA_High;           // variable for storing the handle of the iMA indicator

int      handle_iMA_Low;            // variable for storing the handle of the iMA indicator

int      bars_calculated=0;         // we will keep the number of values in the Moving Average indicator

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,UpBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,DownBuffer,INDICATOR_DATA);

   SetIndexBuffer(2,iMAHighBuffer,INDICATOR_CALCULATIONS);

   SetIndexBuffer(3,iMALowBuffer,INDICATOR_CALCULATIONS);

//--- setting a code from the Wingdings charset as the property of PLOT_ARROW

   PlotIndexSetInteger(0,PLOT_ARROW,236);

   PlotIndexSetInteger(1,PLOT_ARROW,238);

//--- Set the vertical shift of arrows in pixels

   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,-5);

   PlotIndexSetInteger(1,PLOT_ARROW_SHIFT,5);

//--- Set as an empty value 0.0

   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0.0);

//--- create handle of the indicator iMA

   handle_iMA_High=iMA(Symbol(),Period(),Inp_MA_ma_period,Inp_MA_ma_shift,

                       Inp_MA_ma_method,PRICE_HIGH);

//--- if the handle is not created

   if(handle_iMA_High==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iMA indicator (\"Price High\") for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//--- create handle of the indicator iMA

   handle_iMA_Low=iMA(Symbol(),Period(),Inp_MA_ma_period,Inp_MA_ma_shift,

                      Inp_MA_ma_method,PRICE_LOW);

//--- if the handle is not created

   if(handle_iMA_Low==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iMA indicator (\"Price Low\") for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- number of values copied from the iMA indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated_high=BarsCalculated(handle_iMA_High);

   if(calculated_high<=0)

     {

      PrintFormat("BarsCalculated() (\"Price High\") returned %d, error code %d",calculated_high,GetLastError());

      return(0);

     }

   int calculated_low=BarsCalculated(handle_iMA_Low);

   if(calculated_low<=0)

     {

      PrintFormat("BarsCalculated() (\"Price Low\") returned %d, error code %d",calculated_low,GetLastError());

      return(0);

     }

   int calculated=-1;

   if(calculated_high!=calculated_low)

      return(0);

   calculated=calculated_high;

//--- if it is the first start of calculation of the indicator or if the number of values in the iMA indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iMAHighBuffer array or iMALowBuffer array is greater than the number of values in the iMA indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the UpBuffer array  with values of the Moving Average indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(iMAHighBuffer,Inp_MA_ma_shift,handle_iMA_High,values_to_copy))

      return(0);

//--- fill the DownBuffer array  with values of the Moving Average indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(iMALowBuffer,Inp_MA_ma_shift,handle_iMA_Low,values_to_copy))

      return(0);

//--- memorize the number of values in the Moving Average indicator

   bars_calculated=calculated;

//--- main calculation

   int limit=prev_calculated-1;

   if(prev_calculated==0)

      limit=0;

   for(int i=limit; i<rates_total; i++)

     {

      //A;8 5ABL A83=0; : ?>:C?:5(!25G0 ?5@5A5:;0 ?>;=>ABLN) - ?>AB028< A8=NN AB@5;:C 225@E

      if(open[i]<=iMALowBuffer[i] && close[i]>iMAHighBuffer[i] && close[i]>open[i])

         UpBuffer[i]=high[i];//70?><=8< F5=C A8=59 AB@5;:8

      else

         UpBuffer[i]=0.0;

      //A;8 5ABL A83=0; : ?@>4065 - ?>AB028< :@0A=CN AB@5;:C 2=87

      if(open[i]>=iMAHighBuffer[i] && close[i]<iMALowBuffer[i] && close[i]<open[i])

         DownBuffer[i]=low[i];//70?><=8< F5=C :@0A=>9 AB@5;:8

      else

         DownBuffer[i]=0.0;

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the MA indicator                  |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],   // indicator buffer of Moving Average values

                         int shift,          // shift

                         int ind_handle,     // handle of the iMA indicator

                         int amount          // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iMABuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,-shift,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iMA indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+