MA Levels

ÿþ//+------------------------------------------------------------------+

//|                                                    MA Levels.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                      https://www.mql5.com/en/users/barabashkakvn |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/en/users/barabashkakvn"

#property version   "1.000"

#property indicator_chart_window

#property indicator_buffers 9

#property indicator_plots   9

//--- plot Plus_4

#property indicator_label1  "Plus_4"

#property indicator_type1   DRAW_LINE

#property indicator_color1  C'245,244,232'

#property indicator_style1  STYLE_SOLID

#property indicator_width1  4

//--- plot Plus_3

#property indicator_label2  "Plus_3"

#property indicator_type2   DRAW_LINE

#property indicator_color2  C'197,13,102'

#property indicator_style2  STYLE_SOLID

#property indicator_width2  3

//--- plot Plus_2

#property indicator_label3  "Plus_2"

#property indicator_type3   DRAW_LINE

#property indicator_color3  C'240,120,16'

#property indicator_style3  STYLE_SOLID

#property indicator_width3  2

//--- plot Plus_1

#property indicator_label4  "Plus_1"

#property indicator_type4   DRAW_LINE

#property indicator_color4  C'238,198,10'

#property indicator_style4  STYLE_SOLID

#property indicator_width4  1

//--- plot MA

#property indicator_label5  "MA"

#property indicator_type5   DRAW_LINE

#property indicator_color5  clrBlue

#property indicator_style5  STYLE_SOLID

#property indicator_width5  1

//--- plot Minus_1

#property indicator_label6  "Minus_1"

#property indicator_type6   DRAW_LINE

#property indicator_color6  C'185,237,248'

#property indicator_style6  STYLE_SOLID

#property indicator_width6  1

//--- plot Minus_2

#property indicator_label7  "Minus_2"

#property indicator_type7   DRAW_LINE

#property indicator_color7  C'57,186,232'

#property indicator_style7  STYLE_SOLID

#property indicator_width7  2

//--- plot Minus_3

#property indicator_label8  "Minus_3"

#property indicator_type8   DRAW_LINE

#property indicator_color8  C'31,110,212'

#property indicator_style8  STYLE_SOLID

#property indicator_width8  3

//--- plot Minus_4

#property indicator_label9  "Minus_4"

#property indicator_type9   DRAW_LINE

#property indicator_color9  C'0,0,161'

#property indicator_style9  STYLE_SOLID

#property indicator_width9  4

//--- input parameters

input group             "MA"

input int                  Inp_MA_ma_period              = 12;             // MA: averaging period

input int                  Inp_MA_ma_shift               = 0;              // MA: horizontal shift

input ENUM_MA_METHOD       Inp_MA_ma_method              = MODE_SMA;       // MA: smoothing type

input ENUM_APPLIED_PRICE   Inp_MA_applied_price          = PRICE_CLOSE;    // MA: type of price

input group             "Levels"

input uint                 InpPlus_4                     = 400;            // Plus 4

input uint                 InpPlus_3                     = 300;            // Plus 3

input uint                 InpPlus_2                     = 200;            // Plus 2

input uint                 InpPlus_1                     = 100;            // Plus 1

input uint                 InpMinus_1                    = 100;            // Minus 1

input uint                 InpMinus_2                    = 200;            // Minus 2

input uint                 InpMinus_3                    = 300;            // Minus 3

input uint                 InpMinus_4                    = 400;            // Minus 4

//--- indicator buffers

double   Plus_4_Buffer[];

double   Plus_3_Buffer[];

double   Plus_2_Buffer[];

double   Plus_1_Buffer[];

double   MABuffer[];

double   Minus_1_Buffer[];

double   Minus_2_Buffer[];

double   Minus_3_Buffer[];

double   Minus_4_Buffer[];

//---

double   m_plus_4                   = 0.0;      // Plus 4                     -> double

double   m_plus_3                   = 0.0;      // Plus 3                     -> double

double   m_plus_2                   = 0.0;      // Plus 2                     -> double

double   m_plus_1                   = 0.0;      // Plus 1                     -> double

double   m_minus_1                  = 0.0;      // Minus 1                    -> double

double   m_minus_2                  = 0.0;      // Minus 2                    -> double

double   m_minus_3                  = 0.0;      // Minus 3                    -> double

double   m_minus_4                  = 0.0;      // Minus 4                    -> double



int      handle_iMA;                            // variable for storing the handle of the iMA indicator

int      bars_calculated   = 0;                 // we will keep the number of values in the Moving Average indicator

bool     m_init_error      = false;             // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,Plus_4_Buffer,INDICATOR_DATA);

   SetIndexBuffer(1,Plus_3_Buffer,INDICATOR_DATA);

   SetIndexBuffer(2,Plus_2_Buffer,INDICATOR_DATA);

   SetIndexBuffer(3,Plus_1_Buffer,INDICATOR_DATA);

   SetIndexBuffer(4,MABuffer,INDICATOR_DATA);

   SetIndexBuffer(5,Minus_1_Buffer,INDICATOR_DATA);

   SetIndexBuffer(6,Minus_2_Buffer,INDICATOR_DATA);

   SetIndexBuffer(7,Minus_3_Buffer,INDICATOR_DATA);

   SetIndexBuffer(8,Minus_4_Buffer,INDICATOR_DATA);

//---

   m_plus_4                   = InpPlus_4                   * Point();

   m_plus_3                   = InpPlus_3                   * Point();

   m_plus_2                   = InpPlus_2                   * Point();

   m_plus_1                   = InpPlus_1                   * Point();

   m_minus_1                  = InpMinus_1                  * Point();

   m_minus_2                  = InpMinus_2                  * Point();

   m_minus_3                  = InpMinus_3                  * Point();

   m_minus_4                  = InpMinus_4                  * Point();

//--- create handle of the indicator iMA

   handle_iMA=iMA(Symbol(),Period(),Inp_MA_ma_period,Inp_MA_ma_shift,

                  Inp_MA_ma_method,Inp_MA_applied_price);

//--- if the handle is not created

   if(handle_iMA==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iMA indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//---

   if(m_init_error)

      return(0);

   if(rates_total<=Inp_MA_ma_period+Inp_MA_ma_shift)

      return(0);

//---

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iMA);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iMA indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iMABuffer array is greater than the number of values in the iMA indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iMABuffer array with values of the Moving Average indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(MABuffer,Inp_MA_ma_shift,handle_iMA,values_to_copy))

      return(0);

//--- memorize the number of values in the Moving Average indicator

   bars_calculated=calculated;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      limit=Inp_MA_ma_period+Inp_MA_ma_shift;

      for(int i=0; i<limit; i++)

        {

         Plus_4_Buffer[i]=0.0;

         Plus_3_Buffer[i]=0.0;

         Plus_2_Buffer[i]=0.0;

         Plus_1_Buffer[i]=0.0;

         Minus_1_Buffer[i]=0.0;

         Minus_2_Buffer[i]=0.0;

         Minus_3_Buffer[i]=0.0;

         Minus_4_Buffer[i]=0.0;

        }

     }

   for(int i=limit; i<rates_total; i++)

     {

      Plus_4_Buffer[i]=MABuffer[i]+m_plus_4;

      Plus_3_Buffer[i]=MABuffer[i]+m_plus_3;

      Plus_2_Buffer[i]=MABuffer[i]+m_plus_2;

      Plus_1_Buffer[i]=MABuffer[i]+m_plus_1;

      Minus_1_Buffer[i]=MABuffer[i]-m_minus_1;

      Minus_2_Buffer[i]=MABuffer[i]-m_minus_2;

      Minus_3_Buffer[i]=MABuffer[i]-m_minus_3;

      Minus_4_Buffer[i]=MABuffer[i]-m_minus_4;

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the MA indicator                  |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],   // indicator buffer of Moving Average values

                         int shift,          // shift

                         int ind_handle,     // handle of the iMA indicator

                         int amount          // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iMABuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,-shift,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iMA indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iMA!=INVALID_HANDLE)

      IndicatorRelease(handle_iMA);

  }

//+------------------------------------------------------------------+