Macd Hull

ÿþ//+------------------------------------------------------------------

#property copyright   "mladen"

#property link        "mladenfx@gmail.com"

#property link        "https://www.mql5.com"

#property description "Macd Hull"

//+------------------------------------------------------------------

#property indicator_separate_window

#property indicator_buffers 5

#property indicator_plots   3

#property indicator_label1  "Macd Hull filling"

#property indicator_type1   DRAW_FILLING

#property indicator_color1  clrLimeGreen,clrOrange

#property indicator_label2  "Macd value"

#property indicator_type2   DRAW_COLOR_LINE

#property indicator_color2  clrDarkGray,clrGreen,clrCrimson

#property indicator_width2  2

#property indicator_label3  "Macd signal"

#property indicator_type3   DRAW_LINE

#property indicator_color3  clrRed

#property indicator_width3  1

//--- input parameters

input int                inpFastPeriod   = 12;          // Fast Hull period

input int                inpSlowPeriod   = 26;          // Slow Hull period

input int                inpSignalPeriod = 9;           // Signal period

input ENUM_APPLIED_PRICE inpPrice        = PRICE_CLOSE; // Price 

//--- buffers declarations

double fillu[],filld[],val[],valc[],signal[];

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,fillu,INDICATOR_DATA);

   SetIndexBuffer(1,filld,INDICATOR_DATA);

   SetIndexBuffer(2,val,INDICATOR_DATA);

   SetIndexBuffer(3,valc,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(4,signal,INDICATOR_DATA);

   PlotIndexSetInteger(0,PLOT_SHOW_DATA,false);

//---

   IndicatorSetString(INDICATOR_SHORTNAME,"Macd Hull ("+(string)inpFastPeriod+","+(string)inpSlowPeriod+","+(string)inpSignalPeriod+")");

//---

   return (INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator de-initialization function                      |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(Bars(_Symbol,_Period)<rates_total) return(prev_calculated);



   int i=(int)MathMax(prev_calculated-1,1); for(; i<rates_total && !_StopFlag; i++)

     {

      double _price=getPrice(inpPrice,open,close,high,low,i,rates_total);

      val[i]    = iHull(_price,inpFastPeriod,i,rates_total,0)-iHull(_price,inpSlowPeriod,i,rates_total,1);

      signal[i] = iEma(val[i],inpSignalPeriod,i,rates_total,0);

      fillu[i]  = val[i];

      filld[i]  = signal[i];

      valc[i]=(val[i]>signal[i]) ? 1 :(val[i]<signal[i]) ? 2 :(i>0) ? valc[i-1]: 0;

     }

   return (i);

  }

//+------------------------------------------------------------------+

//| Custom functions                                                 |

//+------------------------------------------------------------------+

double workEma[][1];

//

double iEma(double price,double period,int r,int _bars,int instanceNo=0)

  {

   if(ArrayRange(workEma,0)!=_bars) ArrayResize(workEma,_bars);



   workEma[r][instanceNo]=price;

   if(r>0 && period>1)

      workEma[r][instanceNo]=workEma[r-1][instanceNo]+(2.0/(1.0+period))*(price-workEma[r-1][instanceNo]);

   return(workEma[r][instanceNo]);

  }

//---

double workHull[][4];

//+------------------------------------------------------------------+

//|                                                                  |

//+------------------------------------------------------------------+

double iHull(double price,double period,int r,int bars,int instanceNo=0)

  {

   if(ArrayRange(workHull,0)!=bars) ArrayResize(workHull,bars);

   instanceNo*=2; workHull[r][instanceNo]=price;

   if(period<=1) return(price);

//---

   int HmaPeriod  = (int)MathMax(period,2);

   int HalfPeriod = (int)MathFloor(HmaPeriod/2);

   int HullPeriod = (int)MathFloor(MathSqrt(HmaPeriod));

   double hma,hmw,weight;

   hmw=HalfPeriod; hma=hmw*price;

   for(int k=1; k<HalfPeriod && (r-k)>=0; k++)

     {

      weight = HalfPeriod-k;

      hmw   += weight;

      hma   += weight*workHull[r-k][instanceNo];

     }

   workHull[r][instanceNo+1]=2.0*hma/hmw;

   hmw=HmaPeriod; hma=hmw*price;

   for(int k=1; k<period && (r-k)>=0; k++)

     {

      weight = HmaPeriod-k;

      hmw   += weight;

      hma   += weight*workHull[r-k][instanceNo];

     }

   workHull[r][instanceNo+1]-=hma/hmw;

   hmw=HullPeriod; hma=hmw*workHull[r][instanceNo+1];

   for(int k=1; k<HullPeriod && (r-k)>=0; k++)

     {

      weight = HullPeriod-k;

      hmw   += weight;

      hma   += weight*workHull[r-k][1+instanceNo];

     }

   return(hma/hmw);

  }

//+------------------------------------------------------------------+

//|                                                                  |

//+------------------------------------------------------------------+

double getPrice(ENUM_APPLIED_PRICE tprice,

                const double &open[],

                const double &close[],

                const double &high[],

                const double &low[],

                int i,

                int _bars)

  {

   switch(tprice)

     {

      case PRICE_CLOSE:     return(close[i]);

      case PRICE_OPEN:      return(open[i]);

      case PRICE_HIGH:      return(high[i]);

      case PRICE_LOW:       return(low[i]);

      case PRICE_MEDIAN:    return((high[i]+low[i])/2.0);

      case PRICE_TYPICAL:   return((high[i]+low[i]+close[i])/3.0);

      case PRICE_WEIGHTED:  return((high[i]+low[i]+close[i]+close[i])/4.0);

     }

   return(0);

  }

//+------------------------------------------------------------------+