XEnvelopes_Digit_Grid

//+---------------------------------------------------------------------+
//|                                           XEnvelopes_Digit_Grid.mq5 |
//|                                  Copyright © 2016, Nikolay Kositsin | 
//|                                 Khabarovsk,   farria@mail.redcom.ru | 
//+---------------------------------------------------------------------+ 
//| Äëÿ ðàáîòû  èíäèêàòîðà  ñëåäóåò  ïîëîæèòü ôàéë SmoothAlgorithms.mqh |
//| â ïàïêó (äèðåêòîðèþ): êàòàëîã_äàííûõ_òåðìèíàëà\\MQL5\Include        |
//+---------------------------------------------------------------------+
#property copyright "Copyright © 2016, Nikolay Kositsin"
#property link "farria@mail.redcom.ru"
#property description ""
//---- íîìåð âåðñèè èíäèêàòîðà
#property version   "1.00"
//---- îòðèñîâêà èíäèêàòîðà â ãëàâíîì îêíå
#property indicator_chart_window 
//---- êîëè÷åñòâî èíäèêàòîðíûõ áóôåðîâ 4
#property indicator_buffers 4 
//---- èñïîëüçîâàíî âñåãî òðè ãðàôè÷åñêèõ ïîñòðîåíèÿ
#property indicator_plots   3
//+----------------------------------------------+
//|  Ïàðàìåòðû îòðèñîâêè îáëàêà                  |
//+----------------------------------------------+
//---- îòðèñîâêà èíäèêàòîðà â âèäå öâåòíîãî îáëàêà
#property indicator_type1   DRAW_FILLING
//---- â êà÷åñòâå öâåòà îáëàêà èñïîëüçîâàí
#property indicator_color1  clrLavender
//---- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label1  "XEnvelopes Cloud"
//+----------------------------------------------+
//|  Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà óðîâíåé      |
//+----------------------------------------------+
//---- îòðèñîâêà óðîâíåé â âèäå ëèíèé
#property indicator_type2   DRAW_LINE
#property indicator_type3   DRAW_LINE
//---- ââûáîð öâåòîâ óðîâíåé
#property indicator_color2  clrLimeGreen
#property indicator_color3  clrDeepPink
//---- óðîâíè - íåïðåðûâíûå êðèâûå
#property indicator_style2 STYLE_SOLID
#property indicator_style3 STYLE_SOLID
//---- òîëùèíà óðîâíåé ðàâíà 2
#property indicator_width2  2
#property indicator_width3  2
//---- îòîáðàæåíèå ìåòîê óðîâíåé
#property indicator_label2  "Upper XEnvelopes"
#property indicator_label3  "Lower XEnvelopes"
//+----------------------------------------------+
//|  Îïèñàíèå êëàññà CXMA                        |
//+----------------------------------------------+
#include <SmoothAlgorithms.mqh> 
//+----------------------------------------------+
//---- îáúÿâëåíèå ïåðåìåííûõ êëàññà CXMA èç ôàéëà SmoothAlgorithms.mqh
CXMA XMA1;
//+----------------------------------------------+
//|  îáúÿâëåíèå ïåðå÷èñëåíèé                     |
//+----------------------------------------------+
enum Applied_price_      //Òèï êîíñòàíòû
  {
   PRICE_CLOSE_ = 1,     //Close
   PRICE_OPEN_,          //Open
   PRICE_HIGH_,          //High
   PRICE_LOW_,           //Low
   PRICE_MEDIAN_,        //Median Price (HL/2)
   PRICE_TYPICAL_,       //Typical Price (HLC/3)
   PRICE_WEIGHTED_,      //Weighted Close (HLCC/4)
   PRICE_SIMPL_,         //Simpl Price (OC/2)
   PRICE_QUARTER_,       //Quarted Price (HLOC/4) 
   PRICE_TRENDFOLLOW0_,  //TrendFollow_1 Price 
   PRICE_TRENDFOLLOW1_,  //TrendFollow_2 Price
   PRICE_DEMARK_         //Demark Price
  };
//+----------------------------------------------+
//|  îáúÿâëåíèå ïåðå÷èñëåíèé                     |
//+----------------------------------------------+
/*enum SmoothMethod - ïåðå÷èñëåíèå îáúÿâëåíî â ôàéëå SmoothAlgorithms.mqh
  {
   MODE_SMA_,  //SMA
   MODE_EMA_,  //EMA
   MODE_SMMA_, //SMMA
   MODE_LWMA_, //LWMA
   MODE_JJMA,  //JJMA
   MODE_JurX,  //JurX
   MODE_ParMA, //ParMA
   MODE_T3,    //T3
   MODE_VIDYA, //VIDYA
   MODE_AMA,   //AMA
  }; */
//+----------------------------------------------+
//|  îáúÿâëåíèå ïåðå÷èñëåíèé                     |
//+----------------------------------------------+
enum WIDTH
  {
   Width_1=1, //1
   Width_2,   //2
   Width_3,   //3
   Width_4,   //4
   Width_5    //5
  };
//+----------------------------------------------+
//|  îáúÿâëåíèå ïåðå÷èñëåíèé                     |
//+----------------------------------------------+
enum STYLE
  {
   SOLID_,//Ñïëîøíàÿ ëèíèÿ
   DASH_,//Øòðèõîâàÿ ëèíèÿ
   DOT_,//Ïóíêòèðíàÿ ëèíèÿ
   DASHDOT_,//Øòðèõ-ïóíêòèðíàÿ ëèíèÿ
   DASHDOTDOT_   //Øòðèõ-ïóíêòèðíàÿ ëèíèÿ ñ äâîéíûìè òî÷êàìè
  };
//+----------------------------------------------+
//| Âõîäíûå ïàðàìåòðû èíäèêàòîðà                 |
//+----------------------------------------------+
input string  SirName="XEnvelopes_Digit_Grid";     //Ïåðâàÿ ÷àñòü èìåíè ãðàôè÷åñêèõ îáúåêòîâ
input Smooth_Method XMA_Method=MODE_SMA_; //ìåòîä óñðåäíåíèÿ
input uint XLength=12;                    //ãëóáèíà ñãëàæèâàíèÿ                    
input int XPhase=15;                      //ïàðàìåòð ñãëàæèâàíèÿ,
//---- äëÿ JJMA èçìåíÿþùèéñÿ â ïðåäåëàõ -100 ... +100, âëèÿåò íà êà÷åñòâî ïåðåõîäíîãî ïðîöåññà;
//---- Äëÿ VIDIA ýòî ïåðèîä CMO, äëÿ AMA ýòî ïåðèîä ìåäëåííîé ñêîëüçÿùåé
input Applied_price_ IPC=PRICE_CLOSE_;    //öåíîâàÿ êîíñòàíòà
input double Deviation=0.1;               // Äåâèàöèÿ
input uint Digit=2;                       //êîëè÷åñòâî ðàçðÿäîâ îêðóãëåíèÿ
input int Shift=0;                        //ñäâèã èíäèêàòîðà ïî ãîðèçîíòàëè â áàðàõ
input int PriceShift=0;                   //cäâèã èíäèêàòîðà ïî âåðòèêàëè â ïóíêòàõ
input bool ShowPrice=true;                //ïîêàçûâàòü öåíîâûå ìåòêè
//---- öâåòà öåíîâûõ ìåòîê
input color  Upper_color=clrMediumSeaGreen;
input color  Lower_color=clrRed;
//---- Ïàðàìåòðû öåíîâîé ñåòêè
input uint  Total=200;                       //êîëè÷åñòâî áëîêîâ ñåòêè ñâåðõó èëè ñíèçó îò öåíû
//----
input color  Color_A = clrSlateBlue;         //öâåò óðîâíÿ 1 
input STYLE  Style_A = DASHDOTDOT_;          //ñòèëü ëèíèè óðîâíÿ 1
input WIDTH  Width_A = Width_1;              //òîëùèíà ëèíèè óðîâíÿ 1
//----
input color  Color_B = clrDarkOrange;        //öâåò óðîâíÿ 2
input STYLE  Style_B = DASH_;                //ñòèëü ëèíèè óðîâíÿ 2
input WIDTH  Width_B = Width_1;              //òîëùèíà ëèíèè óðîâíÿ 2
//----
input color  Color_C = clrMagenta;           //öâåò óðîâíÿ 3
input STYLE  Style_C = SOLID_;               //ñòèëü ëèíèè óðîâíÿ 3
input WIDTH  Width_C = Width_1;              //òîëùèíà ëèíèè óðîâíÿ 3
//----
input color  Color_D = clrRed;               //öâåò óðîâíÿ 4
input STYLE  Style_D = SOLID_;               //ñòèëü ëèíèè óðîâíÿ 4
input WIDTH  Width_D = Width_1;              //òîëùèíà ëèíèè óðîâíÿ 4
//----
input color  Color_E = clrLime;              //öâåò óðîâíÿ 5
input STYLE  Style_E = SOLID_;               //ñòèëü ëèíèè óðîâíÿ 5
input WIDTH  Width_E = Width_1;              //òîëùèíà ëèíèè óðîâíÿ 5
//----
input bool ShowLineInfo = true;              //îòîáðàæåíèå çíà÷åíèÿ óðîâíÿ íà öåíîâîì ãðàôèêå
//+----------------------------------------------+
//---- îáúÿâëåíèå äèíàìè÷åñêèõ ìàññèâîâ, êîòîðûå áóäóò â 
// äàëüíåéøåì èñïîëüçîâàíû â êà÷åñòâå èíäèêàòîðíûõ áóôåðîâ
double UpBuffer[],DnBuffer[],UpLineBuffer[],DnLineBuffer[];
//---- Îáúÿâëåíèå ïåðåìåííûõ çíà÷åíèÿ âåðòèêàëüíîãî ñäâèãà ìóâèíãà è êîýôôèöèåíòîâ äåâèàöèè
double dPriceShift,UpKdev,DnKdev;
//---- Îáúÿâëåíèå öåëûõ ïåðåìåííûõ íà÷àëà îòñ÷¸òà äàííûõ
int min_rates_total;
//---- Îáúÿâëåíèå ñòðèíãîâ äëÿ òåêñòîâûõ ìåòîê
string upper_name,lower_name;
//---- Îáúÿâëåíèå ïåðåìåííûõ öåíîâîé ñåòêè
color clr;
STYLE Style;
WIDTH Width;
bool ShowPriceLable;
int middle,sizex,Normalize,Count;
string ObjectNames[];
double PointPow10,PointPow100,PointPow1000,PointPow10000,PointPow100000,PriceGrid[],Price[];
//+------------------------------------------------------------------+   
//| Custom indicator initialization function                         | 
//+------------------------------------------------------------------+ 
void OnInit()
  {
//---- Èíèöèàëèçàöèÿ ïåðåìåííûõ íà÷àëà îòñ÷¸òà äàííûõ
   min_rates_total=XMA1.GetStartBars(XMA_Method,XLength,XPhase);
//---- óñòàíîâêà àëåðòîâ íà íåäîïóñòèìûå çíà÷åíèÿ âíåøíèõ ïåðåìåííûõ
   XMA1.XMALengthCheck("XLength",XLength);
   XMA1.XMAPhaseCheck("XPhase",XPhase,XMA_Method);
//---- Èíèöèàëèçàöèÿ ñäâèãà ïî âåðòèêàëè
   dPriceShift=_Point*PriceShift;
//---- Èíèöèàëèçàöèÿ êîýôôèöèåíòà äåâèàöèè  
   UpKdev=(1+Deviation/100.0);
   DnKdev=(1-Deviation/100.0);
   PointPow10=_Point*MathPow(10,Digit);
//---- Èíèöèàëèçàöèÿ ñòðèíãîâ
   upper_name="XEnvelopes upper text lable";
   lower_name="XEnvelopes lower text lable";
//---- ðàñïðåäåëåíèå ïàìÿòè ïîä ìàññèâû ïåðåìåííûõ öåíîâîé ñåòêè 
   sizex=int(Total*2);
   ArrayResize(ObjectNames,sizex);
   ArrayResize(PriceGrid,sizex);
   ArrayResize(Price,sizex);
//---- èíèöèàëèçàöèÿ èì¸í
   for(Count=0; Count<sizex; Count++) ObjectNames[Count]=SirName+" PriceLine "+string(Count);
//---- èíèöèàëèçàöèÿ ïåðåìåííûõ         
   PointPow10=_Point*MathPow(10,Digit);
   PointPow100=PointPow10*10;
   PointPow1000=PointPow10*100;
   PointPow10000=PointPow10*1000;
   PointPow100000=PointPow10*10000;
   middle=(sizex/2)-1;
   Normalize=int(_Digits-Digit);
//---- èíèöèàëèçàöèÿ ïåðåìåííûõ         
   for(Count=middle; Count<sizex; Count++) PriceGrid[Count]=+NormalizeDouble(PointPow10*(Count-middle),Normalize);
   for(Count=middle-1; Count>=0; Count--) PriceGrid[Count]=-NormalizeDouble(PointPow10*(middle-Count),Normalize);
//---- ïðåâðàùåíèå äèíàìè÷åñêîãî ìàññèâà â èíäèêàòîðíûé áóôåð
   SetIndexBuffer(0,UpBuffer,INDICATOR_DATA);
//---- ïðåâðàùåíèå äèíàìè÷åñêîãî ìàññèâà â èíäèêàòîðíûé áóôåð
   SetIndexBuffer(1,DnBuffer,INDICATOR_DATA);
//---- îñóùåñòâëåíèå ñäâèãà èíäèêàòîðà 1 ïî ãîðèçîíòàëè
   PlotIndexSetInteger(0,PLOT_SHIFT,Shift);
//---- îñóùåñòâëåíèå ñäâèãà íà÷àëà îòñ÷¸òà îòðèñîâêè èíäèêàòîðà
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
//---- óñòàíîâêà çíà÷åíèé èíäèêàòîðà, êîòîðûå íå áóäóò âèäèìû íà ãðàôèêå
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,EMPTY_VALUE);

//---- ïðåâðàùåíèå äèíàìè÷åñêèõ ìàññèâîâ â èíäèêàòîðíûå áóôåðû
   SetIndexBuffer(2,UpLineBuffer,INDICATOR_DATA);
   SetIndexBuffer(3,DnLineBuffer,INDICATOR_DATA);
//---- óñòàíîâêà ïîçèöèè, ñ êîòîðîé íà÷èíàåòñÿ îòðèñîâêà óðîâíåé
   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,min_rates_total);
//---- çàïðåò íà îòðèñîâêó èíäèêàòîðîì ïóñòûõ çíà÷åíèé
   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,EMPTY_VALUE);

//--- ñîçäàíèå èìåíè äëÿ îòîáðàæåíèÿ â îòäåëüíîì ïîäîêíå è âî âñïëûâàþùåé ïîäñêàçêå
   IndicatorSetString(INDICATOR_SHORTNAME,"Env("+string(XLength)+")");
   PlotIndexSetString(0,PLOT_LABEL,"Env("+string(XLength)+")Cloud");
   PlotIndexSetString(1,PLOT_LABEL,"Env("+string(XLength)+")Upper");
   PlotIndexSetString(2,PLOT_LABEL,"Env("+string(XLength)+")Lower");

//--- îïðåäåëåíèå òî÷íîñòè îòîáðàæåíèÿ çíà÷åíèé èíäèêàòîðà
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits+1);
//---- çàâåðøåíèå èíèöèàëèçàöèè
  }
//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+    
void OnDeinit(const int reason)
  {
//----
   ObjectDelete(0,upper_name);
   ObjectDelete(0,lower_name);
   for(Count=0; Count<sizex; Count++) ObjectDelete(0,ObjectNames[Count]);
//----
   ChartRedraw(0);
  }
//+------------------------------------------------------------------+ 
//| Custom indicator iteration function                              | 
//+------------------------------------------------------------------+ 
int OnCalculate(
                const int rates_total,    // êîëè÷åñòâî èñòîðèè â áàðàõ íà òåêóùåì òèêå
                const int prev_calculated,// êîëè÷åñòâî èñòîðèè â áàðàõ íà ïðåäûäóùåì òèêå
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[]
                )
  {
//---- ïðîâåðêà êîëè÷åñòâà áàðîâ íà äîñòàòî÷íîñòü äëÿ ðàñ÷¸òà
   if(rates_total<min_rates_total) return(0);
//---- èíäåêñàöèÿ ýëåìåíòîâ â ìàññèâàõ êàê â òàéìñåðèÿõ
   ArraySetAsSeries(close,false);
   ArraySetAsSeries(time,false);

   double res=NormalizeDouble(PointPow10*MathCeil(close[rates_total-1]/PointPow10),Normalize);
   if(prev_calculated!=rates_total)
     {
      for(Count=0; Count<sizex; Count++) ObjectDelete(0,ObjectNames[Count]);
     }
   for(Count=0; Count<sizex; Count++) Price[Count]=NormalizeDouble(res+PriceGrid[Count],Normalize);
   datetime time0=time[rates_total-1]+PeriodSeconds()*Shift;
   datetime timeX=time[0];
   for(Count=0; Count<sizex; Count++)
     {
      string info="";
      if(ShowLineInfo) info=ObjectNames[Count]+" "+DoubleToString(Price[Count],Normalize);
      
      if(!NormalizeDouble(Price[Count]-PointPow100000*MathCeil(Price[Count]/PointPow100000),Normalize))
        {
         SetTline(0,ObjectNames[Count],0,timeX,Price[Count],time0,Price[Count],Color_E,Style_E,Width_E,info);
        }
      else if(!NormalizeDouble(Price[Count]-PointPow10000*MathCeil(Price[Count]/PointPow10000),Normalize))
        {
         SetTline(0,ObjectNames[Count],0,timeX,Price[Count],time0,Price[Count],Color_D,Style_D,Width_D,info);
        }
      else if(!NormalizeDouble(Price[Count]-PointPow1000*MathCeil(Price[Count]/PointPow1000),Normalize))
        {
         SetTline(0,ObjectNames[Count],0,timeX,Price[Count],time0,Price[Count],Color_C,Style_C,Width_C,info);
        }
      else  if(!NormalizeDouble(Price[Count]-PointPow100*MathCeil(Price[Count]/PointPow100),Normalize))
        {
         SetTline(0,ObjectNames[Count],0,timeX,Price[Count],time0,Price[Count],Color_B,Style_B,Width_B,info);
        }
      else
        {
         SetTline(0,ObjectNames[Count],0,timeX,Price[Count],time0,Price[Count],Color_A,Style_A,Width_A,info);
        }
     }

//---- èíäåêñàöèÿ ýëåìåíòîâ â ìàññèâàõ íå êàê â òàéìñåðèÿõ
   ArraySetAsSeries(close,false);
   ArraySetAsSeries(time,false);

//---- Îáúÿâëåíèå ïåðåìåííûõ ñ ïëàâàþùåé òî÷êîé  
   double price,xma;
//---- Îáúÿâëåíèå öåëûõ ïåðåìåííûõ è ïîëó÷åíèå óæå ïîñ÷èòàííûõ áàðîâ
   int first,bar;

//---- ðàñ÷¸ò ñòàðòîâîãî íîìåðà first äëÿ öèêëà ïåðåñ÷¸òà áàðîâ
   if(prev_calculated>rates_total || prev_calculated<=0) // ïðîâåðêà íà ïåðâûé ñòàðò ðàñ÷¸òà èíäèêàòîðà
      first=0; // ñòàðòîâûé íîìåð äëÿ ðàñ÷¸òà âñåõ áàðîâ
   else first=prev_calculated-1; // ñòàðòîâûé íîìåð äëÿ ðàñ÷¸òà íîâûõ áàðîâ

//---- Îñíîâíîé öèêë ðàñ÷¸òà èíäèêàòîðà
   for(bar=first; bar<rates_total && !IsStopped(); bar++)
     {
      price=PriceSeries(IPC,bar,open,low,high,close);
      xma=XMA1.XMASeries(0,prev_calculated,rates_total,XMA_Method,XPhase,XLength,price,bar,false);      
      UpBuffer[bar]=UpLineBuffer[bar]=PointPow10*MathCeil((UpKdev*xma)/PointPow10)+dPriceShift;
      DnBuffer[bar]=DnLineBuffer[bar]=PointPow10*MathFloor((DnKdev*xma)/PointPow10)+dPriceShift;
     }
   if(ShowPrice)
     {
      int bar0=rates_total-1;
      time0=time[bar0]+Shift*PeriodSeconds();
      SetRightPrice(0,upper_name,0,time0,UpBuffer[bar0],Upper_color);
      SetRightPrice(0,lower_name,0,time0,DnBuffer[bar0],Lower_color);
     }
//----
   ChartRedraw(0);     
   return(rates_total);
  }
//+------------------------------------------------------------------+
//|  RightPrice creation                                             |
//+------------------------------------------------------------------+
void CreateRightPrice(long chart_id,// chart ID
                      string   name,              // object name
                      int      nwin,              // window index
                      datetime time,              // price level time
                      double   price,             // price level
                      color    Color              // Text color
                      )
//---- 
  {
//----
   ObjectCreate(chart_id,name,OBJ_ARROW_RIGHT_PRICE,nwin,time,price);
   ObjectSetInteger(chart_id,name,OBJPROP_COLOR,Color);
   ObjectSetInteger(chart_id,name,OBJPROP_BACK,true);
   ObjectSetInteger(chart_id,name,OBJPROP_WIDTH,2);
//----
  }
//+------------------------------------------------------------------+
//|  RightPrice reinstallation                                       |
//+------------------------------------------------------------------+
void SetRightPrice(long chart_id,// chart ID
                   string   name,              // object name
                   int      nwin,              // window index
                   datetime time,              // price level time
                   double   price,             // price level
                   color    Color              // Text color
                   )
//---- 
  {
//----
   if(ObjectFind(chart_id,name)==-1) CreateRightPrice(chart_id,name,nwin,time,price,Color);
   else ObjectMove(chart_id,name,0,time,price);
//----
  }
//+------------------------------------------------------------------+
//|  Ñîçäàíèå òðåíäîâîé ëèíèè                                        |
//+------------------------------------------------------------------+
void CreateTline(
                 long     chart_id,      // èäåíòèôèêàòîð ãðàôèêà
                 string   name,          // èìÿ îáúåêòà
                 int      nwin,          // èíäåêñ îêíà
                 datetime time1,         // âðåìÿ 1 öåíîâîãî óðîâíÿ
                 double   price1,        // 1 öåíîâîé óðîâåíü
                 datetime time2,         // âðåìÿ 2 öåíîâîãî óðîâíÿ
                 double   price2,        // 2 öåíîâîé óðîâåíü
                 color    Color,         // öâåò ëèíèè
                 int      style,         // ñòèëü ëèíèè
                 int      width,         // òîëùèíà ëèíèè
                 string   text           // òåêñò
                 )
//---- 
  {
//----
   ObjectCreate(chart_id,name,OBJ_TREND,nwin,time1,price1,time2,price2);
   ObjectSetInteger(chart_id,name,OBJPROP_COLOR,Color);
   ObjectSetInteger(chart_id,name,OBJPROP_STYLE,style);
   ObjectSetInteger(chart_id,name,OBJPROP_WIDTH,width);
   ObjectSetString(chart_id,name,OBJPROP_TEXT,text);
   ObjectSetInteger(chart_id,name,OBJPROP_BACK,true);
   ObjectSetInteger(chart_id,name,OBJPROP_RAY_RIGHT,false);
   ObjectSetInteger(chart_id,name,OBJPROP_SELECTED,false);
   ObjectSetInteger(chart_id,name,OBJPROP_SELECTABLE,false);
   ObjectSetInteger(chart_id,name,OBJPROP_ZORDER,true);
//----
  }
//+------------------------------------------------------------------+
//|  Ïåðåóñòàíîâêà òðåíäîâîé ëèíèè                                   |
//+------------------------------------------------------------------+
void SetTline(
              long     chart_id,      // èäåíòèôèêàòîð ãðàôèêà
              string   name,          // èìÿ îáúåêòà
              int      nwin,          // èíäåêñ îêíà
              datetime time1,         // âðåìÿ 1 öåíîâîãî óðîâíÿ
              double   price1,        // 1 öåíîâîé óðîâåíü
              datetime time2,         // âðåìÿ 2 öåíîâîãî óðîâíÿ
              double   price2,        // 2 öåíîâîé óðîâåíü
              color    Color,         // öâåò ëèíèè
              int      style,         // ñòèëü ëèíèè
              int      width,         // òîëùèíà ëèíèè
              string   text           // òåêñò
              )
//---- 
  {
//----
   if(ObjectFind(chart_id,name)==-1) CreateTline(chart_id,name,nwin,time1,price1,time2,price2,Color,style,width,text);
   else
     {
      ObjectSetString(chart_id,name,OBJPROP_TEXT,text);
      ObjectMove(chart_id,name,0,time1,price1);
      ObjectMove(chart_id,name,1,time2,price2);
      ObjectSetInteger(chart_id,name,OBJPROP_COLOR,Color);
      ObjectSetInteger(chart_id,name,OBJPROP_STYLE,style);
      ObjectSetInteger(chart_id,name,OBJPROP_WIDTH,width);
     }
//----
  }
//+------------------------------------------------------------------+