RSI Level Breakout

ÿþ//+------------------------------------------------------------------+

//|                                           RSI Level Breakout.mq5 |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.002"

#property indicator_separate_window

#property indicator_minimum 0

#property indicator_maximum 100

#property indicator_buffers 5

#property indicator_plots   4

//--- plot RSI LINE

#property indicator_label1  "RSI LINE"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrDodgerBlue

#property indicator_style1  STYLE_DASH

#property indicator_width1  2

//--- plot RSI HISTOGRAM

#property indicator_label2  "RSI HISTOGRAM"

#property indicator_type2   DRAW_COLOR_HISTOGRAM

#property indicator_color2  clrBlue,clrGreenYellow,clrRed

#property indicator_style2  STYLE_SOLID

#property indicator_width2  2

//--- plot Level80

#property indicator_label3  "Level 80"

#property indicator_type3   DRAW_ARROW

#property indicator_color3  clrBlue

#property indicator_style3  STYLE_SOLID

#property indicator_width3  1

//--- plot Level20

#property indicator_label4  "Level 20"

#property indicator_type4   DRAW_ARROW

#property indicator_color4  clrRed

#property indicator_style4  STYLE_SOLID

#property indicator_width4  1

//--- input parameters

input group             "RSI"

input int                  Inp_RSI_ma_period    = 5;           // RSI: averaging period

input ENUM_APPLIED_PRICE   Inp_RSI_applied_price= PRICE_CLOSE; // RSI: type of price

//--- indicator buffers

double   RSILineBuffer[];

double   RSIHistogramBuffer[];

double   RSIHistogramColorsBuffer[];

double   Level80Buffer[];

double   Level20Buffer[];

//---

int      handle_iRSI;                           // variable for storing the handle of the iRSI indicator

int      bars_calculated= 0;                    // we will keep the number of values in the Relative Strength Index indicator

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,RSILineBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,RSIHistogramBuffer,INDICATOR_DATA);

   SetIndexBuffer(2,RSIHistogramColorsBuffer,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(3,Level80Buffer,INDICATOR_DATA);

   SetIndexBuffer(4,Level20Buffer,INDICATOR_DATA);

//--- set levels

   IndicatorSetInteger(INDICATOR_LEVELS,4);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,0,80.0);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,1,70.0);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,2,30.0);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,3,20.0);

//--- set accuracy

   IndicatorSetInteger(INDICATOR_DIGITS,2);

//--- setting a code from the Wingdings charset as the property of PLOT_ARROW

   PlotIndexSetInteger(2,PLOT_ARROW,236);

   PlotIndexSetInteger(3,PLOT_ARROW,238);

//--- set the vertical shift of arrows in pixels

   PlotIndexSetInteger(2,PLOT_ARROW_SHIFT,-10);

   PlotIndexSetInteger(3,PLOT_ARROW_SHIFT,-10);

//--- Set as an empty value 0

   PlotIndexSetDouble(2,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(3,PLOT_EMPTY_VALUE,0.0);

//--- create handle of the indicator iRSI

   handle_iRSI=iRSI(Symbol(),Period(),Inp_RSI_ma_period,Inp_RSI_applied_price);

//--- if the handle is not created

   if(handle_iRSI==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iRSI indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(rates_total<3)

      return(0);

//--- number of values copied from the iRSI indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iRSI);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iRSI indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iRSIBuffer array is greater than the number of values in the iRSI indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the array with values of the iRSI indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(RSILineBuffer,handle_iRSI,values_to_copy))

      return(0);

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      RSIHistogramColorsBuffer[0]=1.0;

      Level80Buffer[0]=0.0;

      Level20Buffer[0]=0.0;

      limit=1;

     }

   for(int i=limit; i<rates_total; i++)

     {

      //---

      RSIHistogramBuffer[i]=RSILineBuffer[i];

      RSIHistogramColorsBuffer[i]=1.0;

      Level80Buffer[i]=0.0;

      Level20Buffer[i]=0.0;

      //--- RSI Histogram

      if(RSIHistogramBuffer[i]>=70.0)

         RSIHistogramColorsBuffer[i]=0.0;

      else

         if(RSIHistogramBuffer[i]<=30.0)

            RSIHistogramColorsBuffer[i]=2.0;

      //--- Level 80

      if(RSIHistogramBuffer[i-1]<80.0 && RSIHistogramBuffer[i]>=80.0)

         Level80Buffer[i]=RSIHistogramBuffer[i];

      //--- Level 20

      if(RSIHistogramBuffer[i-1]>20.0 && RSIHistogramBuffer[i]<=20.0)

         Level20Buffer[i]=RSIHistogramBuffer[i];

     }

//--- memorize the number of values in the Relative Strength Index indicator

   bars_calculated=calculated;

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iRSI indicator                |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &rsi_buffer[],  // indicator buffer of Relative Strength Index values

                         int ind_handle,        // handle of the iRSI indicator

                         int amount             // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iRSIBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,rsi_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iRSI indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iRSI==INVALID_HANDLE)

      IndicatorRelease(handle_iRSI);

  }

//+------------------------------------------------------------------+