xma_bbx7_cloud_digit_grid

//+---------------------------------------------------------------------+
//|                                       XMA_BBx7_Cloud_Digit_Grid.mq5 | 
//|                                  Copyright © 2016, Nikolay Kositsin | 
//|                                 Khabarovsk,   farria@mail.redcom.ru | 
//+---------------------------------------------------------------------+ 
//| Äëÿ ðàáîòû  èíäèêàòîðà  ñëåäóåò  ïîëîæèòü ôàéë SmoothAlgorithms.mqh |
//| â ïàïêó (äèðåêòîðèþ): êàòàëîã_äàííûõ_òåðìèíàëà\\MQL5\Include        |
//+---------------------------------------------------------------------+
#property copyright "Copyright © 2016, Nikolay Kositsin"
#property link "farria@mail.redcom.ru"
#property description "XMA Bollinger Bands"
//---- íîìåð âåðñèè èíäèêàòîðà
#property version   "1.01"
//---- îòðèñîâêà èíäèêàòîðà â ãëàâíîì îêíå
#property indicator_chart_window 
//---- êîëè÷åñòâî èíäèêàòîðíûõ áóôåðîâ 11
#property indicator_buffers 11 
//---- èñïîëüçîâàíî âñåãî øåñòü ãðàôè÷åñêèõ ïîñòðîåíèé
#property indicator_plots   6
//+----------------------------------------------+
//|  Ïàðàìåòðû îòðèñîâêè îáëàêà                  |
//+----------------------------------------------+
//---- îòðèñîâêà èíäèêàòîðà â âèäå öâåòíîãî îáëàêà
#property indicator_type1   DRAW_FILLING
//---- â êà÷åñòâå öâåòà îáëàêà èñïîëüçîâàí
#property indicator_color1  clrDeepSkyBlue
//---- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label1  "Upper Sigma3 Cloud"
//+----------------------------------------------+
//|  Ïàðàìåòðû îòðèñîâêè îáëàêà                  |
//+----------------------------------------------+
//---- îòðèñîâêà èíäèêàòîðà â âèäå öâåòíîãî îáëàêà
#property indicator_type2   DRAW_FILLING
//---- â êà÷åñòâå öâåòà îáëàêà èñïîëüçîâàí
#property indicator_color2  clrLime
//---- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label2  "Upper Sigma2 Cloud"
//+----------------------------------------------+
//|  Ïàðàìåòðû îòðèñîâêè îáëàêà                  |
//+----------------------------------------------+
//---- îòðèñîâêà èíäèêàòîðà â âèäå öâåòíîãî îáëàêà
#property indicator_type3   DRAW_FILLING
//---- â êà÷åñòâå öâåòà îáëàêà èñïîëüçîâàí
#property indicator_color3  clrLavender
//---- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label3  "Sigma1 Cloud"
//+----------------------------------------------+
//|  Ïàðàìåòðû îòðèñîâêè ìóâèíãà                 |
//+----------------------------------------------+
//---- îòðèñîâêà èíäèêàòîðà â âèäå ëèíèè
#property indicator_type4   DRAW_LINE
//---- â êà÷åñòâå öâåòà ëèíèè èíäèêàòîðà èñïîëüçîâàí ñèíå-ôèîëåòîâûé öâåò
#property indicator_color4 clrBlueViolet
//---- ëèíèÿ èíäèêàòîðà - ñïëîøíàÿ
#property indicator_style4  STYLE_SOLID
//---- òîëùèíà ëèíèè èíäèêàòîðà ðàâíà 2
#property indicator_width4  2
//---- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label4  "XMA"
//+----------------------------------------------+
//|  Ïàðàìåòðû îòðèñîâêè îáëàêà                  |
//+----------------------------------------------+
//---- îòðèñîâêà èíäèêàòîðà â âèäå öâåòíîãî îáëàêà
#property indicator_type5   DRAW_FILLING
//---- â êà÷åñòâå öâåòà îáëàêà èñïîëüçîâàí
#property indicator_color5  clrMagenta
//---- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label5  "Lower Sigma2 Cloud"
//+----------------------------------------------+
//|  Ïàðàìåòðû îòðèñîâêè îáëàêà                  |
//+----------------------------------------------+
//---- îòðèñîâêà èíäèêàòîðà â âèäå öâåòíîãî îáëàêà
#property indicator_type6   DRAW_FILLING
//---- â êà÷åñòâå öâåòà îáëàêà èñïîëüçîâàí
#property indicator_color6  clrMediumOrchid
//---- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label6  "Lower Sigma3 Cloud"
//+--------------------------------------------+
//|  Îïèñàíèå êëàññîâ óñðåäíåíèé               |
//+--------------------------------------------+
#include <SmoothAlgorithms.mqh> 
//+--------------------------------------------+
//---- îáúÿâëåíèå ïåðåìåííûõ êëàññîâ CXMA è CStdDeviation èç ôàéëà SmoothAlgorithms.mqh
CXMA XMA1;
CStdDeviation STD1,STD2,STD3;
//+--------------------------------------------+
//|  Îáúÿâëåíèå ïåðå÷èñëåíèé                   |
//+--------------------------------------------+
enum Applied_price_ //Òèï êîíñòàíòû
  {
   PRICE_CLOSE_ = 1,     //Close
   PRICE_OPEN_,          //Open
   PRICE_HIGH_,          //High
   PRICE_LOW_,           //Low
   PRICE_MEDIAN_,        //Median Price (HL/2)
   PRICE_TYPICAL_,       //Typical Price (HLC/3)
   PRICE_WEIGHTED_,      //Weighted Close (HLCC/4)
   PRICE_SIMPL_,         //Simpl Price (OC/2)
   PRICE_QUARTER_,       //Quarted Price (HLOC/4) 
   PRICE_TRENDFOLLOW0_,  //TrendFollow_1 Price 
   PRICE_TRENDFOLLOW1_,  //TrendFollow_2 Price
   PRICE_DEMARK_         //Demark Price 
  };
//+--------------------------------------------+
//|  Îáúÿâëåíèå ïåðå÷èñëåíèÿ                   |
//+--------------------------------------------+  
enum WIDTH
  {
   Width_1=1, //1
   Width_2,   //2
   Width_3,   //3
   Width_4,   //4
   Width_5    //5
  };
//+--------------------------------------------+
//|  Îáúÿâëåíèå ïåðå÷èñëåíèÿ                   |
//+--------------------------------------------+
enum STYLE
  {
   SOLID_,//Ñïëîøíàÿ ëèíèÿ
   DASH_,//Øòðèõîâàÿ ëèíèÿ
   DOT_,//Ïóíêòèðíàÿ ëèíèÿ
   DASHDOT_,//Øòðèõ-ïóíêòèðíàÿ ëèíèÿ
   DASHDOTDOT_   //Øòðèõ-ïóíêòèðíàÿ ëèíèÿ ñ äâîéíûìè òî÷êàìè
  };
//+--------------------------------------------+
//|  Îáúÿâëåíèå ïåðå÷èñëåíèé                   |
//+--------------------------------------------+
/*enum Smooth_Method - ïåðå÷èñëåíèå îáúÿâëåíî â ôàéëå SmoothAlgorithms.mqh
  {
   MODE_SMA_,  //SMA
   MODE_EMA_,  //EMA
   MODE_SMMA_, //SMMA
   MODE_LWMA_, //LWMA
   MODE_JJMA,  //JJMA
   MODE_JurX,  //JurX
   MODE_ParMA, //ParMA
   MODE_T3,    //T3
   MODE_VIDYA, //VIDYA
   MODE_AMA,   //AMA
  }; */
//+--------------------------------------------+
//|  Âõîäíûå ïàðàìåòðû èíäèêàòîðà              |
//+--------------------------------------------+
input string  SirName="XMA_BBx7_Cloud_Digit_Grid";     //Ïåðâàÿ ÷àñòü èìåíè ãðàôè÷åñêèõ îáúåêòîâ
input Smooth_Method XMA_Method=MODE_SMA_; //ìåòîä óñðåäíåíèÿ
input uint XLength=100; //ãëóáèíà  óñðåäíåíèÿ                    
input int XPhase=15; //ïàðàìåòð ïåðâîãî óñðåäíåíèÿ,
//---- äëÿ JJMA èçìåíÿþùèéñÿ â ïðåäåëàõ -100 ... +100, âëèÿåò íà êà÷åñòâî ïåðåõîäíîãî ïðîöåññà;
//---- Äëÿ VIDIA ýòî ïåðèîä CMO, äëÿ AMA ýòî ïåðèîä ìåäëåííîé ñêîëüçÿùåé
input double BandsDeviation1=2.0; //äåâèàöèÿ 1
input double BandsDeviation2=3.0; //äåâèàöèÿ 2
input double BandsDeviation3=4.0; //äåâèàöèÿ 3
input uint Digit=2; //êîëè÷åñòâî ðàçðÿäîâ îêðóãëåíèÿ
input Applied_price_ IPC=PRICE_CLOSE_;//öåíîâàÿ êîíñòàíòà
input int Shift=0; // ñäâèã èíäèêàòîðà ïî ãîðèçîíòàëè â áàðàõ
input int PriceShift=0; // cäâèã èíäèêàòîðà ïî âåðòèêàëè â ïóíêòàõ
input bool ShowPrice=true; //ïîêàçûâàòü öåíîâûå ìåòêè
//---- öâåòà öåíîâûõ ìåòîê
input color  Middle_color=clrBlue;
input color  Upper_color1=clrMediumSeaGreen;
input color  Lower_color1=clrRed;
input color  Upper_color2=clrDodgerBlue;
input color  Lower_color2=clrMagenta;
input color  Upper_color3=clrBlue;
input color  Lower_color3=clrOrange;
//---- Ïàðàìåòðû öåíîâîé ñåòêè
input uint  Total=200;                       //êîëè÷åñòâî áëîêîâ ñåòêè ñâåðõó èëè ñíèçó îò öåíû
//----
input color  Color_A = clrSlateBlue;         //öâåò óðîâíÿ 1 
input STYLE  Style_A = DASHDOTDOT_;          //ñòèëü ëèíèè óðîâíÿ 1
input WIDTH  Width_A = Width_1;              //òîëùèíà ëèíèè óðîâíÿ 1
//----
input color  Color_B = clrDarkOrange;        //öâåò óðîâíÿ 2
input STYLE  Style_B = DASH_;                //ñòèëü ëèíèè óðîâíÿ 2
input WIDTH  Width_B = Width_1;              //òîëùèíà ëèíèè óðîâíÿ 2
//----
input color  Color_C = clrMagenta;           //öâåò óðîâíÿ 3
input STYLE  Style_C = SOLID_;               //ñòèëü ëèíèè óðîâíÿ 3
input WIDTH  Width_C = Width_1;              //òîëùèíà ëèíèè óðîâíÿ 3
//----
input color  Color_D = clrRed;               //öâåò óðîâíÿ 4
input STYLE  Style_D = SOLID_;               //ñòèëü ëèíèè óðîâíÿ 4
input WIDTH  Width_D = Width_1;              //òîëùèíà ëèíèè óðîâíÿ 4
//----
input color  Color_E = clrLime;              //öâåò óðîâíÿ 5
input STYLE  Style_E = SOLID_;               //ñòèëü ëèíèè óðîâíÿ 5
input WIDTH  Width_E = Width_1;              //òîëùèíà ëèíèè óðîâíÿ 5
//----
input uint Fontsizex= 2;                     //ðàçìåð öåíîâûõ ìåòîê
input bool ShowLineInfo = true;              //îòîáðàæåíèå çíà÷åíèÿ óðîâíÿ íà öåíîâîì ãðàôèêå
//+--------------------------------------------+
//---- îáúÿâëåíèå äèíàìè÷åñêîãî ìàññèâà, êîòîðûé áóäåò â 
// äàëüíåéøåì èñïîëüçîâàí â êà÷åñòâå èíäèêàòîðíîãî áóôåðà
double ExtLineBuffer0[];
//---- îáúÿâëåíèå äèíàìè÷åñêèõ ìàññèâîâ, êîòîðûå áóäóò â 
// äàëüíåéøåì èñïîëüçîâàíû â êà÷åñòâå èíäèêàòîðíûõ áóôåðîâ óðîâíåé Áîëëèíäæåðà
double UpBuffer1[],DnBuffer1[],UpBuffer2[],DnBuffer2[],UpBuffer3[],DnBuffer3[];
double UpBuffer4[],DnBuffer4[],UpBuffer5[],DnBuffer5[];
//---- Îáúÿâëåíèå ïåðåìåííîé çíà÷åíèÿ âåðòèêàëüíîãî ñäâèãà ìóâèíãà
double dPriceShift;
//---- Îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ íà÷àëà îòñ÷åòà äàííûõ
int min_rates_total,min_rates_1;
//---- Îáúÿâëåíèå ñòðîêîâûõ ïåðåìåííûõ äëÿ òåêñòîâûõ ìåòîê
string upper_name1,middle_name,lower_name1,upper_name2,lower_name2,upper_name3,lower_name3;
//---- Îáúÿâëåíèå ïåðåìåííûõ öåíîâîé ñåòêè
color clr;
STYLE Style;
WIDTH Width;
bool ShowPriceLable;
int middle,sizex,Normalize,Count;
string ObjectNames[];
double PointPow10,PointPow100,PointPow1000,PointPow10000,PointPow100000,PriceGrid[],Price[];
//+------------------------------------------------------------------+   
//| X2MA BBx5 indicator initialization function                      | 
//+------------------------------------------------------------------+ 
int OnInit()
  {
//---- Èíèöèàëèçàöèÿ ïåðåìåííûõ íà÷àëà îòñ÷åòà äàííûõ
   min_rates_1=GetStartBars(XMA_Method,XLength,XPhase)+1;
   min_rates_total=min_rates_1+int(XLength);
//---- óñòàíîâêà àëåðòîâ íà íåäîïóñòèìûå çíà÷åíèÿ âíåøíèõ ïåðåìåííûõ
   XMA1.XMALengthCheck("XLength",XLength);
//---- óñòàíîâêà àëåðòîâ íà íåäîïóñòèìûå çíà÷åíèÿ âíåøíèõ ïåðåìåííûõ
   XMA1.XMAPhaseCheck("XPhase",XPhase,XMA_Method);
//---- Èíèöèàëèçàöèÿ ñäâèãà ïî âåðòèêàëè
   dPriceShift=_Point*PriceShift;
   if(BandsDeviation1>=BandsDeviation2)
     {
      Print("Âõîäíîé ïàðàìåòð Äåâèàöèÿ 2 âñåãäà äîëæåí áûòü áîëüøå âõîäíîãî ïàðàìåòðà Äåâèàöèÿ 1! Èñïðàâüòå çíà÷åíèÿ ýòèõ âõîäíûõ ïàðàìåòðîâ èíäèêàòîðà!");
      return(INIT_FAILED);
     }
   if(BandsDeviation2>=BandsDeviation3)
     {
      Print("Âõîäíîé ïàðàìåòð Äåâèàöèÿ 3 âñåãäà äîëæåí áûòü áîëüøå âõîäíîãî ïàðàìåòðà Äåâèàöèÿ 2! Èñïðàâüòå çíà÷åíèÿ ýòèõ âõîäíûõ ïàðàìåòðîâ èíäèêàòîðà!");
      return(INIT_FAILED);
     }
//---- Èíèöèàëèçàöèÿ ñòðîêîâûõ ïåðåìåííûõ
   upper_name1=SirName+" upper text lable 1";
   middle_name=SirName+" middle text lable";
   lower_name1=SirName+" lower text lable 1";
   upper_name2=SirName+" upper text lable 2";
   lower_name2=SirName+" lower text lable 2";
   upper_name3=SirName+" upper text lable 3";
   lower_name3=SirName+" lower text lable 3";
//---- ðàñïðåäåëåíèå ïàìÿòè ïîä ìàññèâû ïåðåìåííûõ öåíîâîé ñåòêè 
   sizex=int(Total*2);
   ArrayResize(ObjectNames,sizex);
   ArrayResize(PriceGrid,sizex);
   ArrayResize(Price,sizex);
//---- èíèöèàëèçàöèÿ èìåí
   for(Count=0; Count<sizex; Count++) ObjectNames[Count]=SirName+" PriceLine "+string(Count);
//---- èíèöèàëèçàöèÿ ïåðåìåííûõ         
   PointPow10=_Point*MathPow(10,Digit);
   PointPow100=PointPow10*10;
   PointPow1000=PointPow10*100;
   PointPow10000=PointPow10*1000;
   PointPow100000=PointPow10*10000;
   middle=(sizex/2)-1;
   Normalize=int(_Digits-Digit);
//---- èíèöèàëèçàöèÿ ïåðåìåííûõ         
   for(Count=middle; Count<sizex; Count++) PriceGrid[Count]=+NormalizeDouble(PointPow10*(Count-middle),Normalize);
   for(Count=middle-1; Count>=0; Count--) PriceGrid[Count]=-NormalizeDouble(PointPow10*(middle-Count),Normalize);
//---- ïðåâðàùåíèå äèíàìè÷åñêîãî ìàññèâà â èíäèêàòîðíûé áóôåð
   SetIndexBuffer(0,UpBuffer4,INDICATOR_DATA);
   SetIndexBuffer(1,DnBuffer4,INDICATOR_DATA);
   SetIndexBuffer(2,UpBuffer2,INDICATOR_DATA);
   SetIndexBuffer(3,DnBuffer2,INDICATOR_DATA);
   SetIndexBuffer(4,UpBuffer1,INDICATOR_DATA);
   SetIndexBuffer(5,DnBuffer1,INDICATOR_DATA);
   SetIndexBuffer(6,ExtLineBuffer0,INDICATOR_DATA);
   SetIndexBuffer(7,UpBuffer3,INDICATOR_DATA);
   SetIndexBuffer(8,DnBuffer3,INDICATOR_DATA);
   SetIndexBuffer(9,UpBuffer5,INDICATOR_DATA);
   SetIndexBuffer(10,DnBuffer5,INDICATOR_DATA);
//---- îñóùåñòâëåíèå ñäâèãà èíäèêàòîðà ïî ãîðèçîíòàëè
   PlotIndexSetInteger(0,PLOT_SHIFT,Shift);
   PlotIndexSetInteger(1,PLOT_SHIFT,Shift);
   PlotIndexSetInteger(2,PLOT_SHIFT,Shift);
   PlotIndexSetInteger(3,PLOT_SHIFT,Shift);
   PlotIndexSetInteger(4,PLOT_SHIFT,Shift);
   PlotIndexSetInteger(5,PLOT_SHIFT,Shift);
//---- îñóùåñòâëåíèå ñäâèãà íà÷àëà îòñ÷åòà îòðèñîâêè èíäèêàòîðà
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,min_rates_total);
   PlotIndexSetInteger(2,PLOT_DRAW_BEGIN,min_rates_total);
   PlotIndexSetInteger(3,PLOT_DRAW_BEGIN,min_rates_total);
   PlotIndexSetInteger(4,PLOT_DRAW_BEGIN,min_rates_total);

//---- èíèöèàëèçàöèÿ ïåðåìåííîé äëÿ êîðîòêîãî èìåíè èíäèêàòîðà
   string shortname;
   string Smooth=XMA1.GetString_MA_Method(XMA_Method);
   StringConcatenate(shortname,"XMA_Bollinger Bands(",Smooth,", ",XLength,", ",DoubleToString(BandsDeviation1,2),", ",
                     DoubleToString(BandsDeviation2,2),", ",DoubleToString(BandsDeviation3,2),")");
//--- ñîçäàíèå èìåíè äëÿ îòîáðàæåíèÿ â îòäåëüíîì ïîäîêíå è âî âñïëûâàþùåé ïîäñêàçêå
   IndicatorSetString(INDICATOR_SHORTNAME,shortname);

//--- îïðåäåëåíèå òî÷íîñòè îòîáðàæåíèÿ çíà÷åíèé èíäèêàòîðà
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits+1);
//--- çàâåðøåíèå èíèöèàëèçàöèè
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+    
void OnDeinit(const int reason)
  {
//----
   ObjectDelete(0,upper_name1);
   ObjectDelete(0,middle_name);
   ObjectDelete(0,lower_name1);
   ObjectDelete(0,upper_name2);
   ObjectDelete(0,lower_name2);
   ObjectDelete(0,upper_name3);
   ObjectDelete(0,lower_name3);
   for(Count=0; Count<sizex; Count++) ObjectDelete(0,ObjectNames[Count]);
//----
   ChartRedraw(0);
  }
//+------------------------------------------------------------------+ 
//| X2MA BBx5 iteration function                                     | 
//+------------------------------------------------------------------+ 
int OnCalculate(
                const int rates_total,    // êîëè÷åñòâî èñòîðèè â áàðàõ íà òåêóùåì òèêå
                const int prev_calculated,// êîëè÷åñòâî èñòîðèè â áàðàõ íà ïðåäûäóùåì òèêå
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[]
                )
  {
//---- ïðîâåðêà êîëè÷åñòâà áàðîâ íà äîñòàòî÷íîñòü äëÿ ðàñ÷åòà
   if(rates_total<min_rates_total) return(0);
//---- èíäåêñàöèÿ ýëåìåíòîâ â ìàññèâàõ êàê â òàéìñåðèÿõ
   ArraySetAsSeries(close,false);
   ArraySetAsSeries(time,false);
//----
   double res=NormalizeDouble(PointPow10*MathCeil(close[rates_total-1]/PointPow10),Normalize);
   if(prev_calculated!=rates_total)
     {
      for(Count=0; Count<sizex; Count++) ObjectDelete(0,ObjectNames[Count]);
     }
   for(Count=0; Count<sizex; Count++) Price[Count]=NormalizeDouble(res+PriceGrid[Count],Normalize);
   datetime time0=time[rates_total-1]+PeriodSeconds()*Shift;
   datetime timeX=time[0];
   for(Count=0; Count<sizex; Count++)
     {
      string info="";
      if(ShowLineInfo) info=ObjectNames[Count]+" "+DoubleToString(Price[Count],Normalize);
      
      if(!NormalizeDouble(Price[Count]-PointPow100000*MathCeil(Price[Count]/PointPow100000),Normalize))
        {
         SetTline(0,ObjectNames[Count],0,timeX,Price[Count],time0,Price[Count],Color_E,Style_E,Width_E,info);
        }
      else if(!NormalizeDouble(Price[Count]-PointPow10000*MathCeil(Price[Count]/PointPow10000),Normalize))
        {
         SetTline(0,ObjectNames[Count],0,timeX,Price[Count],time0,Price[Count],Color_D,Style_D,Width_D,info);
        }
      else if(!NormalizeDouble(Price[Count]-PointPow1000*MathCeil(Price[Count]/PointPow1000),Normalize))
        {
         SetTline(0,ObjectNames[Count],0,timeX,Price[Count],time0,Price[Count],Color_C,Style_C,Width_C,info);
        }
      else  if(!NormalizeDouble(Price[Count]-PointPow100*MathCeil(Price[Count]/PointPow100),Normalize))
        {
         SetTline(0,ObjectNames[Count],0,timeX,Price[Count],time0,Price[Count],Color_B,Style_B,Width_B,info);
        }
      else
        {
         SetTline(0,ObjectNames[Count],0,timeX,Price[Count],time0,Price[Count],Color_A,Style_A,Width_A,info);
        }
     }
//---- èíäåêñàöèÿ ýëåìåíòîâ â ìàññèâàõ íå êàê â òàéìñåðèÿõ
   ArraySetAsSeries(close,false);
   ArraySetAsSeries(time,false);
//---- Îáúÿâëåíèå ïåðåìåííûõ ñ ïëàâàþùåé òî÷êîé  
   double price,xma,line,stdev;
//---- Îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ è ïîëó÷åíèå óæå ïîñ÷èòàííûõ áàðîâ
   int first,bar;
//---- ðàñ÷åò ñòàðòîâîãî íîìåðà first äëÿ öèêëà ïåðåñ÷åòà áàðîâ
   if(prev_calculated>rates_total || prev_calculated<=0) // ïðîâåðêà íà ïåðâûé ñòàðò ðàñ÷åòà èíäèêàòîðà
      first=0; // ñòàðòîâûé íîìåð äëÿ ðàñ÷åòà âñåõ áàðîâ
   else first=prev_calculated-1; // ñòàðòîâûé íîìåð äëÿ ðàñ÷åòà íîâûõ áàðîâ
//---- Îñíîâíîé öèêë ðàñ÷åòà èíäèêàòîðà
   for(bar=first; bar<rates_total && !IsStopped(); bar++)
     {
      price=PriceSeries(IPC,bar,open,low,high,close);
      xma=XMA1.XMASeries(0,prev_calculated,rates_total,XMA_Method,XPhase,XLength,price,bar,false);
      line=xma+dPriceShift;
      ExtLineBuffer0[bar]=PointPow10*MathRound((xma+dPriceShift)/PointPow10);
      //---- ðàñ÷åò è îêðóãëåíèå Áîëëèíäæåðà 1
      stdev=STD1.StdDevSeries(min_rates_1,prev_calculated,rates_total,XLength,BandsDeviation1,price,xma,bar,false);
      UpBuffer1[bar]=DnBuffer2[bar]=PointPow10*MathCeil((line+stdev)/PointPow10);
      DnBuffer1[bar]=UpBuffer3[bar]=PointPow10*MathFloor((line-stdev)/PointPow10);
      //---- èñïðàâëåíèå Áîëëèíäæåðà 1
      if(ExtLineBuffer0[bar]>=UpBuffer1[bar]) UpBuffer1[bar]=DnBuffer2[bar]=ExtLineBuffer0[bar]+PointPow10;
      if(ExtLineBuffer0[bar]<=DnBuffer1[bar]) DnBuffer1[bar]=UpBuffer3[bar]=ExtLineBuffer0[bar]-PointPow10;
      //---- ðàñ÷åò è îêðóãëåíèå Áîëëèíäæåðà 2
      stdev=STD2.StdDevSeries(min_rates_1,prev_calculated,rates_total,XLength,BandsDeviation2,price,xma,bar,false);
      UpBuffer2[bar]=DnBuffer4[bar]=PointPow10*MathCeil((line+stdev)/PointPow10);
      DnBuffer3[bar]=UpBuffer5[bar]=PointPow10*MathFloor((line-stdev)/PointPow10);
      //---- èñïðàâëåíèå Áîëëèíäæåðà 2
      if(UpBuffer1[bar]>=UpBuffer2[bar]) UpBuffer2[bar]=DnBuffer4[bar]=UpBuffer1[bar]+PointPow10;
      if(DnBuffer1[bar]<=DnBuffer3[bar]) DnBuffer3[bar]=UpBuffer5[bar]=DnBuffer1[bar]-PointPow10;
      //---- ðàñ÷åò è îêðóãëåíèå Áîëëèíäæåðà 3        
      stdev=STD3.StdDevSeries(min_rates_1,prev_calculated,rates_total,XLength,BandsDeviation3,price,xma,bar,false);
      UpBuffer4[bar]=PointPow10*MathCeil((line+stdev)/PointPow10);
      DnBuffer5[bar]=PointPow10*MathFloor((line-stdev)/PointPow10);
      //---- èñïðàâëåíèå Áîëëèíäæåðà 3
      if(UpBuffer2[bar]>=UpBuffer4[bar]) UpBuffer4[bar]=UpBuffer2[bar]+PointPow10;
      if(DnBuffer3[bar]<=DnBuffer5[bar]) DnBuffer5[bar]=DnBuffer3[bar]-PointPow10;
     }
   if(ShowPrice)
     {
      int bar0=rates_total-1;
      time0=time[bar0]+Shift*PeriodSeconds();
      SetRightPrice(0,middle_name,0,time0,ExtLineBuffer0[bar0],Middle_color,"Georgia");
      SetRightPrice(0,upper_name1,0,time0,UpBuffer1[bar0],Upper_color1,"Georgia");
      SetRightPrice(0,lower_name1,0,time0,DnBuffer1[bar0],Lower_color1,"Georgia");
      SetRightPrice(0,upper_name2,0,time0,UpBuffer2[bar0],Upper_color2,"Georgia");
      SetRightPrice(0,lower_name2,0,time0,DnBuffer3[bar0],Lower_color2,"Georgia");
      SetRightPrice(0,upper_name3,0,time0,UpBuffer4[bar0],Upper_color3,"Georgia");
      SetRightPrice(0,lower_name3,0,time0,DnBuffer5[bar0],Lower_color3,"Georgia");
     }
//----
   ChartRedraw(0);
   return(rates_total);
  }
//+------------------------------------------------------------------+
//|  RightPrice creation                                             |
//+------------------------------------------------------------------+
void CreateRightPrice(long chart_id,// chart ID
                      string   name,              // object name
                      int      nwin,              // window index
                      datetime time,              // price level time
                      double   price,             // price level
                      color    Color,             // Text color
                      string   Font               // Text font
                      )
//---- 
  {
//----
   ObjectCreate(chart_id,name,OBJ_ARROW_RIGHT_PRICE,nwin,time,price);
   ObjectSetInteger(chart_id,name,OBJPROP_COLOR,Color);
   ObjectSetString(chart_id,name,OBJPROP_FONT,Font);
   ObjectSetInteger(chart_id,name,OBJPROP_BACK,true);
   ObjectSetInteger(chart_id,name,OBJPROP_WIDTH,2);
//----
  }
//+------------------------------------------------------------------+
//|  RightPrice reinstallation                                       |
//+------------------------------------------------------------------+
void SetRightPrice(long chart_id,// chart ID
                   string   name,              // object name
                   int      nwin,              // window index
                   datetime time,              // price level time
                   double   price,             // price level
                   color    Color,             // Text color
                   string   Font               // Text font
                   )
//---- 
  {
//----
   if(ObjectFind(chart_id,name)==-1) CreateRightPrice(chart_id,name,nwin,time,price,Color,Font);
   else ObjectMove(chart_id,name,0,time,price);
//----
  }
//+------------------------------------------------------------------+
//|  Ñîçäàíèå òðåíäîâîé ëèíèè                                        |
//+------------------------------------------------------------------+
void CreateTline(
                 long     chart_id,      // èäåíòèôèêàòîð ãðàôèêà
                 string   name,          // èìÿ îáúåêòà
                 int      nwin,          // èíäåêñ îêíà
                 datetime time1,         // âðåìÿ 1 öåíîâîãî óðîâíÿ
                 double   price1,        // 1 öåíîâîé óðîâåíü
                 datetime time2,         // âðåìÿ 2 öåíîâîãî óðîâíÿ
                 double   price2,        // 2 öåíîâîé óðîâåíü
                 color    Color,         // öâåò ëèíèè
                 int      style,         // ñòèëü ëèíèè
                 int      width,         // òîëùèíà ëèíèè
                 string   text           // òåêñò
                 )
//---- 
  {
//----
   ObjectCreate(chart_id,name,OBJ_TREND,nwin,time1,price1,time2,price2);
   ObjectSetInteger(chart_id,name,OBJPROP_COLOR,Color);
   ObjectSetInteger(chart_id,name,OBJPROP_STYLE,style);
   ObjectSetInteger(chart_id,name,OBJPROP_WIDTH,width);
   ObjectSetString(chart_id,name,OBJPROP_TEXT,text);
   ObjectSetInteger(chart_id,name,OBJPROP_BACK,true);
   ObjectSetInteger(chart_id,name,OBJPROP_RAY_RIGHT,false);
   ObjectSetInteger(chart_id,name,OBJPROP_SELECTED,false);
   ObjectSetInteger(chart_id,name,OBJPROP_SELECTABLE,false);
   ObjectSetInteger(chart_id,name,OBJPROP_ZORDER,true);
//----
  }
//+------------------------------------------------------------------+
//|  Ïåðåóñòàíîâêà òðåíäîâîé ëèíèè                                   |
//+------------------------------------------------------------------+
void SetTline(
              long     chart_id,      // èäåíòèôèêàòîð ãðàôèêà
              string   name,          // èìÿ îáúåêòà
              int      nwin,          // èíäåêñ îêíà
              datetime time1,         // âðåìÿ 1 öåíîâîãî óðîâíÿ
              double   price1,        // 1 öåíîâîé óðîâåíü
              datetime time2,         // âðåìÿ 2 öåíîâîãî óðîâíÿ
              double   price2,        // 2 öåíîâîé óðîâåíü
              color    Color,         // öâåò ëèíèè
              int      style,         // ñòèëü ëèíèè
              int      width,         // òîëùèíà ëèíèè
              string   text           // òåêñò
              )
//---- 
  {
//----
   if(ObjectFind(chart_id,name)==-1) CreateTline(chart_id,name,nwin,time1,price1,time2,price2,Color,style,width,text);
   else
     {
      ObjectSetString(chart_id,name,OBJPROP_TEXT,text);
      ObjectMove(chart_id,name,0,time1,price1);
      ObjectMove(chart_id,name,1,time2,price2);
      ObjectSetInteger(chart_id,name,OBJPROP_COLOR,Color);
      ObjectSetInteger(chart_id,name,OBJPROP_STYLE,style);
      ObjectSetInteger(chart_id,name,OBJPROP_WIDTH,width);
     }
//----
  }
//+------------------------------------------------------------------+