CHO Out Zone Arrow

ÿþ//+------------------------------------------------------------------+

//|                                           CHO Out Zone Arrow.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                      https://www.mql5.com/en/users/barabashkakvn |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/en/users/barabashkakvn"

#property version   "1.000"

#property indicator_chart_window

#property indicator_buffers 3

#property indicator_plots   2

//--- plot CHO Buy

#property indicator_label1  "CHO Buy"

#property indicator_type1   DRAW_ARROW

#property indicator_color1  clrBlue

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot CHO Sell

#property indicator_label2  "CHO Sell"

#property indicator_type2   DRAW_ARROW

#property indicator_color2  clrRed

#property indicator_style2  STYLE_SOLID

#property indicator_width32 1

//--- input parameters

input group             "CHO"

input int                  Inp_CHO_fast_ma_period  = 3;           // CHO: fast period

input int                  Inp_CHO_slow_ma_period  = 10;          // CHO: slow period

input ENUM_MA_METHOD       Inp_CHO_ma_method       = MODE_EMA;    // CHO: smoothing type

input ENUM_APPLIED_VOLUME  Inp_CHO_applied_volume  = VOLUME_TICK; // CHO: type of volume

input group             "Arrow"

input uchar                Inp_Arrow_Buy_Code      = 241;         // CHO Buy: symbol code from the Wingdings font

input int                  Inp_Arrow_Buy_Shift     = 10;          // CHO Buy: vertical shift of arrows in pixels

input uchar                Inp_Arrow_Sell_Code     = 242;         // CHO Sell: symbol code from the Wingdings font

input int                  Inp_Arrow_Sell_Shift    = 10;          // CHO Sell: vertical shift of arrows in pixels

//--- indicator buffers

double   CHOBuyBuffer[];

double   CHOSellBuffer[];

double   CHOBuffer[];

//---

int      handle_iChaikin;                       // variable for storing the handle of the iChaikin indicator

int      bars_calculated=0;                     // we will keep the number of values in the Moving Average indicator

bool     m_init_error=false;                    // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,CHOBuyBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,CHOSellBuffer,INDICATOR_DATA);

   SetIndexBuffer(2,CHOBuffer,INDICATOR_CALCULATIONS);

//--- set accuracy

   IndicatorSetInteger(INDICATOR_DIGITS,Digits());

//--- sets first bar from what index will be drawn

   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,Inp_CHO_slow_ma_period);

   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,Inp_CHO_slow_ma_period);

//--- define the symbol code for drawing in PLOT_ARROW

   PlotIndexSetInteger(0,PLOT_ARROW,Inp_Arrow_Buy_Code);

   PlotIndexSetInteger(1,PLOT_ARROW,Inp_Arrow_Sell_Code);

//--- set the vertical shift of arrows in pixels

   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,Inp_Arrow_Buy_Shift);

   PlotIndexSetInteger(1,PLOT_ARROW_SHIFT,-Inp_Arrow_Sell_Shift);

//--- set as an empty value 0

   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0.0);

//--- name for DataWindow and indicator subwindow label

   string short_name=StringFormat("CHO Out Zone Arrow(fast %d,slow %d)",Inp_CHO_fast_ma_period,Inp_CHO_slow_ma_period);

   IndicatorSetString(INDICATOR_SHORTNAME,short_name);

//--- create handle of the indicator iChaikin

   handle_iChaikin=iChaikin(Symbol(),Period(),Inp_CHO_fast_ma_period,

                            Inp_CHO_slow_ma_period,Inp_CHO_ma_method,Inp_CHO_applied_volume);

//--- if the handle is not created

   if(handle_iChaikin==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iChaikin indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(m_init_error)

      return(0);

//--- number of values copied from the iChaikin indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iChaikin);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iChaikin indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iChaikinBuffer array is greater than the number of values in the iChaikin indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iChaikinBuffer array with values of the Chaikin Oscillator indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(CHOBuffer,handle_iChaikin,values_to_copy))

      return(0);

//--- memorize the number of values in the Chaikin Oscillator indicator

   bars_calculated=calculated;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      limit=Inp_CHO_fast_ma_period+Inp_CHO_slow_ma_period;

      for(int i=0; i<limit; i++)

        {

         CHOBuyBuffer[i]=0.0;

         CHOSellBuffer[i]=0.0;

        }

     }

   for(int i=limit; i<rates_total; i++)

     {

      CHOBuyBuffer[i]=0.0;

      CHOSellBuffer[i]=0.0;

      //--- Buy

      if(CHOBuffer[i-1]<0.0 && CHOBuffer[i]>0.0)

         CHOBuyBuffer[i]=low[i];

      //--- Sell

      if(CHOBuffer[i-1]>0.0 && CHOBuffer[i]<0.0)

         CHOSellBuffer[i]=high[i];

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iChaikin indicator            |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],  // indicator buffer of Chaikin Oscillator values

                         int ind_handle,    // handle of the iChaikin indicator

                         int amount         // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iChaikinBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iChaikin indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iChaikin!=INVALID_HANDLE)

      IndicatorRelease(handle_iChaikin);

  }

//+------------------------------------------------------------------+