CCI Extremum Detection

ÿþ//+------------------------------------------------------------------+

//|                                       CCI Extremum Detection.mq5 |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.000"

#property indicator_separate_window

#property indicator_buffers 3

#property indicator_plots   2

//--- plot CCI

#property indicator_label1  "CCI"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrYellowGreen

#property indicator_style1  STYLE_SOLID

#property indicator_width1  3

//--- plot CCI_Extremum

#property indicator_label2  "CCI_Extremum"

#property indicator_type2   DRAW_COLOR_HISTOGRAM

#property indicator_color2  clrRed,clrBlue

#property indicator_style2  STYLE_SOLID

#property indicator_width2  3

//--- input parameters

input int                  Inp_CCI_ma_period    = 14;             // CCI: averaging period

input ENUM_APPLIED_PRICE   Inp_CCI_applied_price= PRICE_TYPICAL;  // CCI: type of price

//--- indicator buffers

double   CCIBuffer[];

double   CCI_ExtremumBuffer[];

double   CCI_ExtremumColors[];

//--- variable for storing the handle of the iCCI indicator

int    handle_iCCI;

//--- we will keep the number of values in the Commodity Channel Index indicator

int    bars_calculated=0;

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- check for input value of period

   if(Inp_CCI_ma_period<=0)

     {

      printf("Incorrect value for input variable \"Averaging period\"=%d.",Inp_CCI_ma_period);

      return(INIT_PARAMETERS_INCORRECT);

     }

//--- indicator buffers mapping

   SetIndexBuffer(0,CCIBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,CCI_ExtremumBuffer,INDICATOR_DATA);

   SetIndexBuffer(2,CCI_ExtremumColors,INDICATOR_COLOR_INDEX);

//--- indicator name

   IndicatorSetString(INDICATOR_SHORTNAME,"CCI Extremum("+

                      IntegerToString(Inp_CCI_ma_period)+","+

                      EnumToString(Inp_CCI_applied_price)+")");

//--- indexes draw begin settings

   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,Inp_CCI_ma_period-1);

   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,Inp_CCI_ma_period-1);

//--- sets drawing line to empty value

   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0.0);

//--- number of digits of indicator value

   IndicatorSetInteger(INDICATOR_DIGITS,2);

//--- create handle of the indicator iCCI

   handle_iCCI=iCCI(Symbol(),Period(),Inp_CCI_ma_period,Inp_CCI_applied_price);

//--- if the handle is not created

   if(handle_iCCI==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iCCI indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(rates_total<3)

      return(0);

//--- number of values copied from the iCCI indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iCCI);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iCCI indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the CCI array is greater than the number of values in the iCCI indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the CCI array with values of the Commodity Channel Index indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(CCIBuffer,handle_iCCI,values_to_copy))

      return(0);

//--- main loop

   int limit=prev_calculated-2;

   if(prev_calculated==0)

      limit=1;

   for(int i=limit; i<rates_total-1; i++)

     {

      CCI_ExtremumBuffer[i]=0.0;

      CCI_ExtremumColors[i]=0.0;

      if(CCIBuffer[i]>0.0)

        {

         if(CCIBuffer[i-1]<CCIBuffer[i] && CCIBuffer[i]>CCIBuffer[i+1])

            CCI_ExtremumBuffer[i]=100.0;

        }

      else

        {

         if(CCIBuffer[i-1]>CCIBuffer[i] && CCIBuffer[i]<CCIBuffer[i+1])

           {

            CCI_ExtremumBuffer[i]=-100.0;

            CCI_ExtremumColors[i]=1.0;

           }

        }

     }

//--- memorize the number of values in the Commodity Channel Index indicator

   bars_calculated=calculated;

//--- return the prev_calculated value for the next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iCCI indicator                |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],  // indicator buffer of Commodity Channel Index values

                         int ind_handle,    // handle of the iCCI indicator

                         int amount         // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the CCI array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iCCI indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iCCI!=INVALID_HANDLE)

      IndicatorRelease(handle_iCCI);

//--- clear the chart after deleting the indicator

   Comment("");

  }

//+------------------------------------------------------------------+