RSI Dual Arrow

ÿþ//+------------------------------------------------------------------+

//|                                               RSI Dual Arrow.mq5 |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.001"

#property indicator_separate_window

#property indicator_buffers 6

#property indicator_plots   6

//--- plot RSIFast

#property indicator_label1  "RSIFast"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrDodgerBlue

#property indicator_style1  STYLE_SOLID

#property indicator_width1  2

//--- plot RSISlow

#property indicator_label2  "RSISlow"

#property indicator_type2  DRAW_LINE

#property indicator_color2  clrOrange

#property indicator_style2  STYLE_SOLID

#property indicator_width2  2

//--- plot BuyOpen

#property indicator_label3  "BuyOpen"

#property indicator_type3   DRAW_ARROW

#property indicator_color3  clrBlue

#property indicator_style3  STYLE_SOLID

#property indicator_width3  1

//--- plot BuyClose

#property indicator_label4  "BuyClose"

#property indicator_type4   DRAW_ARROW

#property indicator_color4  clrDeepSkyBlue

#property indicator_style4  STYLE_SOLID

#property indicator_width4  1

//--- plot SellOpen

#property indicator_label5  "SellOpen"

#property indicator_type5   DRAW_ARROW

#property indicator_color5  clrRed

#property indicator_style5  STYLE_SOLID

#property indicator_width5  1

//--- plot SellClose

#property indicator_label6  "SellClose"

#property indicator_type6   DRAW_ARROW

#property indicator_color6  clrDarkSalmon

#property indicator_style6  STYLE_SOLID

#property indicator_width6  1



//--- input parameters

input group             "RSI"

input int                  Inp_RSI_Fast_ma_period     = 14;          // RSI Fast: averaging period

input ENUM_APPLIED_PRICE   Inp_RSI_Fast_applied_price = PRICE_CLOSE; // RSI Fast: type of price

input int                  Inp_RSI_Slow_ma_period     = 6;           // RSI Slow: averaging period

input ENUM_APPLIED_PRICE   Inp_RSI_Slow_applied_price = PRICE_CLOSE; // RSI Slow: type of price

input double               Inp_RSI_Level_Down         = 30;          // RSI Level Down

input double               Inp_RSI_Level_Up          = 70;          // RSI Level Up

//--- indicator buffers

double   iRSI_Fast_Buffer[];

double   iRSI_Slow_Buffer[];

double   BuyOpenBuffer[];

double   BuyCloseBuffer[];

double   SellOpenBuffer[];

double   SellCloseBuffer[];

//---

int      handle_iRSI_Fast;                      // variable for storing the handle of the iRSI indicator

int      handle_iRSI_Slow;                      // variable for storing the handle of the iRSI indicator

int      bars_calculated=0;                     // we will keep the number of values in the Relative Strength Index indicator

int      m_start=0;

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,iRSI_Fast_Buffer,INDICATOR_DATA);

   SetIndexBuffer(1,iRSI_Slow_Buffer,INDICATOR_DATA);

   SetIndexBuffer(2,BuyOpenBuffer,INDICATOR_DATA);

   SetIndexBuffer(3,BuyCloseBuffer,INDICATOR_DATA);

   SetIndexBuffer(4,SellOpenBuffer,INDICATOR_DATA);

   SetIndexBuffer(5,SellCloseBuffer,INDICATOR_DATA);

//--- set levels

   IndicatorSetInteger(INDICATOR_LEVELS,2);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,0,Inp_RSI_Level_Down);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,1,Inp_RSI_Level_Up);

//--- set accuracy

   IndicatorSetInteger(INDICATOR_DIGITS,2);

//--- setting a code from the Wingdings charset as the property of PLOT_ARROW

   PlotIndexSetInteger(2,PLOT_ARROW,233);

   PlotIndexSetInteger(3,PLOT_ARROW,234);

   PlotIndexSetInteger(4,PLOT_ARROW,234);

   PlotIndexSetInteger(5,PLOT_ARROW,233);

//--- set the vertical shift of arrows in pixels

   PlotIndexSetInteger(2,PLOT_ARROW_SHIFT,15);

   PlotIndexSetInteger(3,PLOT_ARROW_SHIFT,-15);

   PlotIndexSetInteger(4,PLOT_ARROW_SHIFT,-15);

   PlotIndexSetInteger(5,PLOT_ARROW_SHIFT,15);

//--- Set as an empty value 0

   PlotIndexSetDouble(2,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(3,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(4,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(5,PLOT_EMPTY_VALUE,0.0);

//--- create handle of the indicator iRSI

   handle_iRSI_Fast=iRSI(Symbol(),Period(),Inp_RSI_Fast_ma_period,Inp_RSI_Fast_applied_price);

//--- if the handle is not created

   if(handle_iRSI_Fast==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iRSI indicator (\"Fast\") for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//--- create handle of the indicator iRSI

   handle_iRSI_Slow=iRSI(Symbol(),Period(),Inp_RSI_Slow_ma_period,Inp_RSI_Slow_applied_price);

//--- if the handle is not created

   if(handle_iRSI_Slow==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iRSI indicator (\"Slow\") for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//---

   m_start=(m_start<Inp_RSI_Fast_ma_period+1)?Inp_RSI_Fast_ma_period+1:m_start;

   m_start=(m_start<Inp_RSI_Slow_ma_period+1)?Inp_RSI_Slow_ma_period+1:m_start;

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(rates_total<m_start+3)

      return(0);

//---

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated_fast=BarsCalculated(handle_iRSI_Fast);

   if(calculated_fast<=0)

     {

      PrintFormat("BarsCalculated(\"Fast\") returned %d, error code %d",calculated_fast,GetLastError());

      return(0);

     }

   int calculated_slow=BarsCalculated(handle_iRSI_Slow);

   if(calculated_slow<=0)

     {

      PrintFormat("BarsCalculated(\"Slow\") returned %d, error code %d",calculated_slow,GetLastError());

      return(0);

     }

   if(calculated_fast!=calculated_slow)

     {

      PrintFormat("BarsCalculated(\"Fast\") %d not equal BarsCalculated(\"Slow\") %d",calculated_fast,calculated_slow);

      return(0);

     }

   int calculated=calculated_fast;

//--- if it is the first start of calculation of the indicator or if the number of values in the iRSI indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iRSIBuffer array is greater than the number of values in the iRSI indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the array with values of the iRSI indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(iRSI_Fast_Buffer,handle_iRSI_Fast,values_to_copy))

      return(0);

   if(!FillArrayFromBuffer(iRSI_Slow_Buffer,handle_iRSI_Slow,values_to_copy))

      return(0);

//--- memorize the number of values in the Relative Strength Index indicator

   bars_calculated=calculated;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      limit=m_start;

      for(int i=0; i<limit; i++)

        {

         BuyOpenBuffer[i]=0.0;

         BuyCloseBuffer[i]=0.0;

         SellOpenBuffer[i]=0.0;

         SellCloseBuffer[i]=0.0;

        }

     }

   for(int i=limit; i<rates_total; i++)

     {

      BuyOpenBuffer[i]=0.0;

      BuyCloseBuffer[i]=0.0;

      SellOpenBuffer[i]=0.0;

      SellCloseBuffer[i]=0.0;

      //--- Buy Open Signal

      if(iRSI_Slow_Buffer[i-1]<Inp_RSI_Level_Down && iRSI_Slow_Buffer[i]>Inp_RSI_Level_Down)

         BuyOpenBuffer[i]=(iRSI_Fast_Buffer[i]<iRSI_Slow_Buffer[i])?iRSI_Fast_Buffer[i]:iRSI_Slow_Buffer[i];

      //--- Buy Close Signal

      if(iRSI_Fast_Buffer[i-1]<iRSI_Slow_Buffer[i-1] && iRSI_Fast_Buffer[i]>iRSI_Slow_Buffer[i])

         BuyCloseBuffer[i]=(iRSI_Fast_Buffer[i]<iRSI_Slow_Buffer[i])?iRSI_Fast_Buffer[i]:iRSI_Slow_Buffer[i];

      //--- Sell Open Signal

      if(iRSI_Slow_Buffer[i-1]>Inp_RSI_Level_Up && iRSI_Slow_Buffer[i]<Inp_RSI_Level_Up)

         SellOpenBuffer[i]=(iRSI_Slow_Buffer[i]>iRSI_Slow_Buffer[i])?iRSI_Fast_Buffer[i]:iRSI_Slow_Buffer[i];

      //--- Sell Close Signal

      if(iRSI_Fast_Buffer[i-1]>iRSI_Slow_Buffer[i-1] && iRSI_Fast_Buffer[i]<iRSI_Slow_Buffer[i])

         SellCloseBuffer[i]=(iRSI_Fast_Buffer[i]<iRSI_Slow_Buffer[i])?iRSI_Fast_Buffer[i]:iRSI_Slow_Buffer[i];

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iRSI indicator                |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &rsi_buffer[],  // indicator buffer of Relative Strength Index values

                         int ind_handle,        // handle of the iRSI indicator

                         int amount             // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iRSIBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,rsi_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iRSI indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iRSI_Fast!=INVALID_HANDLE)

      IndicatorRelease(handle_iRSI_Fast);

   if(handle_iRSI_Slow!=INVALID_HANDLE)

      IndicatorRelease(handle_iRSI_Slow);

  }

//+------------------------------------------------------------------+