DeMarker LiDo Color

ÿþ//+------------------------------------------------------------------+

//|                                          DeMarker LiDo Color.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.000"

#property indicator_separate_window

#property indicator_buffers 3

#property indicator_plots   2

//--- plot RSI

#property indicator_label1  "DeM"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrDodgerBlue

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot RSI_Dot

#property indicator_label2  "DeM Dot"

#property indicator_type2   DRAW_COLOR_ARROW

#property indicator_color2  clrMistyRose,clrLime,clrDarkOrange

#property indicator_style2  STYLE_SOLID

#property indicator_width2  3

//--- input parameters

input group             "DeM"

input int                  Inp_DeM_ma_period    = 14;          // DeM: averaging period

input double               Inp_DeM_LevelUP      = 0.7;         // DeM: Level UP

input double               Inp_DeM_LevelDOWN    = 0.3;         // DeM: Level DOWN

input group             "Arrow"

input uchar                InpArrowCode         = 159;         // Arrow code "SELL"

//--- indicator buffers

double   DemBuffer[];

double   DeMDotBuffer[];

double   DeMDotColors[];

//---

int      handle_iDeMarker;             // variable for storing the handle of the DeMarker indicator

int      bars_calculated      = 0;     // we will keep the number of values in the DeMarker indicator

bool     m_init_error         = false; // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- forced initialization of variables

   m_init_error               = false;    // error on InInit

//--- indicator buffers mapping

   SetIndexBuffer(0,DemBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,DeMDotBuffer,INDICATOR_DATA);

   SetIndexBuffer(2,DeMDotColors,INDICATOR_COLOR_INDEX);

//--- set accuracy

   IndicatorSetInteger(INDICATOR_DIGITS,3);

//--- set levels

   IndicatorSetInteger(INDICATOR_LEVELS,2);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,0,Inp_DeM_LevelUP);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,1,Inp_DeM_LevelDOWN);

//--- setting a code from the Wingdings charset as the property of PLOT_ARROW

   PlotIndexSetInteger(1,PLOT_ARROW,InpArrowCode);

//--- sets first bar from what index will be drawn

   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,Inp_DeM_ma_period);

//--- name for DataWindow and indicator subwindow label

   IndicatorSetString(INDICATOR_SHORTNAME,"DeM("+IntegerToString(Inp_DeM_ma_period)+")");

//--- create handle of the indicator iDeMarker

   handle_iDeMarker=iDeMarker(Symbol(),Period(),Inp_DeM_ma_period);

//--- if the handle is not created

   if(handle_iDeMarker==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iDeMarker indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(m_init_error)

      return(0);

//---

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iDeMarker);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iRSI indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the DeMBuffer array is greater than the number of values in the DeMarker indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the array with values of the iRSI indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(DemBuffer,handle_iDeMarker,values_to_copy))

      return(0);

   if(!FillArrayFromBuffer(DeMDotBuffer,handle_iDeMarker,values_to_copy))

      return(0);

//--- memorize the number of values in the DeMarker indicator

   bars_calculated=calculated;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

      limit=0;

   for(int i=limit; i<rates_total; i++)

     {

      DeMDotColors[i]=0.0;

      if(DemBuffer[i]>=Inp_DeM_LevelUP)

         DeMDotColors[i]=1.0;

      if(DemBuffer[i]<=Inp_DeM_LevelDOWN)

         DeMDotColors[i]=2.0;

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iDeMarker indicator           |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &dem_buffer[],  // indicator buffer of DeMarker

                         int ind_handle,        // handle of the iDeMarker indicator

                         int amount             // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iDeMarkerBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,dem_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iDeMarker indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iDeMarker!=INVALID_HANDLE)

      IndicatorRelease(handle_iDeMarker);

  }

//+------------------------------------------------------------------+