WPR Custom Smoothing

//+------------------------------------------------------------------+
//|                                         WPR Custom Smoothing.mq5 |
//|                        Copyright 2021, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2021, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.000"
#property indicator_separate_window
#property indicator_minimum -100
#property indicator_maximum 0
#property indicator_buffers 2
#property indicator_plots   2
//--- plot WPR
#property indicator_label1  "WPR"
#property indicator_type1   DRAW_LINE
#property indicator_color1  clrAqua
#property indicator_style1  STYLE_SOLID
#property indicator_width1  2
//--- plot MA on WPR
#property indicator_label2  "MA On WPR"
#property indicator_type2   DRAW_LINE
#property indicator_color2  clrPlum
#property indicator_style2  STYLE_SOLID
#property indicator_width2  2
//--- input parameters
input group             "WPR"
input int                  Inp_WPR_calc_period  = 14;          // WPR: averaging period
input group             "MA"
input int                  Inp_MA_ma_period     = 3;           // MA: averaging period
input int                  Inp_MA_ma_shift      = 0;           // MA: horizontal shift
input ENUM_MA_METHOD       Inp_MA_ma_method     = MODE_SMA;    // MA: smoothing type
//--- indicator buffers
double   WPRBuffer[];
double   MAOnWPRBuffer[];
//---
int      handle_iMA;                            // variable for storing the handle of the iMA indicator
int      handle_iWPR;                           // variable for storing the handle of the iWPR indicator
int      bars_calculated=0;                     // we will keep the number of values in the Moving Average indicator
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- indicator buffers mapping
   SetIndexBuffer(0,WPRBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,MAOnWPRBuffer,INDICATOR_DATA);
//--- name for DataWindow and indicator subwindow label
   IndicatorSetString(INDICATOR_SHORTNAME,"WPR"+"("+string(Inp_WPR_calc_period)+")");;
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,Inp_WPR_calc_period-1);
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,Inp_MA_ma_period-1);
//--- digits
   IndicatorSetInteger(INDICATOR_DIGITS,2);
//--- create handle of the indicator iWPR
   handle_iWPR=iWPR(Symbol(),Period(),Inp_WPR_calc_period);
//--- if the handle is not created
   if(handle_iWPR==INVALID_HANDLE)
     {
      //--- tell about the failure and output the error code
      PrintFormat("Failed to create handle of the iWPR indicator for the symbol %s/%s, error code %d",
                  Symbol(),
                  EnumToString(Period()),
                  GetLastError());
      //--- the indicator is stopped early
      return(INIT_FAILED);
     }
//--- create handle of the indicator iMA
   handle_iMA=iMA(Symbol(),Period(),Inp_MA_ma_period,Inp_MA_ma_shift,
                  Inp_MA_ma_method,handle_iWPR);
//--- if the handle is not created
   if(handle_iMA==INVALID_HANDLE)
     {
      //--- tell about the failure and output the error code
      PrintFormat("Failed to create handle of the iMA indicator for the symbol %s/%s, error code %d",
                  Symbol(),
                  EnumToString(Period()),
                  GetLastError());
      //--- the indicator is stopped early
      return(INIT_FAILED);
     }
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   if(rates_total<=Inp_MA_ma_period+Inp_WPR_calc_period+3)
      return(0);
//---
   int values_to_copy;
//--- determine the number of values calculated in the indicator
   int calculated_ma=BarsCalculated(handle_iMA);
   if(calculated_ma<=0)
     {
      PrintFormat("BarsCalculated(handle_iMA) returned %d, error code %d",calculated_ma,GetLastError());
      return(0);
     }
   int calculated_wpr=BarsCalculated(handle_iWPR);
   if(calculated_wpr<=0)
     {
      PrintFormat("BarsCalculated(handle_iWPR) returned %d, error code %d",calculated_wpr,GetLastError());
      return(0);
     }
   if(calculated_ma!=calculated_wpr)
     {
      PrintFormat("BarsCalculated(handle_iMA) returned %d, error code %d, BarsCalculated(handle_iWPR) returned %d, error code %d",calculated_ma,calculated_wpr);
      return(0);
     }
   int calculated=calculated_ma;
//--- if it is the first start of calculation of the indicator or if the number of values in the iMA indicator changed
//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)
   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
     {
      //--- if the iMABuffer array is greater than the number of values in the iMA indicator for symbol/period, then we don't copy everything
      //--- otherwise, we copy less than the size of indicator buffers
      if(calculated>rates_total)
         values_to_copy=rates_total;
      else
         values_to_copy=calculated;
     }
   else
     {
      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()
      //--- for calculation not more than one bar is added
      values_to_copy=(rates_total-prev_calculated)+1;
     }
//--- fill the array with values of the Williams' Percent Range indicator
//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation
   if(!FillArrayFromBuffer(WPRBuffer,handle_iWPR,values_to_copy))
      return(0);
//--- fill the MAOnWPRBuffer array with values of the Moving Average indicator
//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation
   if(!FillArrayFromBuffer(MAOnWPRBuffer,Inp_MA_ma_shift,handle_iMA,values_to_copy))
      return(0);
//--- memorize the number of values in the Moving Average indicator
   bars_calculated=calculated;
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Filling indicator buffers from the iWPR indicator                |
//+------------------------------------------------------------------+
bool FillArrayFromBuffer(double &wpr_buffer[],  // indicator buffer of Williams' Percent Range values
                         int ind_handle,        // handle of the iWPR indicator
                         int amount             // number of copied values
                        )
  {
//--- reset error code
   ResetLastError();
//--- fill a part of the iWPRBuffer array with values from the indicator buffer that has 0 index
   if(CopyBuffer(ind_handle,0,0,amount,wpr_buffer)<0)
     {
      //--- if the copying fails, tell the error code
      PrintFormat("Failed to copy data from the iWPR indicator, error code %d",GetLastError());
      //--- quit with zero result - it means that the indicator is considered as not calculated
      return(false);
     }
//--- everything is fine
   return(true);
  }
//+------------------------------------------------------------------+
//| Filling indicator buffers from the MA indicator                  |
//+------------------------------------------------------------------+
bool FillArrayFromBuffer(double &values[],   // indicator buffer of Moving Average values
                         int shift,          // shift
                         int ind_handle,     // handle of the iMA indicator
                         int amount          // number of copied values
                        )
  {
//--- reset error code
   ResetLastError();
//--- fill a part of the iMABuffer array with values from the indicator buffer that has 0 index
   if(CopyBuffer(ind_handle,0,-shift,amount,values)<0)
     {
      //--- if the copying fails, tell the error code
      PrintFormat("Failed to copy data from the iMA indicator, error code %d",GetLastError());
      //--- quit with zero result - it means that the indicator is considered as not calculated
      return(false);
     }
//--- everything is fine
   return(true);
  }
//+------------------------------------------------------------------+
//| Indicator deinitialization function                              |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   if(handle_iMA!=INVALID_HANDLE)
      IndicatorRelease(handle_iMA);
   if(handle_iWPR!=INVALID_HANDLE)
      IndicatorRelease(handle_iWPR);
  }
//+------------------------------------------------------------------+