ROC Dual

ÿþ//+------------------------------------------------------------------+

//|                                                     ROC Dual.mq5 |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43161 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43161"

#property version   "1.000"

#property indicator_separate_window

#property indicator_buffers 2

#property indicator_plots   2

//--- plot CCIFast

#property indicator_label1  "ROCFast"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrDodgerBlue

#property indicator_style1  STYLE_SOLID

#property indicator_width1  2

//--- plot CCISlow

#property indicator_label2  "ROCSlow"

#property indicator_type2   DRAW_LINE

#property indicator_color2  clrPaleVioletRed

#property indicator_style2  STYLE_SOLID

#property indicator_width2  2

//--- input parameters

input group             "ROC"

input int            Inp_ROC_Fast_ma_period     = 12;    // ROC Fast: averaging period

input int            Inp_ROC_Slow_ma_period     = 25;    // ROC Slow: averaging period

//--- indicator buffers

double   ROCFastBuffer[];

double   ROCSlowBuffer[];

//---

int      handle_iROC_Fast;                   // variable for storing the handle of the ROC indicator

int      handle_iROC_Slow;                   // variable for storing the handle of the ROC indicator

int      bars_calculated=0;                  // we will keep the number of values in the ROC indicator

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,ROCFastBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,ROCSlowBuffer,INDICATOR_DATA);

//--- name for Dindicator subwindow label

   IndicatorSetString(INDICATOR_SHORTNAME,"ROC DUAL("+IntegerToString(Inp_ROC_Fast_ma_period)+","+IntegerToString(Inp_ROC_Slow_ma_period)+")");

//--- create handle of the indicator iCustom

   handle_iROC_Fast=iCustom(Symbol(),Period(),"Examples\\ROC",Inp_ROC_Fast_ma_period);

//--- if the handle is not created

   if(handle_iROC_Fast==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iCustom indicator (\"ROC Fast\") for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//--- create handle of the indicator iCustom

   handle_iROC_Slow=iCustom(Symbol(),Period(),"Examples\\ROC",Inp_ROC_Slow_ma_period);

//--- if the handle is not created

   if(handle_iROC_Slow==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iCustom indicator (\"ROC Slow\") for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//---

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated_fast=BarsCalculated(handle_iROC_Fast);

   if(calculated_fast<=0)

     {

      PrintFormat("BarsCalculated(\"ROC Fast\") returned %d, error code %d",calculated_fast,GetLastError());

      return(0);

     }

   int calculated_slow=BarsCalculated(handle_iROC_Slow);

   if(calculated_slow<=0)

     {

      PrintFormat("BarsCalculated(\"ROC Slow\") returned %d, error code %d",calculated_slow,GetLastError());

      return(0);

     }

   if(calculated_fast!=calculated_slow)

     {

      PrintFormat("BarsCalculated(\"ROC Fast\") %d not equal BarsCalculated(\"ROC Slow\") %d",calculated_fast,calculated_slow);

      return(0);

     }

   int calculated=calculated_fast;

//--- if it is the first start of calculation of the indicator or if the number of values in the ROC indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iCCIBuffer array is greater than the number of values in the ROC indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iCCIBuffer array with values of the ROC indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(ROCFastBuffer,handle_iROC_Fast,values_to_copy))

      return(0);

   if(!FillArrayFromBuffer(ROCSlowBuffer,handle_iROC_Slow,values_to_copy))

      return(0);

//--- memorize the number of values in the ROC indicator

   bars_calculated=calculated;

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the ROC indicator                |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],  // indicator buffer of Commodity Channel Index values

                         int ind_handle,    // handle of the ROC indicator

                         int amount         // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iCCIBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the ROC indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iROC_Fast!=INVALID_HANDLE)

      IndicatorRelease(handle_iROC_Fast);

   if(handle_iROC_Slow!=INVALID_HANDLE)

      IndicatorRelease(handle_iROC_Slow);

  }

//+------------------------------------------------------------------+