iMA iRSI

ÿþ//+------------------------------------------------------------------+

//|                                                     iMA iRSI.mq5 |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.001"

#property indicator_separate_window

#property indicator_minimum 0

#property indicator_maximum 100

#property indicator_buffers 3

#property indicator_plots   1

//--- plot iMAiRSI

#property indicator_label1  "iMAiRSI"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrDarkOrange

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- input parameters

//--- MA

input int                  Inp_MA_ma_period     = 12;             // MA: averaging period

input int                  Inp_MA_ma_shift      = 0;              // MA: horizontal shift

input ENUM_MA_METHOD       Inp_MA_ma_method     = MODE_EMA;       // MA: smoothing type

input ENUM_APPLIED_PRICE   Inp_MA_applied_price = PRICE_WEIGHTED; // MA: type of price

//--- RSI

input ENUM_APPLIED_PRICE   Inp_RSI_applied_price= PRICE_WEIGHTED;// RSI: type of price

//--- indicator buffers

double   iMAiRSIBuffer[];

double   iMABuffer[];

double   iRSIBuffer[];

//---

int      handle_iMA;                         // variable for storing the handle of the iMA indicator

int      handle_iRSI;                        // variable for storing the handle of the iRSI indicator

//--- we will keep the number of values indicators

int      bars_calculated=0;

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,iMAiRSIBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,iMABuffer,INDICATOR_CALCULATIONS);

   SetIndexBuffer(2,iRSIBuffer,INDICATOR_CALCULATIONS);

//--- set the accuracy of values to be displayed in the Data Window

   IndicatorSetInteger(INDICATOR_DIGITS,0);

//--- an empty value

   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);

//--- create handle of the indicator iMA

   handle_iMA=iMA(Symbol(),Period(),Inp_MA_ma_period,Inp_MA_ma_shift,

                  Inp_MA_ma_method,Inp_MA_applied_price);

//--- if the handle is not created

   if(handle_iMA==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iMA indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//--- create handle of the indicator iRSI

   handle_iRSI=iRSI(Symbol(),Period(),Inp_MA_ma_period,Inp_RSI_applied_price);

//--- if the handle is not created

   if(handle_iRSI==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iRSI indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- number of values copied from the indicators

   int values_to_copy;

//--- determine the number of values calculated in the iMA indicator

   int calculated_iMA=BarsCalculated(handle_iMA);

   if(calculated_iMA<=0)

     {

      PrintFormat("BarsCalculated(iMA) returned %d, error code %d",calculated_iMA,GetLastError());

      return(0);

     }

//--- determine the number of values calculated in the iRSI indicator

   int calculated_iRSI=BarsCalculated(handle_iRSI);

   if(calculated_iRSI<=0)

     {

      PrintFormat("BarsCalculated(iRSI) returned %d, error code %d",calculated_iRSI,GetLastError());

      return(0);

     }

//---

   if(calculated_iMA!=calculated_iRSI)

     {

      PrintFormat("BarsCalculated(iMA) returned %d, BarsCalculated(iRSI) returned %d",calculated_iMA,calculated_iRSI);

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the indicator changed

//--- or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated_iMA!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the Buffer array is greater than the number of values in the indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated_iMA>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated_iMA;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iMABuffer array with values of the Moving Average indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBufferMA(iMABuffer,Inp_MA_ma_shift,handle_iMA,values_to_copy))

      return(0);

//--- fill the array with values of the iRSI indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBufferRSI(iRSIBuffer,handle_iRSI,values_to_copy))

      return(0);

//--- memorize the number of values in the Moving Average indicator

   bars_calculated=calculated_iMA;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      iMAiRSIBuffer[0]=0.0;

      limit=1;

     }

   for(int i=limit; i<rates_total; i++)

     {

      double result=(iMABuffer[i]-iMABuffer[i-1])/Point()*iRSIBuffer[i];



      if(result<1.0)

        {

         iMAiRSIBuffer[i]=1.0;

        }

      else

        {

         if(result>99.0)

            iMAiRSIBuffer[i]=99;

         else

            iMAiRSIBuffer[i]=result;

        }

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the MA indicator                  |

//+------------------------------------------------------------------+

bool FillArrayFromBufferMA(double &values[],   // indicator buffer of Moving Average values

                           int shift,          // shift

                           int ind_handle,     // handle of the iMA indicator

                           int amount          // number of copied values

                          )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iMABuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,-shift,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iMA indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iRSI indicator                |

//+------------------------------------------------------------------+

bool FillArrayFromBufferRSI(double &rsi_buffer[],  // indicator buffer of Relative Strength Index values

                            int ind_handle,        // handle of the iRSI indicator

                            int amount             // number of copied values

                           )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iRSIBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,rsi_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iRSI indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iMA!=INVALID_HANDLE)

      IndicatorRelease(handle_iMA);

   if(handle_iRSI!=INVALID_HANDLE)

      IndicatorRelease(handle_iRSI);

//--- clear the chart after deleting the indicator

   Comment("");

  }

//+------------------------------------------------------------------+