RVI Arrow Intersection 2

ÿþ//+------------------------------------------------------------------+

//|                                     RVI Arrow Intersection 2.mq5 |

//|                         Copyright © 2020-2021, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020-2021, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "2.001"

#property indicator_chart_window

#property indicator_buffers 4

#property indicator_plots   1

//--- plot Intersection

#property indicator_label1  "RVI Intersection 2"

#property indicator_type1   DRAW_COLOR_ARROW

#property indicator_color1  clrBlue,clrRed

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- input parameters

input group             "RVI"

input int      Inp_RVI_ma_period = 5;     // RVI: averaging period

input group             "Arrow"

input uchar    InpCode           = 174;   // Arrow code for style DRAW_ARROW (font Wingdings)

input int      InpShift          = 10;    // Vertical shift of arrows in pixels

input group             "Additional features"

input bool     InpStrictControl  = true;  // Strict control

//--- indicator buffers

double   IntersectionBuffer[];

double   IntersectionColor[];

double   MainBuffer[];

double   SignalBuffer[];

//---

int      handle_iRVI;         // variable for storing the handle of the iRVI indicator

int      bars_calculated=0;   // we will keep the number of values in the Relative Vigor Index indicator

//---

#define TRIANGLE_PERIOD  3

#define AVERAGE_PERIOD   (TRIANGLE_PERIOD*2)

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,IntersectionBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,IntersectionColor,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(2,MainBuffer,INDICATOR_CALCULATIONS);

   SetIndexBuffer(3,SignalBuffer,INDICATOR_CALCULATIONS);

   IndicatorSetInteger(INDICATOR_DIGITS,3);

//--- setting a code from the Wingdings charset as the property of PLOT_ARROW

   PlotIndexSetInteger(0,PLOT_ARROW,InpCode);

//--- set the vertical shift of arrows in pixels

   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,-InpShift);

//--- set as an empty value 0.0

   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);

//--- name for DataWindow and indicator subwindow label

   IndicatorSetString(INDICATOR_SHORTNAME,"RVI Arrow Intersection 2"+"("+IntegerToString(Inp_RVI_ma_period)+")");

//--- create handle of the indicator iRVI

   handle_iRVI=iRVI(Symbol(),Period(),Inp_RVI_ma_period);

//--- if the handle is not created

   if(handle_iRVI==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iRVI indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(rates_total<Inp_RVI_ma_period+AVERAGE_PERIOD)

      return(0);

//--- number of values copied from the iRVI indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iRVI);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iRVI indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the RVIBuffer array is greater than the number of values in the iRVI indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the arrays with values of the iRVI indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(MainBuffer,SignalBuffer,handle_iRVI,values_to_copy))

      return(0);

//--- memorize the number of values in the Relative Vigor Index indicator

   bars_calculated=calculated;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      limit=1;

      IntersectionBuffer[0]=0.0;

      IntersectionColor[0]=0.0;

     }

   for(int i=limit; i<rates_total; i++)

     {

      IntersectionBuffer[i]=0.0;

      IntersectionColor[i]=0.0;

      if(MainBuffer[i-1]<SignalBuffer[i-1] && MainBuffer[i]>SignalBuffer[i] && (!InpStrictControl || (InpStrictControl && MainBuffer[i]<0.0 && SignalBuffer[i]<0.0)))

        {

         IntersectionBuffer[i]=high[i];

         IntersectionColor[i]=0.0;

         continue;

        }

      if(MainBuffer[i-1]>SignalBuffer[i-1] && MainBuffer[i]<SignalBuffer[i] && (!InpStrictControl || (InpStrictControl && MainBuffer[i]>0.0 && SignalBuffer[i]>0.0)))

        {

         IntersectionBuffer[i]=high[i];

         IntersectionColor[i]=1.0;

        }

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iRVI indicator                |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &rvi_buffer[],     // indicator buffer of Relative Vigor Index values

                         double &signal_buffer[],  // indicator buffer of the signal line

                         int ind_handle,           // handle of the iRVI indicator

                         int amount                // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iRVIBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,rvi_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iRVI indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- fill a part of the SignalBuffer array with values from the indicator buffer that has index 1

   if(CopyBuffer(ind_handle,1,0,amount,signal_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iRVI indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iRVI!=INVALID_HANDLE)

      IndicatorRelease(handle_iRVI);

//--- clear the chart after deleting the indicator

   Comment("");

  }

//+------------------------------------------------------------------+