Zerolagstochs_true

Download script
Author: Copyright � 2004, MetaQuotes Software Corp.
Zerolagstochs_true

This script functions as a customized technical analysis tool designed to track momentum and price positioning within a specific timeframe. It builds upon the traditional Stochastic Oscillator but introduces a specialized mathematical adjustment to reduce "lag"—the delay between a market move and its appearance on a chart.

Core Logic and Workflow

1. Price Range Identification The script begins by scanning historical price data to identify the highest highs and lowest lows over a specific window of time (defined by the KPeriod). By establishing these boundaries, the tool determines the total "range" of price movement during that period.

2. Relative Position Calculation Once the high and low boundaries are established, the script calculates where the current closing price sits relative to that range. It converts this into a percentage value. For example, if the price is trading much closer to the recent high than the low, the resulting value will be high; if it is near the bottom, the value will be low.

3. Smoothing and Momentum Filtering To prevent the indicator from reacting too erratically to minor price "noise," the script applies a smoothing process (the Slowing factor). It calculates moving averages of the percentage values to create a more fluid trend line.

4. The Zero-Lag Adjustment This is the unique logic of this specific script. Instead of simply showing a standard smoothed average, the script performs a "Zero-Lag" calculation. It takes the smoothed value and adds it to itself, then subtracts the average of that result. This mathematical operation is designed to accelerate the indicator's response to new price changes, attempting to make the visual line hug the actual price action more tightly than a standard oscillator would.

5. Signal Generation Finally, the script produces two distinct lines for the user:

  • The Main Line: The primary "Zero-Lag" adjusted momentum value.
  • The Signal Line: A second, even slower moving average of the Main Line.

By comparing these two lines, traders can identify potential shifts in momentum—typically looking for instances where the faster main line crosses over or under the slower signal line to detect changes in market direction.

Indicators Used
Moving average indicator
Miscellaneous
Implements a curve of type %1
12 Views
0 Downloads
0 Favorites
Zerolagstochs_true
//+------------------------------------------------------------------+
//|                                          ZeroLag Stochs_true.mq4 |
//|                      Copyright © 2004, MetaQuotes Software Corp. |
//|                                       http://www.metaquotes.net/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2004, MetaQuotes Software Corp."
#property link      "http://www.metaquotes.net/"
#include <stdlib.mqh>
//----
#property indicator_separate_window
//#property indicator_minimum 0
//#property indicator_maximum 100
#property indicator_buffers 2
#property indicator_color1 Blue
#property indicator_color2 Red
//---- input parameters
extern int KPeriod = 5;
extern int Slowing = 3;
extern int DPeriod = 3;
//---- buffers
double MainBuffer[];
double SignalBuffer[];
double HighesBuffer[];
double LowesBuffer[];
double WorkBuffer[];
double WorkBuffer2[];
//----
int draw_begin1 = 0;
int draw_begin2 = 0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
   string short_name;
//---- 2 additional buffers are used for counting.
   IndicatorBuffers(6);
   SetIndexBuffer(2, HighesBuffer);
   SetIndexBuffer(3, LowesBuffer);
   SetIndexBuffer(4, WorkBuffer);
   SetIndexBuffer(5, WorkBuffer2);     
//---- indicator lines
   SetIndexStyle(0, DRAW_LINE);
   SetIndexBuffer(0, MainBuffer);
   SetIndexStyle(1, DRAW_LINE);
   SetIndexBuffer(1, SignalBuffer);
//---- name for DataWindow and indicator subwindow label
   short_name="ZLStoch(" + KPeriod + "," + DPeriod + "," + Slowing + ")";
   IndicatorShortName(short_name);
   SetIndexLabel(0, short_name);
   SetIndexLabel(1, "Signal");
//----
   draw_begin1 = KPeriod + Slowing;
   draw_begin2 = draw_begin1 + DPeriod;
   SetIndexDrawBegin(0, draw_begin1);
   SetIndexDrawBegin(1, draw_begin2);
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Stochastic oscillator                                            |
//+------------------------------------------------------------------+
int start()
  {
   int    i, k;
   int    counted_bars = IndicatorCounted();
   double price, EMA;
//----
   if(Bars <= draw_begin2) 
       return(0);
//---- initial zero
   if(counted_bars < 1)
     {
       for(i = 1; i <= draw_begin1; i++) 
           MainBuffer[Bars-i] = 0;
       for(i = 1; i <= draw_begin2; i++) 
           SignalBuffer[Bars-i] = 0;
     }
//---- minimums counting
   i = Bars - KPeriod;
   if(counted_bars > KPeriod) 
       i = Bars - counted_bars - 1;
   while(i >= 0)
     {
       double min = 1000000;
       k = i + KPeriod - 1;
       while(k >= i)
         {
           price = Low[k];
           if(min > price) 
               min = price;
           k--;
         }
       LowesBuffer[i] = min;
       i--;
     }
//---- maximums counting
   i = Bars - KPeriod;
   if(counted_bars > KPeriod) 
       i = Bars - counted_bars - 1;
   while(i >= 0)
     {
       double max=-1000000;
       k = i + KPeriod - 1;
       while(k >= i)
         {
           price = High[k];
           if(max < price) 
               max = price;
           k--;
         }
       HighesBuffer[i] = max;
       i--;
     }
//---- %K line
   i = Bars - draw_begin1;
   if(counted_bars > draw_begin1) 
       i = Bars - counted_bars - 1;
   while(i >= 0)
     {
       if(!CompareDouble((HighesBuffer[i] - LowesBuffer[i]), 0.0))
           WorkBuffer[i] = 100*((Close[i] - LowesBuffer[i]) / (HighesBuffer[i] - LowesBuffer[i]));
       i--;
     }
//---- last counted bar will be recounted
   if(counted_bars > 0) 
       counted_bars--;
   int limit = Bars - counted_bars;
//---- main line is simple movimg average
   for(i = 0; i < limit; i++)
       WorkBuffer2[i] = iMAOnArray(WorkBuffer, Bars, Slowing, 0, MODE_SMA, i);
   for(i = 0; i < limit; i++)
     {
       EMA = iMAOnArray(WorkBuffer2, Bars, Slowing, 0, MODE_SMA, i);
       MainBuffer[i] = WorkBuffer2[i] + WorkBuffer2[i] - EMA;
     }
//---- signal line is simple movimg average
   for(i = 0; i < limit; i++)
       WorkBuffer2[i] = iMAOnArray(MainBuffer, Bars, DPeriod, 0, MODE_SMA, i);
   for(i = 0; i < limit; i++)
     {
       EMA = iMAOnArray(WorkBuffer2, Bars, DPeriod, 0, MODE_SMA, i);
       SignalBuffer[i] = WorkBuffer2[i] + WorkBuffer2[i] - EMA;
     }
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Ôóíêöèÿ ñðàíåíèÿ äâóõ âåùåñòâåííûõ ÷èñåë.                        |
//+------------------------------------------------------------------+
bool CompareDouble (double Number1, double Number2)
  {
    bool Compare = NormalizeDouble(Number1 - Number2, 8) == 0;
    return(Compare);
  }
//+------------------------------------------------------------------+ 

Comments