Mama + fama mtf

ÿþ//------------------------------------------------------------------

#property copyright   "© mladen, 2018"

#property link        "mladenfx@gmail.com"

#property description "Mama - fama (multi time frame version)"

//------------------------------------------------------------------

#property indicator_chart_window

#property indicator_buffers 5

#property indicator_plots   2

#property indicator_label1  "Fama"

#property indicator_type1   DRAW_COLOR_LINE

#property indicator_color1  clrDarkGray,clrSandyBrown,clrDodgerBlue

#property indicator_width1  2

#property indicator_label2  "Mama"

#property indicator_type2   DRAW_COLOR_LINE

#property indicator_color2  clrDarkGray,clrSandyBrown,clrDodgerBlue

#property indicator_width2  2

//

//---

//

enum enTimeFrames

  {

   tf_cu  = PERIOD_CURRENT, // Current time frame

   tf_m1  = PERIOD_M1,      // 1 minute

   tf_m2  = PERIOD_M2,      // 2 minutes

   tf_m3  = PERIOD_M3,      // 3 minutes

   tf_m4  = PERIOD_M4,      // 4 minutes

   tf_m5  = PERIOD_M5,      // 5 minutes

   tf_m6  = PERIOD_M6,      // 6 minutes

   tf_m10 = PERIOD_M10,     // 10 minutes

   tf_m12 = PERIOD_M12,     // 12 minutes

   tf_m15 = PERIOD_M15,     // 15 minutes

   tf_m20 = PERIOD_M20,     // 20 minutes

   tf_m30 = PERIOD_M30,     // 30 minutes

   tf_h1  = PERIOD_H1,      // 1 hour

   tf_h2  = PERIOD_H2,      // 2 hours

   tf_h3  = PERIOD_H3,      // 3 hours

   tf_h4  = PERIOD_H4,      // 4 hours

   tf_h6  = PERIOD_H6,      // 6 hours

   tf_h8  = PERIOD_H8,      // 8 hours

   tf_h12 = PERIOD_H12,     // 12 hours

   tf_d1  = PERIOD_D1,      // daily

   tf_w1  = PERIOD_W1,      // weekly

   tf_mn  = PERIOD_MN1,     // monthly

   tf_cp1 = -1,             // Next higher time frame

   tf_cp2 = -2,             // Second higher time frame

   tf_cp3 = -3              // Third higher time frame

  };

//--- input parameters

input enTimeFrames       inpTimeFrame   = tf_cu;        // Time frame

input double             inpFastLimit   = 0.5;          // Fast limit

input double             inpSlowLimit   = 0.05;         // Slow limit

input ENUM_APPLIED_PRICE inpPrice       = PRICE_MEDIAN; // Price

input bool               inpInterpolate = true;         // Interpolate in multi time frame mode?

//--- buffers

//--- indicator buffers

double valf[],valfc[],valm[],valmc[],count[];

//--- mtf handling stuff

int     _mtfHandle=INVALID_HANDLE; ENUM_TIMEFRAMES timeFrame;

#define _mtfCall iCustom(_Symbol,timeFrame,getIndicatorName(),tf_cu,inpFastLimit,inpSlowLimit,inpPrice)

//+------------------------------------------------------------------+ 

//| Custom indicator initialization function                         | 

//+------------------------------------------------------------------+ 

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,valf,INDICATOR_DATA);

   SetIndexBuffer(1,valfc,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(2,valm,INDICATOR_DATA);

   SetIndexBuffer(3,valmc,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(4,count,INDICATOR_CALCULATIONS);

   timeFrame=MathMax(timeFrameGet((int)inpTimeFrame),_Period);

   if(timeFrame!=_Period)

     {

      _mtfHandle = _mtfCall; if(_mtfHandle==INVALID_HANDLE) return(INIT_FAILED);

     }

//--- indicator short name assignment

   IndicatorSetString(INDICATOR_SHORTNAME,timeFrameToString(timeFrame)+" Mama - fama ("+(string)inpFastLimit+","+(string)inpSlowLimit+")");

//---

   return (INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator de-initialization function                      |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,const int prev_calculated,const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(Bars(_Symbol,_Period)<rates_total) return(prev_calculated);

   if(timeFrame!=_Period)

     {

      double result[];

      if(BarsCalculated(_mtfHandle)<0)                     return(prev_calculated);

      if(!timeFrameCheck((ENUM_TIMEFRAMES)timeFrame,time)) return(prev_calculated);

      if(CopyBuffer(_mtfHandle,4,0,1,result)==-1)          return(prev_calculated);



      //

      //---

      //



      #define _mtfRatio PeriodSeconds((ENUM_TIMEFRAMES)timeFrame)/PeriodSeconds(_Period)

      int k,n,i=MathMin(MathMax(prev_calculated-1,0),MathMax(rates_total-(int)result[0]*_mtfRatio-1,0)),_prevMark=0,_seconds=PeriodSeconds(timeFrame);

      for(; i<rates_total && !_StopFlag; i++)

        {

         int _currMark = int(time[i]/_seconds);

         if (_currMark!=_prevMark)

         {

            _prevMark = _currMark; 

            #define _mtfCopy(_buff,_buffNo) if(CopyBuffer(_mtfHandle,_buffNo,time[i],1,result)==-1) break; _buff[i]=result[0]

                    _mtfCopy(valf ,0);

                    _mtfCopy(valfc,1);

                    _mtfCopy(valm ,2);

                    _mtfCopy(valmc,3);

         }

         else

         {

            valf[i]  = valf[i-1];

            valm[i]  = valm[i-1];

            valfc[i] = valfc[i-1];

            valmc[i] = valmc[i-1];

         }            



         //

         //---

         //



         if (!inpInterpolate)  continue; 

            int _nextMark = (i<rates_total-1) ? int(time[i+1]/_seconds) : _prevMark+1; if (_nextMark == _prevMark) continue;

            for(n=1; (i-n)> 0 && time[i-n] >= (_prevMark)*_seconds; n++) continue;

            for(k=1; (i-k)>=0 && k<n; k++)

            {

               #define _mtfInterpolate(_buff) _buff[i-k]=_buff[i]+(_buff[i-n]-_buff[i])*k/n

                       _mtfInterpolate(valf);

                       _mtfInterpolate(valm);

            }

        }

      return(i);

     }

   //

   //---

   //

   

   int i=(int)MathMax(prev_calculated-1,0); for(; i<rates_total && !_StopFlag; i++)

     {

      double _fama;

      valm[i] = iMama(getPrice(inpPrice,open,close,high,low,i,rates_total),inpFastLimit,inpSlowLimit,_fama,i,rates_total);

      valf[i] = _fama;

      valfc[i] = (valf[i]>valm[i]) ? 1 : (valf[i]<valm[i]) ? 2 : (i>0) ? valfc[i-1] : 0;

      valmc[i] = valfc[i];

     }

   count[rates_total-1]=MathMax(rates_total-prev_calculated+1,1);

   return(i);

  }

//+------------------------------------------------------------------+

//| Custom functions                                                 |

//+------------------------------------------------------------------+

#define _mamaInstances 1

#define _mamaInstancesSize 16

double workMama[][_mamaInstances*_mamaInstancesSize];

#define _price     0

#define _smooth    1

#define _detrender 2

#define _period    3

#define _phase     4

#define _Q1        5

#define _I1        6

#define _JI        7

#define _JQ        8

#define _Q2        9

#define _I2       10

#define _Re       11

#define _Im       12

#define _sa       13

#define _mama     14

#define _fama     15

//

//---

//

double iMama(double price,double fastLimit,double slowLimit,double &retFama,int r,int bars)

  {

   if(ArrayRange(workMama,0)!=bars) ArrayResize(workMama,bars);



//

//

//

//

//



#define rad2degree (180.0/M_PI)

#define calcComp(_i,_ind) (_i>5 ?(0.0962*workMama[_i][_ind]+0.5769*workMama[_i-2][_ind]-0.5769*workMama[_i-4][_ind]-0.0962*workMama[_i-6][_ind]) *(0.075*workMama[_i-1][_period]+0.54) : workMama[_i][_ind])



   workMama[r][_price]     = price;

   workMama[r][_smooth]    = (r>3) ? (4.0*workMama[r][_price]+3.0*workMama[r-1][_price]+2.0*workMama[r-2][_price]+workMama[r-3][_price])/10.0 : price;

   workMama[r][_detrender] = calcComp(r,_smooth);

   workMama[r][_Q1]        = calcComp(r,_detrender);

   workMama[r][_I1]        = (r>2) ? workMama[r-3][_detrender] :  workMama[r][_detrender];

   workMama[r][_JI]        = calcComp(r,_I1);

   workMama[r][_JQ]        = calcComp(r,_Q1);



//

//---

//



   workMama[r][_I2] = (r==0) ? workMama[r][_I1] : 0.2*(workMama[r][_I1]-workMama[r][_JQ])                                 + 0.8*workMama[r-1][_I2];

   workMama[r][_Q2] = (r==0) ? workMama[r][_Q1] : 0.2*(workMama[r][_Q1]+workMama[r][_JI])                                 + 0.8*workMama[r-1][_Q2];

   workMama[r][_Re] = (r==0) ? workMama[r][_I2] : 0.2*(workMama[r][_I2]*workMama[r-1][_I2] + workMama[r][_Q2]*workMama[r-1][_Q2]) + 0.8*workMama[r-1][_Re];

   workMama[r][_Im] = (r==0) ? workMama[r][_I2] : 0.2*(workMama[r][_I2]*workMama[r-1][_Q2] - workMama[r][_Q2]*workMama[r-1][_I2]) + 0.8*workMama[r-1][_Im];



   if(workMama[r][_Re]!=0 && workMama[r][_Im]!=0)

      workMama[r][_period] = 360.0/(MathArctan(workMama[r][_Im]/workMama[r][_Re])*rad2degree);

   workMama[r][_period] = (r==0) ? workMama[r][_period] : MathMin(workMama[r][_period],1.50*workMama[r-1][_period]);

   workMama[r][_period] = (r==0) ? workMama[r][_period] : MathMax(workMama[r][_period],0.67*workMama[r-1][_period]);

   workMama[r][_period] = MathMin(MathMax(workMama[r][_period],6),50);

   workMama[r][_period] = (r==0) ? workMama[r][_period] : 0.2*workMama[r][_period]+0.8*workMama[r-1][_period];



//

//---

//



   if(workMama[r][_I1]!=0) workMama[r][_phase]=MathArctan(workMama[r][_Q1]/workMama[r][_I1])*rad2degree;

   double DeltaPhase = (r==0) ? 0 : MathMax(workMama[r-1][_phase]-workMama[r][_phase],1);

   double Alpha      = (DeltaPhase!=0) ? MathMax(MathMin(fastLimit/DeltaPhase,fastLimit),slowLimit) : 1;

   workMama[r][_sa]=Alpha;



//

//---

//



   workMama[r][_mama] = (r==0) ? price :     workMama[r][_sa]*workMama[r][_price] + (1.0-    workMama[r][_sa])*workMama[r-1][_mama];

   workMama[r][_fama] = (r==0) ? price : 0.5*workMama[r][_sa]*workMama[r][_mama]  + (1.0-0.5*workMama[r][_sa])*workMama[r-1][_fama]; retFama = workMama[r][_fama];

   return(workMama[r][_mama]);

  }

//

//---

//  

ENUM_TIMEFRAMES _tfsPer[]={PERIOD_M1,PERIOD_M2,PERIOD_M3,PERIOD_M4,PERIOD_M5,PERIOD_M6,PERIOD_M10,PERIOD_M12,PERIOD_M15,PERIOD_M20,PERIOD_M30,PERIOD_H1,PERIOD_H2,PERIOD_H3,PERIOD_H4,PERIOD_H6,PERIOD_H8,PERIOD_H12,PERIOD_D1,PERIOD_W1,PERIOD_MN1};

string          _tfsStr[]={"1 minute","2 minutes","3 minutes","4 minutes","5 minutes","6 minutes","10 minutes","12 minutes","15 minutes","20 minutes","30 minutes","1 hour","2 hours","3 hours","4 hours","6 hours","8 hours","12 hours","daily","weekly","monthly"};

//

//---

//

string timeFrameToString(int period)

  {

   if(period==PERIOD_CURRENT)

      period=_Period;

   int i; for(i=0;i<ArraySize(_tfsPer);i++) if(period==_tfsPer[i]) break;

   return(_tfsStr[i]);

  }

//

//---

//

ENUM_TIMEFRAMES timeFrameGet(int period)

  {

   int _shift=(period<0?MathAbs(period):0);

   if(_shift>0 || period==tf_cu) period=_Period;

   int i; for(i=0;i<ArraySize(_tfsPer);i++) if(period==_tfsPer[i]) break;



   return(_tfsPer[(int)MathMin(i+_shift,ArraySize(_tfsPer)-1)]);

  }

//

//---

//

string getIndicatorName()

  {

   string _path=MQL5InfoString(MQL5_PROGRAM_PATH);

   string _partsA[];

   ushort _partsS=StringGetCharacter("\\",0);

   int _partsN = StringSplit(_path,_partsS,_partsA);

   string name = _partsA[_partsN-1]; for(int n=_partsN-2; n>=0 && _toLower(_partsA[n])!="indicators"; n--) name = _partsA[n]+"\\"+name;

   return(name);

  }

string _toLower(string _toConvert) { StringToLower(_toConvert); return(_toConvert); }

//

//---

//

bool timeFrameCheck(ENUM_TIMEFRAMES _timeFrame,const datetime &time[])

  {

   static bool warned=false;

   if(time[0]<SeriesInfoInteger(_Symbol,_timeFrame,SERIES_FIRSTDATE))

     {

      datetime startTime,testTime[];

      if(SeriesInfoInteger(_Symbol,PERIOD_M1,SERIES_TERMINAL_FIRSTDATE,startTime))

      if(startTime>0)                       { CopyTime(_Symbol,_timeFrame,time[0],1,testTime); SeriesInfoInteger(_Symbol,_timeFrame,SERIES_FIRSTDATE,startTime); }

      if(startTime<=0 || startTime>time[0]) { Comment(MQL5InfoString(MQL5_PROGRAM_NAME)+"\nMissing data for "+timeFrameToString(_timeFrame)+" time frame\nRe-trying on next tick"); warned=true; return(false); }

     }

   if(warned) { Comment(""); warned=false; }

   return(true);

  }

//

//---

//

double getPrice(ENUM_APPLIED_PRICE tprice,const double &open[],const double &close[],const double &high[],const double &low[],int i,int _bars)

  {

   if(i>=0)

      switch(tprice)

        {

         case PRICE_CLOSE:     return(close[i]);

         case PRICE_OPEN:      return(open[i]);

         case PRICE_HIGH:      return(high[i]);

         case PRICE_LOW:       return(low[i]);

         case PRICE_MEDIAN:    return((high[i]+low[i])/2.0);

         case PRICE_TYPICAL:   return((high[i]+low[i]+close[i])/3.0);

         case PRICE_WEIGHTED:  return((high[i]+low[i]+close[i]+close[i])/4.0);

        }

   return(0);

  }

//+------------------------------------------------------------------+