MA Custom Point Label

ÿþ//+------------------------------------------------------------------+

//|                                        MA Custom Point Label.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                      https://www.mql5.com/en/users/barabashkakvn |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/en/users/barabashkakvn"

#property version   "1.000"

#property indicator_chart_window

#property indicator_buffers 1

#property indicator_plots   0

//--- input parameters

input group             "MA"

input int                  Inp_MA_ma_period        = 12;                // MA: averaging period

input int                  Inp_MA_ma_shift         = 0;                 // MA: horizontal shift

input ENUM_MA_METHOD       Inp_MA_ma_method        = MODE_SMA;          // MA: smoothing type

input ENUM_APPLIED_PRICE   Inp_MA_applied_price    = PRICE_CLOSE;       // MA: type of price

input group             "Label"

input ENUM_APPLIED_PRICE   InpLabelPrice           = PRICE_CLOSE;       // Label price

input string               InpName                 = "MA Label";        // Label name

input int                  InpX                    = 50;                // X-axis distance

input int                  InpY                    = 50;                // Y-axis distance

input ENUM_BASE_CORNER     InpCorner               = CORNER_RIGHT_LOWER;// Chart corner for anchoring

input string               InpFont                 = "Lucida Console";  // Font

input int                  InpFontSize             = 14;                // Font size

input color                InpColor                = clrOrange;         // Color

input double               InpAngle                = 0.0;               // Slope angle in degrees

input ENUM_ANCHOR_POINT    InpAnchor               = ANCHOR_RIGHT_LOWER;// Anchor type

input bool                 InpBack                 = false;             // Background object

input bool                 InpSelection            = false;             // Highlight to move

input bool                 InpHidden               = true;              // Hidden in the object list

input long                 InpZOrder               = 0;                 // Priority for mouse click

//--- indicator buffers

double   MABuffer[];

//---

string   m_price_type      = "";

string   m_ma_type         = "";

int      handle_iMA;                            // variable for storing the handle of the iMA indicator

int      bars_calculated   = 0;                 // we will keep the number of values in the Moving Average indicator

bool     m_init_error      = false;             // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,MABuffer,INDICATOR_DATA);

//--- set shift

   PlotIndexSetInteger(0,PLOT_SHIFT,Inp_MA_ma_shift);

//--- create handle of the indicator iMA

   handle_iMA=iMA(Symbol(),Period(),Inp_MA_ma_period,Inp_MA_ma_shift,

                  Inp_MA_ma_method,Inp_MA_applied_price);

//--- if the handle is not created

   if(handle_iMA==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iMA indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   string ma_applied_price="";

   switch(Inp_MA_applied_price)

     {

      case  PRICE_CLOSE:

         ma_applied_price="Close";

         break;

      case PRICE_OPEN:

         ma_applied_price="Open";

         break;

      case  PRICE_HIGH:

         ma_applied_price="High";

         break;

      case PRICE_LOW:

         ma_applied_price="Low";

         break;

      case  PRICE_MEDIAN:

         ma_applied_price="Median";

         break;

      case PRICE_TYPICAL:

         ma_applied_price="Typical";

         break;

      case  PRICE_WEIGHTED:

         ma_applied_price="Weighted";

         break;

     }

//---

   m_ma_type=IntegerToString(Inp_MA_ma_period)+","+IntegerToString(Inp_MA_ma_shift)+","+

             StringSubstr(EnumToString(Inp_MA_ma_method),5,-1)+","+ma_applied_price;

//---

   switch(InpLabelPrice)

     {

      case  PRICE_CLOSE:

         m_price_type="Close";

         break;

      case PRICE_OPEN:

         m_price_type="Open";

         break;

      case  PRICE_HIGH:

         m_price_type="High";

         break;

      case PRICE_LOW:

         m_price_type="Low";

         break;

      case  PRICE_MEDIAN:

         m_price_type="Median";

         break;

      case PRICE_TYPICAL:

         m_price_type="Typical";

         break;

      case  PRICE_WEIGHTED:

         m_price_type="Weighted";

         break;

     }

//--- create a text label on the chart

   if(!LabelCreate(0,InpName,0,InpX,InpY,InpCorner,"-//-",InpFont,InpFontSize,

                   InpColor,InpAngle,InpAnchor,InpBack,InpSelection,InpHidden,InpZOrder))

     {

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//--- create a timer with a 30 second period

   EventSetTimer(30);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(m_init_error)

      return(0);

   if(rates_total<=Inp_MA_ma_period+Inp_MA_ma_shift)

      return(0);

//---

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iMA);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iMA indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iMABuffer array is greater than the number of values in the iMA indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iMABuffer array with values of the Moving Average indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(MABuffer,Inp_MA_ma_shift,handle_iMA,values_to_copy))

      return(0);

//--- memorize the number of values in the Moving Average indicator

   bars_calculated=calculated;

//--- main loop

   double price=0.0;

   int i=rates_total-1;

   switch(InpLabelPrice)

     {

      case  PRICE_CLOSE:

         price=close[i];

         break;

      case PRICE_OPEN:

         price=open[i];

         break;

      case  PRICE_HIGH:

         price=high[i];

         break;

      case PRICE_LOW:

         price=low[i];

         break;

      case  PRICE_MEDIAN:

         price=(high[i]+low[i])/2.0;

         break;

      case PRICE_TYPICAL:

         price=(high[i]+low[i]+close[i])/3.0;

         break;

      case  PRICE_WEIGHTED:

         price=(high[i]+low[i]+close[i]+close[i])/4.0;

         break;

     }

   string text_point=DoubleToString((price-MABuffer[rates_total-1])/Point(),0);

   LabelTextChange(0,InpName,"Price "+m_price_type+" - MA("+m_ma_type+") "+text_point+" points");

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Timer function                                                   |

//+------------------------------------------------------------------+

void OnTimer()

  {

//--- create a text label on the chart

   if(ObjectFind(0,InpName)<0)

      LabelCreate(0,InpName,0,InpX,InpY,InpCorner,"-//-",InpFont,InpFontSize,

                  InpColor,InpAngle,InpAnchor,InpBack,InpSelection,InpHidden,InpZOrder);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the MA indicator                  |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],   // indicator buffer of Moving Average values

                         int shift,          // shift

                         int ind_handle,     // handle of the iMA indicator

                         int amount          // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iMABuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,-shift,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iMA indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iMA!=INVALID_HANDLE)

      IndicatorRelease(handle_iMA);

   ObjectDelete(0,InpName);

//--- destroy the timer after completing the work

   EventKillTimer();

  }

//+------------------------------------------------------------------+

//| Create a text label                                              |

//+------------------------------------------------------------------+

bool LabelCreate(const long              chart_ID=0,               // chart's ID

                 const string            name="Label",             // label name

                 const int               sub_window=0,             // subwindow index

                 const int               x=0,                      // X coordinate

                 const int               y=0,                      // Y coordinate

                 const ENUM_BASE_CORNER  corner=CORNER_LEFT_UPPER, // chart corner for anchoring

                 const string            text="Label",             // text

                 const string            font="Arial",             // font

                 const int               font_size=10,             // font size

                 const color             clr=clrRed,               // color

                 const double            angle=0.0,                // text slope

                 const ENUM_ANCHOR_POINT anchor=ANCHOR_LEFT_UPPER, // anchor type

                 const bool              back=false,               // in the background

                 const bool              selection=false,          // highlight to move

                 const bool              hidden=true,              // hidden in the object list

                 const long              z_order=0)                // priority for mouse click

  {

//--- reset the error value

   ResetLastError();

//--- create a text label

   if(!ObjectCreate(chart_ID,name,OBJ_LABEL,sub_window,0,0))

     {

      Print(__FUNCTION__,

            ": failed to create text label! Error code = ",GetLastError());

      return(false);

     }

//--- set label coordinates

   ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x);

   ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y);

//--- set the chart's corner, relative to which point coordinates are defined

   ObjectSetInteger(chart_ID,name,OBJPROP_CORNER,corner);

//--- set the text

   ObjectSetString(chart_ID,name,OBJPROP_TEXT,text);

//--- set text font

   ObjectSetString(chart_ID,name,OBJPROP_FONT,font);

//--- set font size

   ObjectSetInteger(chart_ID,name,OBJPROP_FONTSIZE,font_size);

//--- set the slope angle of the text

   ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle);

//--- set anchor type

   ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,anchor);

//--- set color

   ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);

//--- display in the foreground (false) or background (true)

   ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);

//--- enable (true) or disable (false) the mode of moving the label by mouse

   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);

   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);

//--- hide (true) or display (false) graphical object name in the object list

   ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);

//--- set the priority for receiving the event of a mouse click in the chart

   ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);

//--- successful execution

   return(true);

  }

//+------------------------------------------------------------------+

//| Change the label text                                            |

//+------------------------------------------------------------------+

bool LabelTextChange(const long   chart_ID=0,   // chart's ID

                     const string name="Label", // object name

                     const string text="Text")  // text

  {

//--- reset the error value

   ResetLastError();

//--- change object text

   if(!ObjectSetString(chart_ID,name,OBJPROP_TEXT,text))

     {

      Print(__FUNCTION__,

            ": failed to change the text! Error code = ",GetLastError());

      return(false);

     }

//--- successful execution

   return(true);

  }

//+------------------------------------------------------------------+