ParabolicSAR Histogram

ÿþ//+------------------------------------------------------------------+

//|                                       ParabolicSAR Histogram.mq5 |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.000"

#property indicator_separate_window

#property indicator_minimum -0.1

#property indicator_maximum 1.1

#property indicator_buffers 3

#property indicator_plots   1

//--- plot SAR

#property indicator_label1  "SAR"

#property indicator_type1   DRAW_COLOR_HISTOGRAM

#property indicator_color1  clrRed,clrBlue

#property indicator_style1  STYLE_SOLID

#property indicator_width1  3

//--- input parameters

input group             "SAR"

input double         Inp_SAR_step         = 0.02;        // SAR: price increment step - acceleration factor

input double         Inp_SAR_maximum      = 0.2;         // SAR: maximum value of step

//--- indicator buffers

double   SARBuffer[];

double   SARColors[];

double   iSARBuffer[];

//---

int      handle_iSAR;                        // variable for storing the handle of the iSAR indicator

int      bars_calculated=0;                  // we will keep the number of values in the Parabolic SAR indicator

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,SARBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,SARColors,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(2,iSARBuffer,INDICATOR_CALCULATIONS);

//--- set indicator digits

   IndicatorSetInteger(INDICATOR_DIGITS,0);

//--- set label name

   PlotIndexSetString(0,PLOT_LABEL,"SAR("+DoubleToString(Inp_SAR_step,2)+","+DoubleToString(Inp_SAR_maximum,2)+")");

//--- create handle of the indicator iSAR

   handle_iSAR=iSAR(Symbol(),Period(),Inp_SAR_step,Inp_SAR_maximum);

//--- if the handle is not created

   if(handle_iSAR==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iSAR indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(rates_total<3)

      return(0);

//--- number of values copied from the iSAR indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iSAR);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iSAR indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iSARBuffer array is greater than the number of values in the iSAR indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the arrays with values of the iSAR indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(iSARBuffer,handle_iSAR,values_to_copy))

      return(0);

//--- memorize the number of values in the Parabolic SAR indicator

   bars_calculated=calculated;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      SARBuffer[0]=0.0;

      SARColors[0]=0.0;

      limit=1;

     }

   for(int i=limit; i<rates_total; i++)

     {

     SARBuffer[i]=1.0;

      if(iSARBuffer[i]<high[i])

         SARColors[i]=1.0;

      else

         SARColors[i]=0.0;

     }

//--- return the prev_calculated value for the next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iSAR indicator                |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &sar_buffer[],  // indicator buffer of Parabolic SAR values

                         int ind_handle,        // handle of the iSAR indicator

                         int amount             // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iSARBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,sar_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iSAR indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iSAR!=INVALID_HANDLE)

      IndicatorRelease(handle_iSAR);

  }

//+------------------------------------------------------------------+