i-Sessions1

Download script
Author: ��� ����� �. aka KimIV
i-Sessions1

This script is designed to provide a visual roadmap of the global financial markets by highlighting active trading sessions directly on your price chart. It helps traders quickly identify which geographical markets (Asia, Europe, and America) are currently open or have been active recently, making it easier to understand market liquidity and volatility trends.

Core Functionality

Session Visualization The tool automatically draws colored rectangular blocks on the background of your chart to represent three specific trading sessions:

  • Asian Session
  • European Session
  • American Session

By using distinct colors for each session, you can immediately see the "heartbeat" of the global market. For example, you can visually track when the Asian market closes and the European market begins to open.

Dynamic Range Detection Instead of simply drawing a box from a fixed price point, the script intelligently calculates the price action during each specific session. It identifies the highest and lowest prices reached during those hours and stretches the visual block to cover that entire range. This allows you to see the "High" and "Low" boundaries of every market session at a glance.

Timeframe Management The script is programmed to look back over a user-defined number of days (defaulting to 7). It handles the complexities of calendar dates, ensuring that the session blocks are placed accurately day after day without overlapping or skipping dates incorrectly.

Price Level Labels There is an optional feature to display specific price levels for the most recent session. If enabled, the tool will place text labels on the chart showing the exact high and low prices reached during the current session, helping you identify key support and resistance levels established by that market's activity.

Key Features for the User

  • Customizable Timing: You can adjust the start and end times for all three sessions to match your specific broker's clock or preferred trading hours.
  • Visual Customization: You have the ability to choose different colors for each session so they align with your personal charting style.
  • Clean Chart Environment: The script is designed to manage its own objects; it automatically handles the creation and deletion of the shapes, ensuring your chart remains organized.
  • Historical Context: By viewing several days of history at once, you can spot recurring patterns in how different markets behave during their peak hours.
11 Views
0 Downloads
0 Favorites
i-Sessions1 
/*-----------------------------+
|			       |
| Shared by www.Aptrafx.com    |
|			       |
+------------------------------*/

//+------------------------------------------------------------------+
//|                                                   i-Sessions.mq4 |
//|                                           Êèì Èãîðü Â. aka KimIV |
//|                                                                  |
//|                                                                  |
//|  16.11.2005  Èíäèêàòîð òîðãîâûõ ñåññèé                           |
//+------------------------------------------------------------------+
#property copyright "Êèì Èãîðü Â. aka KimIV"
#property link      ""

#property indicator_chart_window

//------- Âíåøíèå ïàðàìåòðû èíäèêàòîðà -------------------------------
extern int    NumberOfDays = 7;             // Êîëè÷åñòâî äíåé
extern string AsiaBegin    = "01:00";       // Îòêðûòèå àçèàòñêîé ñåññèè
extern string AsiaEnd      = "10:00";       // Çàêðûòèå àçèàòñêîé ñåññèè
extern color  AsiaColor    = DarkGreen;     // Öâåò àçèàòñêîé ñåññèè
extern string EurBegin     = "07:00";       // Îòêðûòèå åâðîïåéñêîé ñåññèè
extern string EurEnd       = "16:00";       // Çàêðûòèå åâðîïåéñêîé ñåññèè
extern color  EurColor     = DarkSlateGray; // Öâåò åâðîïåéñêîé ñåññèè
extern string USABegin     = "14:00";       // Îòêðûòèå àìåðèêàíñêîé ñåññèè
extern string USAEnd       = "23:00";       // Çàêðûòèå àìåðèêàíñêîé ñåññèè
extern color  USAColor     = Navy;          // Öâåò àìåðèêàíñêîé ñåññèè
extern bool   ShowPrice    = True;          // Ïîêàçûâàòü öåíîâûå óðîâíè
extern color  clFont       = Blue;          // Öâåò øðèôòà
extern int    SizeFont     = 8;             // Ðàçìåð øðèôòà
extern int    OffSet       = 10;            // Ñìåùåíèå


//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
void init() {
  DeleteObjects();
  for (int i=0; i<NumberOfDays; i++) {
    CreateObjects("AS"+i, AsiaColor);
    CreateObjects("EU"+i, EurColor);
    CreateObjects("US"+i, USAColor);
  }
  Comment("");
}

//+------------------------------------------------------------------+
//| Custor indicator deinitialization function                       |
//+------------------------------------------------------------------+
void deinit() {
  DeleteObjects();
  Comment("");
}

//+------------------------------------------------------------------+
//| Ñîçäàíèå îáúåêòîâ èíäèêàòîðà                                     |
//| Ïàðàìåòðû:                                                       |
//|   no - íàèìåíîâàíèå îáúåêòà                                      |
//|   cl - öâåò îáúåêòà                                              |
//+------------------------------------------------------------------+
void CreateObjects(string no, color cl) {
  ObjectCreate(no, OBJ_RECTANGLE, 0, 0,0, 0,0);
  ObjectSet(no, OBJPROP_STYLE, STYLE_SOLID);
  ObjectSet(no, OBJPROP_COLOR, cl);
  ObjectSet(no, OBJPROP_BACK, True);
}

//+------------------------------------------------------------------+
//| Óäàëåíèå îáúåêòîâ èíäèêàòîðà                                     |
//+------------------------------------------------------------------+
void DeleteObjects() {
  for (int i=0; i<NumberOfDays; i++) {
    ObjectDelete("AS"+i);
    ObjectDelete("EU"+i);
    ObjectDelete("US"+i);
  }
  ObjectDelete("ASup");
  ObjectDelete("ASdn");
  ObjectDelete("EUup");
  ObjectDelete("EUdn");
  ObjectDelete("USup");
  ObjectDelete("USdn");
}

//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
void start() {
  datetime dt=CurTime();

  for (int i=0; i<NumberOfDays; i++) {
    if (ShowPrice && i==0) {
      DrawPrices(dt, "AS", AsiaBegin, AsiaEnd);
      DrawPrices(dt, "EU", EurBegin, EurEnd);
      DrawPrices(dt, "US", USABegin, USAEnd);
    }
    DrawObjects(dt, "AS"+i, AsiaBegin, AsiaEnd);
    DrawObjects(dt, "EU"+i, EurBegin, EurEnd);
    DrawObjects(dt, "US"+i, USABegin, USAEnd);
    dt=decDateTradeDay(dt);
    while (TimeDayOfWeek(dt)>5) dt=decDateTradeDay(dt);
  }
}

//+------------------------------------------------------------------+
//| Ïðîðèñîâêà îáúåêòîâ íà ãðàôèêå                                   |
//| Ïàðàìåòðû:                                                       |
//|   dt - äàòà òîðãîâîãî äíÿ                                        |
//|   no - íàèìåíîâàíèå îáúåêòà                                      |
//|   tb - âðåìÿ íà÷àëà ñåññèè                                       |
//|   te - âðåìÿ îêîí÷àíèÿ ñåññèè                                    |
//+------------------------------------------------------------------+
void DrawObjects(datetime dt, string no, string tb, string te) {
  datetime t1, t2;
  double   p1, p2;
  int      b1, b2;

  t1=StrToTime(TimeToStr(dt, TIME_DATE)+" "+tb);
  t2=StrToTime(TimeToStr(dt, TIME_DATE)+" "+te);
  b1=iBarShift(NULL, 0, t1);
  b2=iBarShift(NULL, 0, t2);
  p1=High[Highest(NULL, 0, MODE_HIGH, b1-b2, b2)];
  p2=Low [Lowest (NULL, 0, MODE_LOW , b1-b2, b2)];
  ObjectSet(no, OBJPROP_TIME1 , t1);
  ObjectSet(no, OBJPROP_PRICE1, p1);
  ObjectSet(no, OBJPROP_TIME2 , t2);
  ObjectSet(no, OBJPROP_PRICE2, p2);
}

//+------------------------------------------------------------------+
//| Ïðîðèñîâêà öåíîâûõ ìåòîê íà ãðàôèêå                              |
//| Ïàðàìåòðû:                                                       |
//|   dt - äàòà òîðãîâîãî äíÿ                                        |
//|   no - íàèìåíîâàíèå îáúåêòà                                      |
//|   tb - âðåìÿ íà÷àëà ñåññèè                                       |
//|   te - âðåìÿ îêîí÷àíèÿ ñåññèè                                    |
//+------------------------------------------------------------------+
void DrawPrices(datetime dt, string no, string tb, string te) {
  datetime t1, t2;
  double   p1, p2;
  int      b1, b2;

  t1=StrToTime(TimeToStr(dt, TIME_DATE)+" "+tb);
  t2=StrToTime(TimeToStr(dt, TIME_DATE)+" "+te);
  b1=iBarShift(NULL, 0, t1);
  b2=iBarShift(NULL, 0, t2);
  p1=High[Highest(NULL, 0, MODE_HIGH, b1-b2, b2)];
  p2=Low [Lowest (NULL, 0, MODE_LOW , b1-b2, b2)];

  if (ObjectFind(no+"up")<0) ObjectCreate(no+"up", OBJ_TEXT, 0, 0,0);
  ObjectSet(no+"up", OBJPROP_TIME1   , t2);
  ObjectSet(no+"up", OBJPROP_PRICE1  , p1+OffSet*Point);
  ObjectSet(no+"up", OBJPROP_COLOR   , clFont);
  ObjectSet(no+"up", OBJPROP_FONTSIZE, SizeFont);
  ObjectSetText(no+"up", DoubleToStr(p1+Ask-Bid, Digits));

  if (ObjectFind(no+"dn")<0) ObjectCreate(no+"dn", OBJ_TEXT, 0, 0,0);
  ObjectSet(no+"dn", OBJPROP_TIME1   , t2);
  ObjectSet(no+"dn", OBJPROP_PRICE1  , p2);
  ObjectSet(no+"dn", OBJPROP_COLOR   , clFont);
  ObjectSet(no+"dn", OBJPROP_FONTSIZE, SizeFont);
  ObjectSetText(no+"dn", DoubleToStr(p2, Digits));
}

//+------------------------------------------------------------------+
//| Óìåíüøåíèå äàòû íà îäèí òîðãîâûé äåíü                            |
//| Ïàðàìåòðû:                                                       |
//|   dt - äàòà òîðãîâîãî äíÿ                                        |
//+------------------------------------------------------------------+
datetime decDateTradeDay (datetime dt) {
  int ty=TimeYear(dt);
  int tm=TimeMonth(dt);
  int td=TimeDay(dt);
  int th=TimeHour(dt);
  int ti=TimeMinute(dt);

  td--;
  if (td==0) {
    tm--;
    if (tm==0) {
      ty--;
      tm=12;
    }
    if (tm==1 || tm==3 || tm==5 || tm==7 || tm==8 || tm==10 || tm==12) td=31;
    if (tm==2) if (MathMod(ty, 4)==0) td=29; else td=28;
    if (tm==4 || tm==6 || tm==9 || tm==11) td=30;
  }
  return(StrToTime(ty+"."+tm+"."+td+" "+th+":"+ti));
}
//+------------------------------------------------------------------+

Similar scripts

Sessions_v1

This indicator automatically projects visual zones on the chart to identify and track high-to-low price extremes during specific global trading windows.

Time Zones

This indicator visually delineates specific time-based trading windows on the chart by projecting rectangular zones based on historical price extremes or fixed volatility levels.

i_ParamonWorkTime

This indicator visually demarcates specific global trading sessions on the chart using multi-colored rectangular zones based on user-defined time windows.

i-ParamonWorkTime1_v1

This indicator identifies and visualizes specific intraday trading periods by rendering shaded geometric zones based on user-defined temporal constraints and price extremes.

MarketHoursShade_v01

This indicator visually partitions the trading chart into distinct chronological blocks to highlight specific global market sessions using background shading.

i-Sessions_v1

This indicator renders distinct shaded zones on the chart to delineate the specific operating hours of Asian, European, and American markets over a multi-day historical period.

i-Sessions

This indicator dynamically visualizes distinct geographic trading windows by projecting high-low price boundaries onto the chart based on user-defined time intervals.

$TrillionEntryBoxes

This indicator visualizes specific trading windows by plotting colored rectangular zones that automatically highlight high and low price ranges across multiple predefined daily periods.

ATM_SessionsGMT+2

Visually delineates specific trading windows by projecting historical high and low boundaries across customizable time blocks.

marketsessions

This indicator dynamically visualizes specific trading periods by rendering high and low price boundaries as distinct background rectangles across historical dates.

i-Sessions pst

Comments