CCI Alert 2

ÿþ//+------------------------------------------------------------------+

//|                                                  CCI Alert 2.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43161 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43161"

#property version   "2.001"

#property description "Four types of Alert: enter/exit from 'Level DOWN (-90)', enter/exit from 'Level UP (90)'"

#property indicator_separate_window

#property indicator_buffers 1

#property indicator_plots   1

//--- plot CCIColor

#property indicator_label1  "CCI"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrPaleVioletRed

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- input parameters

input group             "CCI"

input int                  Inp_CCI_ma_period    = 9;              // averaging period

input ENUM_APPLIED_PRICE   Inp_CCI_applied_price= PRICE_TYPICAL;  // type of price

input double               Inp_CCI_LevelUP      = 90;             // Level UP (90)

input double               Inp_CCI_LevelDOWN    =-90;             // Level DOWN (-90)

input group             "Alerts"

input string               InpSoundName         = "alert.wav"; // Sound Name

input uchar                InpSoundRepetitions  = 3;           // Repetitions

input uchar                InpSoundPause        = 3;           // Pause, in seconds

input bool                 InpAlert             = true;        // Alert

input bool                 InpMail              = true;        // Send mail

input bool                 InpNotification      = true;        // Send notification

//--- indicator buffer

double   CCIBuffer[];

//---

int      handle_iCCI;                           // variable for storing the handle of the iCCI indicator

int      bars_calculated      = 0;              // we will keep the number of values in the CCI indicator

datetime m_last_sound         = 0;              // "0" -> D'1970.01.01 00:00';

uchar    m_repetitions        = 0;              //

string   m_text               = "";             //

datetime m_prev_bars          = 0;              // "0" -> D'1970.01.01 00:00';

bool     m_init_error         = false;          // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,CCIBuffer,INDICATOR_DATA);

//--- set levels

   IndicatorSetInteger(INDICATOR_LEVELS,2);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,0,Inp_CCI_LevelUP);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,1,Inp_CCI_LevelDOWN);

//--- indexes draw begin settings

   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,Inp_CCI_ma_period);

//--- number of digits of indicator value

   IndicatorSetInteger(INDICATOR_DIGITS,2);

//--- create handle of the indicator iCCI

   handle_iCCI=iCCI(Symbol(),Period(),Inp_CCI_ma_period,Inp_CCI_applied_price);

//--- if the handle is not created

   if(handle_iCCI==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iCCI indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//--- show the symbol/timeframe the Moving Average indicator is calculated for

   string short_name=StringFormat("CCI Alert(%d, %s)",

                                  Inp_CCI_ma_period,EnumToString(Inp_CCI_applied_price));

   IndicatorSetString(INDICATOR_SHORTNAME,short_name);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(m_init_error)

      return(0);

   if(rates_total<=Inp_CCI_ma_period)

      return(0);

//---

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iCCI);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iCCI indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iCCIBuffer array is greater than the number of values in the iCCI indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iCCIBuffer array with values of the Commodity Channel Index indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(CCIBuffer,handle_iCCI,values_to_copy))

      return(0);

//--- memorize the number of values in the Commodity Channel Index indicator

   bars_calculated=calculated;

//--- main loop

   if(time[rates_total-1]>m_prev_bars)

     {

      m_last_sound=0;

      m_prev_bars=time[rates_total-1];

      m_repetitions=0;

     }

   if(m_repetitions>=InpSoundRepetitions)

      return(rates_total);

//---

   datetime time_current=TimeCurrent();

   if(time_current-m_last_sound>InpSoundPause)

     {

      int i=rates_total-1;

      if(CCIBuffer[i-1]<Inp_CCI_LevelDOWN && CCIBuffer[i]>Inp_CCI_LevelDOWN)

        {

         PlaySound(InpSoundName);

         m_text=Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" CCI crossed the 'Level DOWN' from bottom to top, "+TimeToString(time[i]);

         if(InpAlert)

            Alert(m_text);

         m_last_sound=time_current;

         m_repetitions++;

         //---

         if(InpMail)

           {

            SendMail(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1),m_text);

           }

         if(InpNotification)

           {

            SendNotification(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" "+m_text);

           }

         return(rates_total);

        }

      if(CCIBuffer[i-1]>Inp_CCI_LevelDOWN && CCIBuffer[i]<Inp_CCI_LevelDOWN)

        {

         PlaySound(InpSoundName);

         m_text=Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" CCI crossed the 'Level DOWN' from top to bottom, "+TimeToString(time[i]);

         if(InpAlert)

            Alert(m_text);

         m_last_sound=time_current;

         m_repetitions++;

         //---

         if(InpMail)

           {

            SendMail(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1),m_text);

           }

         if(InpNotification)

           {

            SendNotification(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" "+m_text);

           }

         return(rates_total);

        }

      if(CCIBuffer[i-1]>Inp_CCI_LevelUP && CCIBuffer[i]<Inp_CCI_LevelUP)

        {

         PlaySound(InpSoundName);

         m_text=Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" CCI crossed the 'Level UP' from top to bottom, "+TimeToString(time[i]);

         if(InpAlert)

            Alert(m_text);

         m_last_sound=time_current;

         m_repetitions++;

         //---

         if(InpMail)

           {

            SendMail(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1),m_text);

           }

         if(InpNotification)

           {

            SendNotification(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" "+m_text);

           }

         return(rates_total);

        }

      if(CCIBuffer[i-1]<Inp_CCI_LevelUP && CCIBuffer[i]>Inp_CCI_LevelUP)

        {

         PlaySound(InpSoundName);

         m_text=Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" CCI crossed the 'Level UP' from bottom to top, "+TimeToString(time[i]);

         if(InpAlert)

            Alert(m_text);

         m_last_sound=time_current;

         m_repetitions++;

         //---

         if(InpMail)

           {

            SendMail(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1),m_text);

           }

         if(InpNotification)

           {

            SendNotification(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" "+m_text);

           }

         return(rates_total);

        }

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iCCI indicator                |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],  // indicator buffer of Commodity Channel Index values

                         int ind_handle,    // handle of the iCCI indicator

                         int amount         // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iCCIBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iCCI indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iCCI!=INVALID_HANDLE)

      IndicatorRelease(handle_iCCI);

  }

//+------------------------------------------------------------------+