ShadeNY_v5_v2

Download script
Author: Copyright � 2006, sx ted
ShadeNY_v5_v2

Overview

The ShadeNY_v5 script is a visual tool designed to help traders clearly identify specific trading sessions—most notably the New York session—directly on their price charts. By automatically highlighting these time blocks with a colored overlay, it allows users to quickly distinguish between high-activity periods and quieter market hours without having to manually calculate time differences or monitor clocks constantly.

Core Logic & Functionality

1. Time Zone Synchronization The script is designed to bridge the gap between different global time zones. It accounts for three specific time variables:

  • Server Time: The local time used by your trading platform.
  • Exchange Time: The local time of the physical market (e.g., New York local time).
  • Time Offset: The script automatically calculates the difference between your server and the exchange to ensure that the "shading" appears at the correct moment regardless of where your broker is located.

2. Automated Boundary Detection Instead of requiring the user to guess which bars correspond to a session, the script performs the following calculations:

  • It identifies the exact start and end hours/minutes for a session based on the user's preferences.
  • It checks the current chart timeframe (supporting M1 through H4) and aligns the session boundaries to fit that specific timeframe.
  • It handles "overnight" sessions, ensuring that if a trading period starts on one day and ends on the next, the shading remains continuous and accurate.

3. Dynamic Visual Shading Once the start and end times are calculated, the script performs these visual actions:

  • Historical Mapping: It looks back over a set number of days (defaulting to 5) and draws a rectangular box over every completed session in that period.
  • Price Range Adjustment: The height of each shaded box is automatically adjusted to cover the highest and lowest prices reached during that specific session, ensuring the entire price action is enveloped by the color.
  • Real-Time Updates: For the current active session, the script provides "immediate" shading. It recognizes the moment a new session begins and ensures the visual block updates as the market moves.

4. Performance & Cleanup The logic is optimized to prevent chart "clutter." Every time the chart refreshes or a new bar appears:

  • The script clears out old visual objects from its temporary memory.
  • It redraws only the necessary shaded boxes for the specified timeframe.
  • If you move the chart to a timeframe larger than 4 hours (like the Daily chart), the script automatically disables itself to keep the interface clean.

Summary for the User

In simple terms, this script acts as an automatic highlighter. You tell it which hours represent the session you care about and what color you want them to be; the script then handles all the complex math involving time zones, dates, and price extremes to paint those sessions onto your chart automatically.

Price Data Components
Series array that contains open time of each bar
Miscellaneous
It issuies visual alerts to the screen
10 Views
0 Downloads
0 Favorites
ShadeNY_v5_v2 
//+------------------------------------------------------------------+
//|                                                   ShadeNY_v5.mq4 |
//|                                         Copyright © 2006, sx ted |
//| Purpose: shade New York or other sessions for chart time frames  |
//|          M1 to H4 (at a push).                                   |
//| Notes..: To change chart time frame from M5 to M15 for example,  |
//|          click on M15, M5 and M15 again to force a chart refresh.|
//|          Modify the values of MAX_DAYS_TO_SHADE, SESSION_OPEN_HH,|
//|          SESSION_OPEN_MM, SESSION_CLOSE_HH and SESSION_CLOSE_MM  |
//|          to suit ***** THE LOCAL TIMES AT THE EXCHANGE *****.    |
//|          The values for SERVER_TIME_ZONE and EXCHANGE_TIME_ZONE  |
//|          are to be edited for DST when applicable.               |
//| version: 2 - enhanced for speed but with MT4 beeing so fast no   |
//|              difference will be noticed, all the sessions are    |
//|              shaded in the init(), last session if it is current |
//|              is widened in the start() in lieu of repainting all.|
//|          3 - 2006.03.22 added "SetImmediacyON" input parameter   |
//|              which forces shading after first tick is received   |
//|              in the new session. Corrected case where bar is not |
//|              complete and session starts, and case when session  |
//|              covers two days when in Moscow (GMT+3 and greater). |
//|          4 - 2006.03.29 corrected for not taking into account the|
//|              difference between Local time and Server time.      |
//|          5 - 2006.04.03 corrected for Server time change, open   |
//|              and close times of exchange are now expressed in    |
//|              local times of the exchange.                        |
//|              Added new SERVER_TIME_ZONE and EXCHANGE_TIME_ZONE in|
//|              the #define section. Finally learnt about GMT time! |
//+------------------------------------------------------------------+

#property copyright "Copyright © 2006, sx ted"
#property link      ""

#property indicator_chart_window

//---- input parameters
extern color     ShadeColor=Yellow;
extern bool      SetImmediacyON=true;  // if set ON forces shading after first tick in new session

#define MAX_DAYS_TO_SHADE   5          // maximum number of days back from last chart date to be shaded

#define SERVER_TIME_ZONE   +2          // MetaTrader server time zone, compare CurTime() with Greenwich GMT
#define EXCHANGE_TIME_ZONE -4          // Exchange time zone, example New York -4 GMT
#define SESSION_OPEN_HH    09          // session open hour (in local time at the exchange)
#define SESSION_OPEN_MM    30          // session open minutes (in local time at the exchange)
#define SESSION_CLOSE_HH   16          // session close hour (in local time at the exchange)
#define SESSION_CLOSE_MM   05          // session close minutes (in local time at the exchange)

//---- global variables to program
string  obj[];                         // array of object names

//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
   if(Period() > PERIOD_H4) return(0); // no shading required
   // comment out or delete the following line when no longer required
   Alert( "ServerTime at ", ServerAddress(), " is ", TimeToStr( CurTime(),TIME_MINUTES ), "\nAdjust #define SERVER_TIME_ZONE if required" );
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
  {
   for(int i=0; i < ArraySize(obj); i++)
     {
      if(ObjectFind(obj[i]) > -1) ObjectDelete(obj[i]); // tidy up
     }
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
  {
   if(Period() > PERIOD_H4) return(0); // no shading required
   int    i, iCount, iAdjust,          // counters
          iStart, iEnd;                // x co-ordinates of object (index)
   double dLow, dHigh;                 // y co-ordinates of object   
   string sName;                       // name for the object
   int    iSessionDuration;            // session duration in seconds
   bool   ok;
   // adjust for difference between Server time and Local time at the exchange (in minutes)
   iAdjust=(SERVER_TIME_ZONE - EXCHANGE_TIME_ZONE) * 60;
   // determine open time of first bar in the session matching chart time frame in format " hh:mi"
   iStart=SESSION_OPEN_HH*60+SESSION_OPEN_MM+iAdjust;
   if(iStart > 24*60) iStart-=24*60;
   string sStart=" "+TimeToStr(StrToTime("2006.3.22")+(MathFloor(iStart/Period()) * Period() ) * 60, TIME_MINUTES);
   // calculate session duration in seconds, check if session covers two days (cater for GMT+3 and above)
   if(SESSION_OPEN_HH*60+SESSION_OPEN_MM >= SESSION_CLOSE_HH*60+SESSION_CLOSE_MM) iSessionDuration = ((23-SESSION_OPEN_HH+SESSION_CLOSE_HH)*60+59-SESSION_OPEN_MM+SESSION_CLOSE_MM+1)*60;
   else iSessionDuration = ( (SESSION_CLOSE_HH*60+SESSION_CLOSE_MM) - (SESSION_OPEN_HH*60+SESSION_OPEN_MM) )*60;
   // round session duration to suit an open time of chart time frame
   datetime tStart =StrToTime(TimeToStr(Time[0], TIME_DATE)+sStart);
   datetime tEnd   =StrToTime(TimeToStr(Time[0], TIME_DATE)+" "+DoubleToStr(SESSION_OPEN_HH ,0)+":"+DoubleToStr(SESSION_OPEN_MM ,0))+iSessionDuration+iAdjust*60;
   iSessionDuration=MathCeil((tEnd-tStart)/Period())*Period();
   // clear previous objects
   for(i=0; i < ArraySize(obj); i++)
     {
      if(ObjectFind(obj[i]) > -1) ObjectDelete(obj[i]);
     }
   for(i=MAX_DAYS_TO_SHADE; i >= 0; i--)
     {
      tStart=StrToTime(TimeToStr(iTime(NULL, PERIOD_D1, i), TIME_DATE)+sStart);
      tEnd  =tStart+iSessionDuration;
      iStart=iBarShift(NULL, 0, tStart, false);
      ok=(iStart > 0 && iStart < Bars-1 && TimeDayOfYear(tStart) == TimeDayOfYear(Time[iStart]));
      if(!ok && SetImmediacyON && CurTime() >= tStart && CurTime() < tEnd)
        {
         ok=true;
         iStart=1;
        }
      if(ok)  
        {
         iEnd=iBarShift(NULL, 0, tEnd, false);
         if(iEnd >= Bars-1) iEnd=0; // end not found, therefore current session
         while(iEnd < iStart && Time[iEnd] > tEnd) iEnd++; // cater for earlier close on Friday
         dLow =Low[Lowest(NULL,0,MODE_LOW,iStart-iEnd,iEnd)];
         dHigh=High[Highest(NULL,0,MODE_HIGH,iStart-iEnd,iEnd)];
         sName="Session_"+TimeToStr(iTime(NULL, PERIOD_D1, i), TIME_DATE);
         ObjectCreate(sName,OBJ_RECTANGLE,0,Time[iStart],dLow-Point,Time[iEnd],dHigh+Point);
         ObjectSet(sName,OBJPROP_COLOR,ShadeColor);
         // keep track of object names for tidying up upon exit
         iCount=ArraySize(obj);
         ArrayResize(obj, iCount+1);
         obj[iCount]=sName;
        }
     }
   return(0);
  }
//+------------------------------------------------------------------+

Similar scripts

ShadeNY_v5

This indicator dynamically projects and highlights specific global trading sessions on the chart by calculating temporal offsets between server time, exchange local time, and daylight savings.

Geo_Impulse

DT-ZigZag-Lauer

Identifies key structural pivot points by mapping higher timeframe ZigZag extrema onto lower timeframe price action to detect trend violations.

Ind_VilkaFractals_v1_2

ShadeNY_v5b

Dynamically renders historical and real-time exchange session boundaries as visual overlays by calculating time zone offsets and specific trade window durations.

DT-ZigZag-Lauer_v2

This indicator identifies structural trend pivots by mapping high-period ZigZag extremes onto the current chart to filter price action relative to macro market swings.

JJN-ActiveHours

This indicator dynamically renders visual vertical demarcations to isolate specific intraday liquidity windows based on user-defined chronological thresholds.

LargeTimeFrame

This indicator projects historical candle bodies and price ranges from a higher timeframe onto the current chart for concurrent structural analysis.

# OTCFX_b-clock modified V2.2

Price_Bars_MTF

This indicator maps and visualizes the opening, closing, high, and low price boundaries of a specified higher timeframe onto the current chart for concurrent structural analysis.

b-clock modified

Comments