RSI Levels Filling

ÿþ//+------------------------------------------------------------------+

//|                                           RSI Levels Filling.mq5 |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.003"

#property indicator_separate_window

#property indicator_minimum   0

#property indicator_maximum   100

#property indicator_level1    17

#property indicator_level2    33

#property indicator_level3    37

#property indicator_level4    50

#property indicator_level5    63

#property indicator_level6    67

#property indicator_level7    83

#property indicator_buffers   13

#property indicator_plots     7

//--- plot L17_33

#property indicator_label1  "L17_33"

#property indicator_type1   DRAW_FILLING

#property indicator_color1  clrLightGray

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot L33_37

#property indicator_label2  "L33_37"

#property indicator_type2   DRAW_FILLING

#property indicator_color2  clrWhiteSmoke

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- plot L37_50

#property indicator_label3  "L37_50"

#property indicator_type3   DRAW_FILLING

#property indicator_color3  clrDarkGray

#property indicator_style3  STYLE_SOLID

#property indicator_width3  1

//--- plot L50_63

#property indicator_label4  "L50_63"

#property indicator_type4   DRAW_FILLING

#property indicator_color4  clrLightGray

#property indicator_style4  STYLE_SOLID

#property indicator_width4  1

//--- plot L63_67

#property indicator_label5  "L63_67"

#property indicator_type5   DRAW_FILLING

#property indicator_color5  clrWhiteSmoke

#property indicator_style5  STYLE_SOLID

#property indicator_width5  1

//--- plot L67_83

#property indicator_label6  "L67_83"

#property indicator_type6   DRAW_FILLING

#property indicator_color6  clrDarkGray

#property indicator_style6  STYLE_SOLID

#property indicator_width6  1

//--- plot RSI

#property indicator_label7  "RSI"

#property indicator_type7   DRAW_LINE

#property indicator_color7  clrDodgerBlue

#property indicator_style7  STYLE_SOLID

#property indicator_width7  3

//--- input parameters

input group             "RSI"

input int                  Inp_RSI_ma_period    = 14;          // RSI: averaging period

input ENUM_APPLIED_PRICE   Inp_RSI_applied_price= PRICE_CLOSE; // RSI: type of price

//--- indicator buffers

double   L17_33Buffer1[];

double   L17_33Buffer2[];

double   L33_37Buffer1[];

double   L33_37Buffer2[];

double   L37_50Buffer1[];

double   L37_50Buffer2[];

double   L50_63Buffer1[];

double   L50_63Buffer2[];

double   L63_67Buffer1[];

double   L63_67Buffer2[];

double   L67_83Buffer1[];

double   L67_83Buffer2[];

double   RSIBuffer[];

//---

int      handle_iRSI;         // variable for storing the handle of the iRSI indicator

int      bars_calculated=0;   // we will keep the number of values in the Relative Strength Index indicator

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,L17_33Buffer1,INDICATOR_DATA);

   SetIndexBuffer(1,L17_33Buffer2,INDICATOR_DATA);

   SetIndexBuffer(2,L33_37Buffer1,INDICATOR_DATA);

   SetIndexBuffer(3,L33_37Buffer2,INDICATOR_DATA);

   SetIndexBuffer(4,L37_50Buffer1,INDICATOR_DATA);

   SetIndexBuffer(5,L37_50Buffer2,INDICATOR_DATA);

   SetIndexBuffer(6,L50_63Buffer1,INDICATOR_DATA);

   SetIndexBuffer(7,L50_63Buffer2,INDICATOR_DATA);

   SetIndexBuffer(8,L63_67Buffer1,INDICATOR_DATA);

   SetIndexBuffer(9,L63_67Buffer2,INDICATOR_DATA);

   SetIndexBuffer(10,L67_83Buffer1,INDICATOR_DATA);

   SetIndexBuffer(11,L67_83Buffer2,INDICATOR_DATA);

   SetIndexBuffer(12,RSIBuffer,INDICATOR_DATA);

//--- Set the accuracy of values to be displayed in the Data Window

   IndicatorSetInteger(INDICATOR_DIGITS,0);

//--- create handle of the indicator

   handle_iRSI=iRSI(Symbol(),Period(),Inp_RSI_ma_period,Inp_RSI_applied_price);

//--- if the handle is not created

   if(handle_iRSI==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iRSI indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//--- show the symbol/timeframe the Relative Strength Index indicator is calculated for

   string short_name=StringFormat("RSI Arrow (%s,%s, %d, %s) ",Symbol(),EnumToString(Period()),

                                  Inp_RSI_ma_period,EnumToString(Inp_RSI_applied_price));

   IndicatorSetString(INDICATOR_SHORTNAME,short_name);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- number of values copied from the iRSI indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iRSI);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iRSI indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   int limit=0;

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iRSIBuffer array is greater than the number of values in the iRSI indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

      limit=rates_total-values_to_copy;

     }

//---

   for(int i=limit; i<rates_total; i++)

     {

      L17_33Buffer1[i]=33;

      L17_33Buffer2[i]=17;

      L33_37Buffer1[i]=37;

      L33_37Buffer2[i]=33;

      L37_50Buffer1[i]=50;

      L37_50Buffer2[i]=37;

      L50_63Buffer1[i]=63;

      L50_63Buffer2[i]=50;

      L63_67Buffer1[i]=67;

      L63_67Buffer2[i]=63;

      L67_83Buffer1[i]=83;

      L67_83Buffer2[i]=67;

     }

//--- fill the array with values of the iRSI indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(RSIBuffer,handle_iRSI,values_to_copy))

      return(0);

//--- memorize the number of values in the Relative Strength Index indicator

   bars_calculated=calculated;

//--- return the prev_calculated value for the next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iRSI indicator                |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &rsi_buffer[],  // indicator buffer of Relative Strength Index values

                         int ind_handle,        // handle of the iRSI indicator

                         int amount             // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iRSIBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,rsi_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iRSI indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iRSI!=INVALID_HANDLE)

      IndicatorRelease(handle_iRSI);

  }

//+------------------------------------------------------------------+