RVI Custom Levels Alert

ÿþ//+------------------------------------------------------------------+

//|                                      RVI Custom Levels Alert.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43161 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43161"

#property version   "1.001"

#property indicator_separate_window

#property indicator_buffers 4

#property indicator_plots   4

//--- plot RVI

#property indicator_label1  "RVI"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrGold

#property indicator_style1  STYLE_SOLID

#property indicator_width1  3

//--- plot Signal

#property indicator_label2  "Signal"

#property indicator_type2   DRAW_LINE

#property indicator_color2  clrRed

#property indicator_style2  STYLE_SOLID

#property indicator_width2  3

//--- plot BUY

#property indicator_label3  "RVI BUY"

#property indicator_type3   DRAW_ARROW

#property indicator_color3  clrBlue

#property indicator_style3  STYLE_SOLID

#property indicator_width3  1

//--- plot SELL

#property indicator_label4  "RVI SELL"

#property indicator_type4   DRAW_ARROW

#property indicator_color4  clrRed

#property indicator_style4  STYLE_SOLID

#property indicator_width4  1

//--- input parameters

input group             "RVI"

input int      Inp_RVI_ma_period    = 12;          // RVI: averaging period

input group             "Levels"

input double   Inp_RVI_Level_UP     = 0.2;         // Value Level UP (0.2)

input double   Inp_RVI_Level_DOWN   = -0.2;        // Value Level DOWN (-0.2)

input group             "Arrow"

sinput uchar   InpCodeBuy           = 233;         // Arrow code for 'RVI BUY' (font Wingdings)

sinput uchar   InpCodeSell          = 234;         // Arrow code for 'RVI SELL' (font Wingdings)

sinput int     InpShift             = 10;          // Vertical shift of arrows in pixel

sinput bool    InpBuyDOWN           = true;        // BUY: intersections ONLY below the Level DOWN

sinput bool    InpSELLUP            = true;        // SELL: intersections ONLY above the Level UP

input group             "Alerts"

sinput uchar   InpAlertSignalBar    = 0;           // Alerts Signal Bar !

sinput string  InpSoundName         = "alert.wav"; // Sound Name ("" -> OFF)

sinput uchar   InpSoundRepetitions  = 3;           // Repetitions

sinput uchar   InpSoundPause        = 3;           // Pause, in seconds

sinput bool    InpAlert             = true;        // Alert

sinput bool    InpMail              = true;        // Send mail

sinput bool    InpNotification      = true;        // Send notification

//--- indicator buffers

double   RVIBuffer[];

double   SignalBuffer[];

double   RVIBUYBuffer[];

double   RVISELLBuffer[];

//---

int      handle_iRVI;               // variable for storing the handle of the iRVI indicator

int      bars_calculated   = 0;     // we will keep the number of values in the Relative Vigor Index indicator

//---

datetime m_last_sound      = 0;     // "0" -> D'1970.01.01 00:00';

uchar    m_repetitions     = 0;     //

string   m_text            = "";    //

datetime m_prev_bars       = 0;     // "0" -> D'1970.01.01 00:00';

//---

bool     m_init_error      = false; // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,RVIBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,SignalBuffer,INDICATOR_DATA);

   SetIndexBuffer(2,RVIBUYBuffer,INDICATOR_DATA);

   SetIndexBuffer(3,RVISELLBuffer,INDICATOR_DATA);

   IndicatorSetInteger(INDICATOR_DIGITS,3);

//--- custom parameters

   IndicatorSetInteger(INDICATOR_LEVELS,2);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,0,Inp_RVI_Level_UP);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,1,Inp_RVI_Level_DOWN);

//--- define the symbol code for drawing in PLOT_ARROW

   PlotIndexSetInteger(2,PLOT_ARROW,InpCodeBuy);

   PlotIndexSetInteger(3,PLOT_ARROW,InpCodeSell);

//--- set the vertical shift of arrows in pixels

   PlotIndexSetInteger(2,PLOT_ARROW_SHIFT,InpShift);

   PlotIndexSetInteger(3,PLOT_ARROW_SHIFT,-InpShift);

//--- Set as an empty value 0

   PlotIndexSetDouble(2,PLOT_EMPTY_VALUE,EMPTY_VALUE);

   PlotIndexSetDouble(3,PLOT_EMPTY_VALUE,EMPTY_VALUE);

//--- name for DataWindow and indicator subwindow label

   string short_name=StringFormat("RVI Custom Levels(%d)",Inp_RVI_ma_period);

   IndicatorSetString(INDICATOR_SHORTNAME,short_name);

   PlotIndexSetString(0,PLOT_LABEL,short_name);

//--- create handle of the indicator iRVI

   handle_iRVI=iRVI(Symbol(),Period(),Inp_RVI_ma_period);

//--- if the handle is not created

   if(handle_iRVI==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iRVI indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(m_init_error)

      return(0);

   if(rates_total<3 || rates_total<InpAlertSignalBar+3)

      return(0);

//--- number of values copied from the iRVI indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iRVI);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iRVI indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the RVIBuffer array is greater than the number of values in the iRVI indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the arrays with values of the iRVI indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(RVIBuffer,SignalBuffer,handle_iRVI,values_to_copy))

      return(0);

//--- memorize the number of values in the Relative Vigor Index indicator

   bars_calculated=calculated;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      limit=1;

      RVIBUYBuffer[0]=EMPTY_VALUE;

      RVISELLBuffer[0]=EMPTY_VALUE;

     }

   for(int i=limit; i<rates_total; i++)

     {

      RVIBUYBuffer[i]=EMPTY_VALUE;

      if(RVIBuffer[i-1]<SignalBuffer[i-1] && RVIBuffer[i]>SignalBuffer[i])

         if((RVIBuffer[i-1]<Inp_RVI_Level_DOWN && InpBuyDOWN) || !InpBuyDOWN)

            RVIBUYBuffer[i]=SignalBuffer[i];

      RVISELLBuffer[i]=EMPTY_VALUE;

      if(RVIBuffer[i-1]>SignalBuffer[i-1] && RVIBuffer[i]<SignalBuffer[i])

         if((RVIBuffer[i-1]>Inp_RVI_Level_UP && InpSELLUP) || !InpSELLUP)

            RVISELLBuffer[i]=SignalBuffer[i];

     }

//--- main alert

   if(time[rates_total-1]>m_prev_bars)

     {

      m_last_sound=0;

      m_prev_bars=time[rates_total-1];

      m_repetitions=0;

     }

   if(m_repetitions>=InpSoundRepetitions)

      return(rates_total);

//---

   datetime time_current=TimeCurrent();

   if(time_current-m_last_sound>InpSoundPause)

     {

      // i -> Alert Signal Bar

      int i=rates_total-1-InpAlertSignalBar;

      if(RVIBuffer[i-1]<SignalBuffer[i-1] && RVIBuffer[i]>SignalBuffer[i])

         if((RVIBuffer[i-1]<Inp_RVI_Level_DOWN && InpBuyDOWN) || !InpBuyDOWN)

           {

            if(InpSoundName!="")

               PlaySound(InpSoundName);

            m_text=Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" RVI crossed Signal from bottom to top, "+TimeToString(time[i]);

            if(InpAlert)

               Alert(m_text);

            m_last_sound=time_current;

            m_repetitions++;

            //---

            if(InpMail)

               SendMail(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1),m_text);

            if(InpNotification)

               SendNotification(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" "+m_text);

            return(rates_total);

           }

      if(RVIBuffer[i-1]>SignalBuffer[i-1] && RVIBuffer[i]<SignalBuffer[i])

         if((RVIBuffer[i-1]>Inp_RVI_Level_UP && InpSELLUP) || !InpSELLUP)

           {

            if(InpSoundName!="")

               PlaySound(InpSoundName);

            m_text=Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" RVI crossed Signal from top to bottom, "+TimeToString(time[i]);

            if(InpAlert)

               Alert(m_text);

            m_last_sound=time_current;

            m_repetitions++;

            //---

            if(InpMail)

               SendMail(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1),m_text);

            if(InpNotification)

               SendNotification(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" "+m_text);

            return(rates_total);

           }

     }

//--- return the prev_calculated value for the next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iRVI indicator                |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &rvi_buffer[],     // indicator buffer of Relative Vigor Index values

                         double &signal_buffer[],  // indicator buffer of the signal line

                         int ind_handle,           // handle of the iRVI indicator

                         int amount                // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iRVIBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,rvi_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iRVI indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- fill a part of the SignalBuffer array with values from the indicator buffer that has index 1

   if(CopyBuffer(ind_handle,1,0,amount,signal_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iRVI indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iRVI!=INVALID_HANDLE)

      IndicatorRelease(handle_iRVI);

  }

//+------------------------------------------------------------------+