Pips Close Multicurrency

ÿþ//+------------------------------------------------------------------+

//|                                     Pips Close Multicurrency.mq5 |

//|                              Copyright © 2019, Vladimir Karputov |

//|                                           http://wmua.ru/slesar/ |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2019, Vladimir Karputov"

#property link      "http://wmua.ru/slesar/"

#property version   "1.000"

/*

   barabashkakvn Trading engine 3.104

*/

#include <Trade\PositionInfo.mqh>

#include <Trade\Trade.mqh>

//---

CPositionInfo  m_position;                   // object of CPositionInfo class

CTrade         m_trade;                      // object of CTrade class

//--- input parameters

input ushort   InpLoss              = 15;          // Loss, in points (1.00045-1.00055=10 points)

input ulong    InpDeviation         = 10;          // Deviation, in points (1.00045-1.00055=10 points)

input ulong    InpMagic             = 56390818;    // Magic number

//+------------------------------------------------------------------+

//| Expert initialization function                                   |

//+------------------------------------------------------------------+

int OnInit()

  {

   m_trade.SetExpertMagicNumber(InpMagic);

   m_trade.SetMarginMode();

   m_trade.SetDeviationInPoints(InpDeviation);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Expert tick function                                             |

//+------------------------------------------------------------------+

void OnTick()

  {

   for(int i=PositionsTotal()-1; i>=0; i--) // returns the number of current positions

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

        {

         double price_current = m_position.PriceCurrent();

         double price_open    = m_position.PriceOpen();

         double points        = 0.0;

         if(!SymbolInfoDouble(m_position.Symbol(),SYMBOL_POINT,points))

            continue;

         if(m_position.PositionType()==POSITION_TYPE_BUY)

           {

            if((price_open-price_current)/points>=InpLoss) // if the loss

               m_trade.PositionClose(m_position.Ticket());

           }

         else

            if(m_position.PositionType()==POSITION_TYPE_SELL)

              {

               if((price_current-price_open)/points>=InpLoss) // if the loss

                  m_trade.PositionClose(m_position.Ticket());

              }

        }

//---

  }

//+------------------------------------------------------------------+