This indicator is designed to provide a clearer, more stable view of market trends by applying a sophisticated smoothing process to the standard Average Directional Index (ADX). While a standard ADX helps traders identify the strength of a trend, it can sometimes be "noisy" or jumpy. This script addresses that issue by processing the data through a multi-layered mathematical filter.
Core Components
The tool tracks three primary metrics simultaneously:
- DI Plus: Represents the strength of upward price momentum.
- DI Minus: Represents the strength of downward price momentum.
- ADX: The overall measure of trend intensity, regardless of direction.
How the Logic Works
Instead of simply plotting these values directly from the raw market data, the script employs a two-stage smoothing technique to refine the signals:
-
The Primary Smoothing Phase: The script first calculates a "lead" value for each metric. It looks at the current market data alongside the previous price points and blends them using a specific weighting factor (alpha1). This initial pass helps to neutralize sudden, erratic spikes in price movement while maintaining the integrity of the underlying trend.
-
The Secondary Smoothing Phase: The output from the first phase is then passed through a second layer of processing. By applying another weighting factor (alpha2), the script further "rounds off" the lines. This results in a much smoother visual curve that is easier for the human eye to follow on a chart.
Practical Application
By using this dual-layer approach, the indicator aims to eliminate the "jitter" often found in standard trend oscillators. For a trader, this means:
- Clearer Visuals: The lines move more fluidly across the screen, making it easier to identify when a trend is truly establishing itself.
- Reduced False Signals: By smoothing out temporary price fluctuations, the indicator helps focus on sustained movements rather than minor market noise.
- Trend Strength Identification: It allows users to see the relationship between bullish and bearish momentum (DI Plus vs. DI Minus) and the overall power of the move (ADX) in a stabilized format.
//+------------------------------------------------------------------+
//| ADX Smoothed.mq4 |
//| Copyright © 2007, MetaQuotes Software Corp. |
//| http://www.metaquotes.net |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2007, MetaQuotes Software Corp."
#property link "http://www.metaquotes.net"
//----
#property indicator_separate_window
#property indicator_buffers 3
#property indicator_color1 DarkBlue
#property indicator_color2 FireBrick
#property indicator_color3 DarkGreen
#property indicator_level1 25
//---- input parameters
extern int per = 14;
extern double alpha1 = 0.25;
extern double alpha2 = 0.33;
extern int PriceType = 0;
//---- buffers
double DiPlusFinal[];
double DiMinusFinal[];
double ADXFinal[];
double DIPlusLead[];
double DIMinusLead[];
double ADXLead[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int init()
{
//---- indicators
IndicatorBuffers(6);
SetIndexStyle(0, DRAW_LINE);
SetIndexBuffer(0, DiPlusFinal);
SetIndexLabel(0, "Di Plus");
//----
SetIndexStyle(1, DRAW_LINE);
SetIndexBuffer(1, DiMinusFinal);
SetIndexLabel(1, "Di Minus");
//----
SetIndexStyle(2, DRAW_LINE);
SetIndexBuffer(2, ADXFinal);
SetIndexLabel(2, "ADX");
//----
SetIndexBuffer(3, DIPlusLead);
SetIndexBuffer(4, DIMinusLead);
SetIndexBuffer(5, ADXLead);
//----
IndicatorDigits(2);
IndicatorShortName("ADX(" + per + ")smothed");
//----
return(0);
}
//+------------------------------------------------------------------+
//| Custom indicator deinitialization function |
//+------------------------------------------------------------------+
int deinit()
{
//----
return(0);
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function |
//+------------------------------------------------------------------+
int start()
{
int counted_bars = IndicatorCounted();
int i, k, limit;
double DIPlus, DIMinus, ADX, DIPlus1, DIMinus1, ADX1;
//----
if(counted_bars == 0)
limit = Bars - per - 1;
if(counted_bars > 0)
limit = Bars - counted_bars;
for(i = limit; i >= 0; i--)
{
DIPlus = iADX(NULL, 0, per, PriceType, MODE_PLUSDI, i);
DIMinus = iADX(NULL, 0, per, PriceType, MODE_MINUSDI, i);
ADX = iADX(NULL, 0, per, PriceType, MODE_MAIN, i);
DIPlus1 = iADX(NULL, 0, per, PriceType, MODE_PLUSDI, i + 1);
DIMinus1 = iADX(NULL, 0, per, PriceType, MODE_MINUSDI, i + 1);
ADX1 = iADX(NULL, 0, per, PriceType, MODE_MAIN, i + 1);
//----
DIPlusLead[i] = 2*DIPlus + (alpha1 - 2) * DIPlus1 +
(1 - alpha1) * DIPlusLead[i+1];
DIMinusLead[i] = 2*DIMinus + (alpha1 - 2) * DIMinus1 +
(1 - alpha1) * DIMinusLead[i+1];
ADXLead[i] = 2*ADX + (alpha1 - 2) * ADX1 + (1 - alpha1) * ADXLead[i+1];
}
for(i = limit; i >= 0; i--)
{
DiPlusFinal[i] = alpha2*DIPlusLead[i] + (1 - alpha2) * DiPlusFinal[i+1];
DiMinusFinal[i] = alpha2*DIMinusLead[i] + (1 - alpha2) * DiMinusFinal[i+1];
ADXFinal[i] = alpha2*ADXLead[i] + (1 - alpha2) * ADXFinal[i+1];
}
//----
return(0);
}
//+------------------------------------------------------------------+
Comments