Rectangle in interval

ÿþ//+------------------------------------------------------------------+

//|                                        Rectangle in interval.mq5 |

//|                              Copyright © 2022, Vladimir Karputov |

//|                      https://www.mql5.com/en/users/barabashkakvn |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2022, Vladimir Karputov"

#property link      "https://www.mql5.com/en/users/barabashkakvn"

#property version   "1.003"

#property description "Always only one rectangle"

#property indicator_chart_window

#property indicator_buffers 0

#property indicator_plots   0

//--- input parameters

input group             "Time settings"

input datetime             InpTimeLeft    = D'2021.05.31 07:00';  // Time Left (use only HH:MM)

input datetime             InpTimeRight   = D'2021.05.31 09:00';  // Time Right (use only HH:MM)

input group             "Rectangle settings"

input color                InpRecClr      = clrDeepPink;          // Rectangle color

input ENUM_LINE_STYLE      InpRecStyle    = STYLE_SOLID;          // Style of rectangle lines

input int                  InpRecWidth    = 1;                    // Width of rectangle lines

input bool                 InpRecFill     = false;                // Filling rectangle with color

input bool                 InpRecBack     = false;                // In the background

input bool                 InpRecSelection= false;                // Highlight to move

input bool                 InpRecHidden   = true;                 // Hidden in the object list

//---

string   m_prefix = "RII_";   // prefix

MqlDateTime SDateTimeLeft,SDateTimeRigth;

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

   TimeToStruct(InpTimeLeft,SDateTimeLeft);

   TimeToStruct(InpTimeRight,SDateTimeRigth);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- determine the date (hours, minutes and seconds are not important)

   MqlDateTime STime;

   TimeToStruct(time[rates_total-1],STime);

   STime.hour=0;

   STime.min=0;

   STime.sec=0;

   datetime time_start_day=StructToTime(STime);

//--- we form borders from two dates to request history on the 'M1' timeframe

   STime.hour=SDateTimeLeft.hour;

   STime.min=SDateTimeLeft.min;

   STime.sec=0;

   datetime time_left=StructToTime(STime);

   STime.hour=SDateTimeRigth.hour;

   STime.min=SDateTimeRigth.min;

   STime.sec=0;

   datetime time_right=StructToTime(STime);

//--- request for history from 'M1' timeframe

   if(time[rates_total-1]>time_right)

      return(rates_total);

   MqlRates rates_m1[];

   int result=CopyRates(Symbol(),PERIOD_M1,time_left,time_right,rates_m1);

   if(result>1)

     {

      double price_max=DBL_MIN,price_min=DBL_MAX;

      for(int i=0; i<result; i++)

        {

         if(rates_m1[i].high>price_max)

            price_max=rates_m1[i].high;

         if(rates_m1[i].low<price_min)

            price_min=rates_m1[i].low;

        }

      if(price_max!=DBL_MIN && price_min!=DBL_MAX)

        {

         string res_name=m_prefix+TimeToString(time_start_day,TIME_DATE|TIME_MINUTES);

         if(ObjectFind(ChartID(),res_name)<0)

           {

            //--- create

            RectangleCreate(ChartID(),res_name,0,time_left,price_max,time_right,price_min,

                            InpRecClr,

                            InpRecStyle,

                            InpRecWidth,

                            InpRecFill,

                            InpRecBack,

                            InpRecSelection,

                            InpRecHidden);

           }

         else

           {

            //--- modify

            RectanglePointChange(ChartID(),res_name,0,time_left,price_max);

            RectanglePointChange(ChartID(),res_name,1,time_right,price_min);

           }

        }

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Create rectangle by the given coordinates                        |

//+------------------------------------------------------------------+

bool RectangleCreate(const long            chart_ID=0,        // chart's ID

                     const string          name="Rectangle",  // rectangle name

                     const int             sub_window=0,      // subwindow index

                     datetime              time1=0,           // first point time

                     double                price1=0,          // first point price

                     datetime              time2=0,           // second point time

                     double                price2=0,          // second point price

                     const color           clr=clrRed,        // rectangle color

                     const ENUM_LINE_STYLE style=STYLE_SOLID, // style of rectangle lines

                     const int             width=1,           // width of rectangle lines

                     const bool            fill=false,        // filling rectangle with color

                     const bool            back=false,        // in the background

                     const bool            selection=true,    // highlight to move

                     const bool            hidden=true,       // hidden in the object list

                     const long            z_order=0)         // priority for mouse click

  {

//--- set anchor points' coordinates if they are not set

   ChangeRectangleEmptyPoints(time1,price1,time2,price2);

//--- reset the error value

   ResetLastError();

//--- create a rectangle by the given coordinates

   if(!ObjectCreate(chart_ID,name,OBJ_RECTANGLE,sub_window,time1,price1,time2,price2))

     {

      Print(__FUNCTION__,

            ": failed to create a rectangle! Error code = ",GetLastError());

      return(false);

     }

//--- set rectangle color

   ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);

//--- set the style of rectangle lines

   ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);

//--- set width of the rectangle lines

   ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);

//--- enable (true) or disable (false) the mode of filling the rectangle

   ObjectSetInteger(chart_ID,name,OBJPROP_FILL,fill);

//--- display in the foreground (false) or background (true)

   ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);

//--- enable (true) or disable (false) the mode of highlighting the rectangle for moving

//--- when creating a graphical object using ObjectCreate function, the object cannot be

//--- highlighted and moved by default. Inside this method, selection parameter

//--- is true by default making it possible to highlight and move the object

   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);

   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);

//--- hide (true) or display (false) graphical object name in the object list

   ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);

//--- set the priority for receiving the event of a mouse click in the chart

   ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);

//--- successful execution

   return(true);

  }

//+------------------------------------------------------------------+

//| Move the rectangle anchor point                                  |

//+------------------------------------------------------------------+

bool RectanglePointChange(const long   chart_ID=0,       // chart's ID

                          const string name="Rectangle", // rectangle name

                          const int    point_index=0,    // anchor point index

                          datetime     time=0,           // anchor point time coordinate

                          double       price=0)          // anchor point price coordinate

  {

//--- if point position is not set, move it to the current bar having Bid price

   if(!time)

      time=TimeCurrent();

   if(!price)

      price=SymbolInfoDouble(Symbol(),SYMBOL_BID);

//--- reset the error value

   ResetLastError();

//--- move the anchor point

   if(!ObjectMove(chart_ID,name,point_index,time,price))

     {

      Print(__FUNCTION__,

            ": failed to move the anchor point! Error code = ",GetLastError());

      return(false);

     }

//--- successful execution

   return(true);

  }

//+------------------------------------------------------------------+

//| Delete the rectangle                                             |

//+------------------------------------------------------------------+

bool RectangleDelete(const long   chart_ID=0,       // chart's ID

                     const string name="Rectangle") // rectangle name

  {

//--- reset the error value

   ResetLastError();

//--- delete rectangle

   if(!ObjectDelete(chart_ID,name))

     {

      Print(__FUNCTION__,

            ": failed to delete rectangle! Error code = ",GetLastError());

      return(false);

     }

//--- successful execution

   return(true);

  }

//+------------------------------------------------------------------+

//| Check the values of rectangle's anchor points and set default    |

//| values for empty ones                                            |

//+------------------------------------------------------------------+

void ChangeRectangleEmptyPoints(datetime &time1,double &price1,

                                datetime &time2,double &price2)

  {

//--- if the first point's time is not set, it will be on the current bar

   if(!time1)

      time1=TimeCurrent();

//--- if the first point's price is not set, it will have Bid value

   if(!price1)

      price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);

//--- if the second point's time is not set, it is located 9 bars left from the second one

   if(!time2)

     {

      //--- array for receiving the open time of the last 10 bars

      datetime temp[10];

      CopyTime(Symbol(),Period(),time1,10,temp);

      //--- set the second point 9 bars left from the first one

      time2=temp[0];

     }

//--- if the second point's price is not set, move it 300 points lower than the first one

   if(!price2)

      price2=price1-300*SymbolInfoDouble(Symbol(),SYMBOL_POINT);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   ObjectsDeleteAll(0,m_prefix,0,OBJ_RECTANGLE);

  }

//+------------------------------------------------------------------+