Schaff trend RSI mtf

ÿþ//------------------------------------------------------------------

#property copyright   "Copyright 2017, mladen"

#property link        "mladenfx@gmail.com"

#property description "Schaff trend RSI mtf"

#property version     "1.00"

//------------------------------------------------------------------

#property indicator_separate_window

#property indicator_buffers 3

#property indicator_plots   1

#property indicator_label1  "Schaff trend RSI value"

#property indicator_type1   DRAW_COLOR_LINE

#property indicator_color1  clrSilver,clrLimeGreen,clrOrange

#property indicator_width1  2

//

//-----------------

//

enum enPrices

  {

   pr_close,      // Close

   pr_open,       // Open

   pr_high,       // High

   pr_low,        // Low

   pr_median,     // Median

   pr_typical,    // Typical

   pr_weighted,   // Weighted

   pr_average,    // Average (high+low+open+close)/4

   pr_medianb,    // Average median body (open+close)/2

   pr_tbiased,    // Trend biased price

   pr_tbiased2,   // Trend biased (extreme) price

   pr_haclose,    // Heiken ashi close

   pr_haopen ,    // Heiken ashi open

   pr_hahigh,     // Heiken ashi high

   pr_halow,      // Heiken ashi low

   pr_hamedian,   // Heiken ashi median

   pr_hatypical,  // Heiken ashi typical

   pr_haweighted, // Heiken ashi weighted

   pr_haaverage,  // Heiken ashi average

   pr_hamedianb,  // Heiken ashi median body

   pr_hatbiased,  // Heiken ashi trend biased price

   pr_hatbiased2  // Heiken ashi trend biased (extreme) price

  };

//

//---

//

enum enTimeFrames

  {

   tf_cu  = PERIOD_CURRENT, // Current time frame

   tf_m1  = PERIOD_M1,      // 1 minute

   tf_m2  = PERIOD_M2,      // 2 minutes

   tf_m3  = PERIOD_M3,      // 3 minutes

   tf_m4  = PERIOD_M4,      // 4 minutes

   tf_m5  = PERIOD_M5,      // 5 minutes

   tf_m6  = PERIOD_M6,      // 6 minutes

   tf_m10 = PERIOD_M10,     // 10 minutes

   tf_m12 = PERIOD_M12,     // 12 minutes

   tf_m15 = PERIOD_M15,     // 15 minutes

   tf_m20 = PERIOD_M20,     // 20 minutes

   tf_m30 = PERIOD_M30,     // 30 minutes

   tf_h1  = PERIOD_H1,      // 1 hour

   tf_h2  = PERIOD_H2,      // 2 hours

   tf_h3  = PERIOD_H3,      // 3 hours

   tf_h4  = PERIOD_H4,      // 4 hours

   tf_h6  = PERIOD_H6,      // 6 hours

   tf_h8  = PERIOD_H8,      // 8 hours

   tf_h12 = PERIOD_H12,     // 12 hours

   tf_d1  = PERIOD_D1,      // daily

   tf_w1  = PERIOD_W1,      // weekly

   tf_mn  = PERIOD_MN1,     // monthly

   tf_cp1 = -1,             // Next higher time frame

   tf_cp2 = -2,             // Second higher time frame

   tf_cp3 = -3              // Third higher time frame

  };

// input parameters

input enTimeFrames TimeFrame   = tf_cu;    // Time frame

input int          FastEma     = 23;       // Fast ema period

input int          SlowEma     = 50;       // Slow ema period

input double       RsiPeriod   = 9;        // Rsi period

input enPrices     Price       = pr_close; // Price

input bool         Interpolate = true;     // Interpolate in multi time frame mode?

//--- buffers

double  val[],valc[],count[];

//--- mtf handling stuff

int     _mtfHandle=INVALID_HANDLE; ENUM_TIMEFRAMES timeFrame;

#define _mtfCall iCustom(_Symbol,timeFrame,getIndicatorName(),0,FastEma,SlowEma,RsiPeriod,Price)

//+------------------------------------------------------------------+

//|                                                                  |

//+------------------------------------------------------------------+

int OnInit()

  {

   SetIndexBuffer(0,val,INDICATOR_DATA);

   SetIndexBuffer(1,valc,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(2,count,INDICATOR_CALCULATIONS);

   timeFrame=MathMax(timeFrameGet((int)TimeFrame),_Period);

   if(timeFrame!=_Period)

     {

      _mtfHandle = _mtfCall; if(_mtfHandle==INVALID_HANDLE) return(INIT_FAILED);

     }

   IndicatorSetString(INDICATOR_SHORTNAME,timeFrameToString(timeFrame)+" Schaff trend RSI ("+(string)FastEma+","+(string)SlowEma+","+(string)RsiPeriod+")");

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//|                                                                  |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(Bars(_Symbol,_Period)<rates_total) return(prev_calculated);

   if(timeFrame!=_Period)

     {

      if(BarsCalculated(_mtfHandle)<0) return(prev_calculated);



      //

      //---

      //



      double result[];

      datetime currTime[],nextTime[];

      if(!timeFrameCheck((ENUM_TIMEFRAMES)timeFrame,time)) return(prev_calculated);

      if(CopyBuffer(_mtfHandle,2,0,1,result)==-1)          return(prev_calculated);



      //

      //---

      //



      #define _mtfRatio PeriodSeconds((ENUM_TIMEFRAMES)timeFrame)/PeriodSeconds(_Period)

      int k,n,i=MathMin(MathMax(prev_calculated-1,0),MathMax(rates_total-(int)result[0]*_mtfRatio-1,0));

      for(; i<rates_total && !_StopFlag; i++)

        {

         #define _mtfCopy(_buff,_buffNo) if(CopyBuffer(_mtfHandle,_buffNo,time[i],1,result)==-1) break; _buff[i]=result[0]

            _mtfCopy(val,0);

            _mtfCopy(valc,1);



         //

         //---

         //



         if(!Interpolate) continue;  int _timeCopied = CopyTime(_Symbol,timeFrame,time[i],1,currTime); if (_timeCopied!=1) break;

         if(i<(rates_total-1)) { CopyTime(_Symbol,timeFrame,time[i+1],1,nextTime); if(currTime[0]==nextTime[0]) continue; }

         for(n=1; (i-n)> 0 && time[i-n] >= currTime[0]; n++) continue;

         for(k=1; (i-k)>=0 && k<n; k++)

           {

            #define _mtfInterpolate(_buff) _buff[i-k]=_buff[i]+(_buff[i-n]-_buff[i])*k/n

            _mtfInterpolate(val);

           }

        }

      return(i);

     }

//

//---

//

   int i=(int)MathMax(prev_calculated-1,0); for(; i<rates_total && !_StopFlag; i++)

     {

      double price=getPrice(Price,open,close,high,low,i,rates_total);

      val[i]  = iRsi(iEma(price,FastEma,i,rates_total,0)-iEma(price,SlowEma,i,rates_total,1),RsiPeriod,i,rates_total);

      valc[i] = (i>0) ? (val[i]>val[i-1]) ? 1 : (val[i]<val[i-1]) ? 2 : valc[i-1] : 0;

     }

   count[rates_total-1]=MathMax(rates_total-prev_calculated+1,1);

   return(i);

  }

//------------------------------------------------------------------

// custom functions

//------------------------------------------------------------------

#define rsiInstances 1

double workRsi[][rsiInstances*3];

#define _price  0

#define _prices 3

#define _change 1

#define _changa 2

//

//---

//

double iRsi(double price,double period,int r,int bars,int instanceNo=0)

  {

   if(ArrayRange(workRsi,0)!=bars) ArrayResize(workRsi,bars);

   int z=instanceNo*3;

//

//---

//



   workRsi[r][z+_price]=price;

   double alpha=1.0/MathMax(period,1);

   if(r<period)

     {

      int k; double sum=0; for(k=0; k<period && (r-k-1)>=0; k++) sum+=MathAbs(workRsi[r-k][z+_price]-workRsi[r-k-1][z+_price]);

      workRsi[r][z+_change] = (workRsi[r][z+_price]-workRsi[0][z+_price])/MathMax(k,1);

      workRsi[r][z+_changa] =                                         sum/MathMax(k,1);

     }

   else

     {

      double change=workRsi[r][z+_price]-workRsi[r-1][z+_price];

      workRsi[r][z+_change] = workRsi[r-1][z+_change] + alpha*(        change  - workRsi[r-1][z+_change]);

      workRsi[r][z+_changa] = workRsi[r-1][z+_changa] + alpha*(MathAbs(change) - workRsi[r-1][z+_changa]);

     }

   return(50.0*(workRsi[r][z+_change]/MathMax(workRsi[r][z+_changa],DBL_MIN)+1));

  }

//

//---

//

double workEma[][2];

//

//---

//

double iEma(double price,double period,int r,int _bars,int instanceNo=0)

  {

   if(ArrayRange(workEma,0)!=_bars) ArrayResize(workEma,_bars);



   workEma[r][instanceNo]=price;

   if(r>0 && period>1)

      workEma[r][instanceNo]=workEma[r-1][instanceNo]+(2.0/(1.0+period))*(price-workEma[r-1][instanceNo]);

   return(workEma[r][instanceNo]);

  }

//

//---

//

#define _pricesInstances 1

#define _pricesSize      4

double workHa[][_pricesInstances*_pricesSize];

//

//---

//

double getPrice(int tprice,const double &open[],const double &close[],const double &high[],const double &low[],int i,int _bars,int instanceNo=0)

  {

   if(tprice>=pr_haclose)

     {

      if(ArrayRange(workHa,0)!=_bars) ArrayResize(workHa,_bars); instanceNo*=_pricesSize;

      double haOpen  = (i>0) ? (workHa[i-1][instanceNo+2]+workHa[i-1][instanceNo+3])/2.0 : (open[i]+close[i])/2;;

      double haClose = (open[i] + high[i] + low[i] + close[i]) / 4.0;

      double haHigh  = MathMax(high[i], MathMax(haOpen,haClose));

      double haLow   = MathMin(low[i] , MathMin(haOpen,haClose));



      if(haOpen  <haClose) { workHa[i][instanceNo+0] = haLow;  workHa[i][instanceNo+1] = haHigh; }

      else                 { workHa[i][instanceNo+0] = haHigh; workHa[i][instanceNo+1] = haLow;  }

      workHa[i][instanceNo+2] = haOpen;

      workHa[i][instanceNo+3] = haClose;

      //

      //--------------------

      //

      switch(tprice)

        {

         case pr_haclose:     return(haClose);

         case pr_haopen:      return(haOpen);

         case pr_hahigh:      return(haHigh);

         case pr_halow:       return(haLow);

         case pr_hamedian:    return((haHigh+haLow)/2.0);

         case pr_hamedianb:   return((haOpen+haClose)/2.0);

         case pr_hatypical:   return((haHigh+haLow+haClose)/3.0);

         case pr_haweighted:  return((haHigh+haLow+haClose+haClose)/4.0);

         case pr_haaverage:   return((haHigh+haLow+haClose+haOpen)/4.0);

         case pr_hatbiased:

            if(haClose>haOpen)

            return((haHigh+haClose)/2.0);

            else  return((haLow+haClose)/2.0);

         case pr_hatbiased2:

            if(haClose>haOpen)  return(haHigh);

            if(haClose<haOpen)  return(haLow);

            return(haClose);

        }

     }

//

//---

//

   switch(tprice)

     {

      case pr_close:     return(close[i]);

      case pr_open:      return(open[i]);

      case pr_high:      return(high[i]);

      case pr_low:       return(low[i]);

      case pr_median:    return((high[i]+low[i])/2.0);

      case pr_medianb:   return((open[i]+close[i])/2.0);

      case pr_typical:   return((high[i]+low[i]+close[i])/3.0);

      case pr_weighted:  return((high[i]+low[i]+close[i]+close[i])/4.0);

      case pr_average:   return((high[i]+low[i]+close[i]+open[i])/4.0);

      case pr_tbiased:

         if(close[i]>open[i])

         return((high[i]+close[i])/2.0);

         else  return((low[i]+close[i])/2.0);

      case pr_tbiased2:

         if(close[i]>open[i]) return(high[i]);

         if(close[i]<open[i]) return(low[i]);

         return(close[i]);

     }

   return(0);

  }

//

//---

//  

ENUM_TIMEFRAMES _tfsPer[]={PERIOD_M1,PERIOD_M2,PERIOD_M3,PERIOD_M4,PERIOD_M5,PERIOD_M6,PERIOD_M10,PERIOD_M12,PERIOD_M15,PERIOD_M20,PERIOD_M30,PERIOD_H1,PERIOD_H2,PERIOD_H3,PERIOD_H4,PERIOD_H6,PERIOD_H8,PERIOD_H12,PERIOD_D1,PERIOD_W1,PERIOD_MN1};

string          _tfsStr[]={"1 minute","2 minutes","3 minutes","4 minutes","5 minutes","6 minutes","10 minutes","12 minutes","15 minutes","20 minutes","30 minutes","1 hour","2 hours","3 hours","4 hours","6 hours","8 hours","12 hours","daily","weekly","monthly"};

//

//---

//

string timeFrameToString(int period)

  {

   if(period==PERIOD_CURRENT)

      period=_Period;

   int i; for(i=0;i<ArraySize(_tfsPer);i++) if(period==_tfsPer[i]) break;

   return(_tfsStr[i]);

  }

//

//---

//

ENUM_TIMEFRAMES timeFrameGet(int period)

  {

   int _shift=(period<0?MathAbs(period):0);

   if(_shift>0 || period==tf_cu) period=_Period;

   int i; for(i=0;i<ArraySize(_tfsPer);i++) if(period==_tfsPer[i]) break;



   return(_tfsPer[(int)MathMin(i+_shift,ArraySize(_tfsPer)-1)]);

  }

//

//---

//

string getIndicatorName()

  {

   string _path=MQL5InfoString(MQL5_PROGRAM_PATH);

   string _partsA[];

   ushort _partsS=StringGetCharacter("\\",0);

   int _partsN = StringSplit(_path,_partsS,_partsA);

   string name = _partsA[_partsN-1]; for(int n=_partsN-2; n>=0 && _toLower(_partsA[n])!="indicators"; n--) name = _partsA[n]+"\\"+name;

   return(name);

  }

string _toLower(string _toConvert) { StringToLower(_toConvert); return(_toConvert); }

//

//---

//

bool timeFrameCheck(ENUM_TIMEFRAMES _timeFrame,const datetime &time[])

  {

   static bool warned=false;

   if(time[0]<SeriesInfoInteger(_Symbol,_timeFrame,SERIES_FIRSTDATE))

     {

      datetime startTime,testTime[];

      if(SeriesInfoInteger(_Symbol,PERIOD_M1,SERIES_TERMINAL_FIRSTDATE,startTime))

      if(startTime>0)                       { CopyTime(_Symbol,_timeFrame,time[0],1,testTime); SeriesInfoInteger(_Symbol,_timeFrame,SERIES_FIRSTDATE,startTime); }

      if(startTime<=0 || startTime>time[0]) { Comment(MQL5InfoString(MQL5_PROGRAM_NAME)+"\nMissing data for "+timeFrameToString(_timeFrame)+" time frame\nRe-trying on next tick"); warned=true; return(false); }

     }

   if(warned) { Comment(""); warned=false; }

   return(true);

  }

//+------------------------------------------------------------------+