MA vertical shift last intersection Arrow

ÿþ//+------------------------------------------------------------------+

//|                    MA vertical shift last intersection Arrow.mq5 |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43161 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43161"

#property version   "1.003"

#property indicator_chart_window

#property indicator_buffers 4

#property indicator_plots   3

//--- plot iMA

#property indicator_label1  "iMA"

#property indicator_type1   DRAW_COLOR_LINE

#property indicator_color1  clrYellowGreen,clrBlue,clrRed

#property indicator_style1  STYLE_SOLID

#property indicator_width1  2

//--- plot MAShiftUp

#property indicator_label2  "MAShiftUp"

#property indicator_type2   DRAW_ARROW

#property indicator_color2  clrBlue

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- plot MAShiftDown

#property indicator_label3  "MAShiftDown"

#property indicator_type3   DRAW_ARROW

#property indicator_color3  clrRed

#property indicator_style3  STYLE_SOLID

#property indicator_width3  1

//--- input parameters

input group           "Moving Average"

input int                  Inp_MA_ma_period     = 12;          // MA: averaging period

input int                  Inp_MA_ma_shift      = 0;           // MA: horizontal shift

input ENUM_MA_METHOD       Inp_MA_ma_method     = MODE_SMA;    // MA: smoothing type

input ENUM_APPLIED_PRICE   Inp_MA_applied_price = PRICE_CLOSE; // MA: type of price

input group           "Arrows"

input uchar                InpUpArrowCode       = 228;         // Arrow Up: code (font Wingdings)

input int                  InpUpArrowShift      = 5;           // Arrow Up: vertical shift in pixel

input uchar                InpDownArrowCode     = 230;         // Arrow Down: code (font Wingdings)

input int                  InpDownArrowShift    = 5;           // Arrow Down: vertical shift in pixel

input group           "Alert"

input uint                 InpVerticalShift     = 50;          // Vertical Shift, in Points (1.00045-1.00055=10 points)

//--- indicator buffers

double   iMABuffer[];

double   iMAColors[];

double   MAShiftUpBuffer[];

double   MAShiftDownBuffer[];



//---

int      handle_iMA;                         // variable for storing the handle of the iMA indicator

int      bars_calculated            = 0;     // we will keep the number of values in the Moving Average indicator

double   m_vertical_shift           = 0.0;   // Vertical Shift          -> double

datetime m_last_intersection_date   = 0;     // "0" -> D'1970.01.01 00:00';

double   m_last_intersection_price  = 0;     //

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,iMABuffer,INDICATOR_DATA);

   SetIndexBuffer(1,iMAColors,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(2,MAShiftUpBuffer,INDICATOR_DATA);

   SetIndexBuffer(3,MAShiftDownBuffer,INDICATOR_DATA);

//--- set shift

   PlotIndexSetInteger(0,PLOT_SHIFT,Inp_MA_ma_shift);

//--- setting a code from the Wingdings charset as the property of PLOT_ARROW

   PlotIndexSetInteger(1,PLOT_ARROW,InpUpArrowCode);

   PlotIndexSetInteger(2,PLOT_ARROW,InpDownArrowCode);

//--- set the vertical shift of arrows in pixels

   PlotIndexSetInteger(1,PLOT_ARROW_SHIFT,-InpUpArrowShift);

   PlotIndexSetInteger(2,PLOT_ARROW_SHIFT,InpDownArrowShift);

//--- an empty value for plotting, for which there is no drawing

   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(2,PLOT_EMPTY_VALUE,0.0);

//--- create handle of the indicator iMA

   handle_iMA=iMA(Symbol(),Period(),Inp_MA_ma_period,Inp_MA_ma_shift,

                  Inp_MA_ma_method,Inp_MA_applied_price);

//--- if the handle is not created

   if(handle_iMA==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iMA indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//--- show the symbol/timeframe the Moving Average indicator is calculated for

   string short_name=StringFormat("iMA(%s/%s, %d, %d, %s, %s)",Symbol(),EnumToString(Period()),

                                  Inp_MA_ma_period, Inp_MA_ma_shift,EnumToString(Inp_MA_ma_method),EnumToString(Inp_MA_applied_price));

   IndicatorSetString(INDICATOR_SHORTNAME,short_name);

//---

   m_vertical_shift     = InpVerticalShift      * Point();

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- number of values copied from the iMA indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iMA);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iMA indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iMABuffer array is greater than the number of values in the iMA indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iMABuffer array with values of the Moving Average indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(iMABuffer,Inp_MA_ma_shift,handle_iMA,values_to_copy))

      return(0);

//--- memorize the number of values in the Moving Average indicator

   bars_calculated=calculated;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      limit=Inp_MA_ma_shift+Inp_MA_ma_period;

      for(int i=0; i<limit; i++)

        {

         MAShiftUpBuffer[i]=0.0;

         MAShiftDownBuffer[i]=0.0;

         iMAColors[i]=0;

        }

     }

   for(int i=limit; i<rates_total; i++)

     {

      if((close[i]<iMABuffer[i] && open[i]>iMABuffer[i]) || (close[i]>iMABuffer[i] && open[i]<iMABuffer[i]))

        {

         m_last_intersection_date=time[i];

         m_last_intersection_price=iMABuffer[i];

         MAShiftUpBuffer[i]=0.0;

         MAShiftDownBuffer[i]=0.0;

         iMAColors[i]=0;

        }

      if(close[i]>=m_last_intersection_price+m_vertical_shift)

        {

         m_last_intersection_date=time[i];

         MAShiftUpBuffer[i]=high[i];

         iMAColors[i]=1;

        }

      else

        {

         if(m_last_intersection_date<time[i])

           {

            MAShiftUpBuffer[i]=0.0;

            iMAColors[i]=0;

           }

        }

      if(close[i]<=m_last_intersection_price-m_vertical_shift)

        {

         m_last_intersection_date=time[i];

         MAShiftDownBuffer[i]=low[i];

         iMAColors[i]=2;

        }

      else

        {

         if(m_last_intersection_date<time[i])

           {

            MAShiftDownBuffer[i]=0.0;

            iMAColors[i]=0;

           }

        }

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the MA indicator                  |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],   // indicator buffer of Moving Average values

                         int shift,          // shift

                         int ind_handle,     // handle of the iMA indicator

                         int amount          // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iMABuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,-shift,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iMA indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iMA!=INVALID_HANDLE)

      IndicatorRelease(handle_iMA);

  }

//+------------------------------------------------------------------+