StdDev Custom Percentage Label

ÿþ//+------------------------------------------------------------------+

//|                               StdDev Custom Percentage Label.mq5 |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.003"

#property indicator_chart_window

#property indicator_buffers 1

#property indicator_plots   0

//--- input parameters

//--- StdDev

input int                  Inp_StdDev_ma_period    = 20;             // StdDev: averaging period

input int                  Inp_StdDev_ma_shift     = 0;              // StdDev: horizontal shift

input ENUM_MA_METHOD       Inp_StdDev_ma_method    = MODE_SMA;       // StdDev: smoothing type

input ENUM_APPLIED_PRICE   Inp_StdDev_applied_price= PRICE_CLOSE;    // StdDev: type of price

//--- Label

input string               InpName                 = "StdDev Label";    // Label name

input int                  InpX                    = 50;                // X-axis distance

input int                  InpY                    = 50;                // Y-axis distance

input ENUM_BASE_CORNER     InpCorner               = CORNER_RIGHT_LOWER;// Chart corner for anchoring

input string               InpFont                 = "Lucida Console";  // Font

input int                  InpFontSize             = 14;                // Font size

input color                InpColor                = clrOrange;         // Color

input double               InpAngle                = 0.0;               // Slope angle in degrees

input ENUM_ANCHOR_POINT    InpAnchor               = ANCHOR_RIGHT_LOWER;// Anchor type

input bool                 InpBack                 = false;             // Background object

input bool                 InpSelection            = false;             // Highlight to move

input bool                 InpHidden               = true;              // Hidden in the object list

input long                 InpZOrder               = 0;                 // Priority for mouse click

//--- indicator buffers

double   StdDevBuffer[];

//---

int      handle_iStdDev;                        // variable for storing the handle of the iStdDev indicator

int      bars_calculated=0;                     // we will keep the number of values in the Standard Deviation indicator

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,StdDevBuffer,INDICATOR_DATA);

//--- set indicator short name

   IndicatorSetString(INDICATOR_SHORTNAME,"StdDev("+IntegerToString(Inp_StdDev_ma_period)+") Custom Percentage Label");

//--- create handle of the indicator iStdDev

   handle_iStdDev=iStdDev(Symbol(),Period(),Inp_StdDev_ma_period,

                          Inp_StdDev_ma_shift,Inp_StdDev_ma_method,Inp_StdDev_applied_price);

//--- if the handle is not created

   if(handle_iStdDev==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iStdDev indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//--- create a text label on the chart

   if(!LabelCreate(0,InpName,0,InpX,InpY,InpCorner,"-//-",InpFont,InpFontSize,

                   InpColor,InpAngle,InpAnchor,InpBack,InpSelection,InpHidden,InpZOrder))

     {

      return(INIT_FAILED);

     }

//--- create a timer with a 30 second period

   EventSetTimer(30);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(rates_total<Inp_StdDev_ma_period+Inp_StdDev_ma_shift)

      return(0);

//---

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iStdDev);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iStdDev indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iStdDevBuffer array is greater than the number of values in the iStdDev indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the array with values of the Standard Deviation indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(StdDevBuffer,Inp_StdDev_ma_shift,handle_iStdDev,values_to_copy))

      return(0);

//--- memorize the number of values in the Standard Deviation indicator

   bars_calculated=calculated;

//--- main loop

   string text=DoubleToString(StdDevBuffer[rates_total-1]/close[rates_total-1]*100.0,2);

   IndicatorSetString(INDICATOR_SHORTNAME,"StdDev("+IntegerToString(Inp_StdDev_ma_period)+") Custom Percentage");

   LabelTextChange(0,InpName,"StdDev("+IntegerToString(Inp_StdDev_ma_period)+")"+" "+text+"%");

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Timer function                                                   |

//+------------------------------------------------------------------+

void OnTimer()

  {

//--- create a text label on the chart

   if(ObjectFind(0,InpName)<0)

      LabelCreate(0,InpName,0,InpX,InpY,InpCorner,"-//-",InpFont,InpFontSize,

                  InpColor,InpAngle,InpAnchor,InpBack,InpSelection,InpHidden,InpZOrder);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iStdDev indicator             |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &std_buffer[],  // indicator buffer of the Standard Deviation line

                         int std_shift,         // shift of the Standard Deviation line

                         int ind_handle,        // handle of the iStdDev indicator

                         int amount             // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iStdDevBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,-std_shift,amount,std_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iStdDev indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iStdDev!=INVALID_HANDLE)

      IndicatorRelease(handle_iStdDev);

   ObjectDelete(0,InpName);

//--- destroy the timer after completing the work

   EventKillTimer();

  }

//+------------------------------------------------------------------+

//| Create a text label                                              |

//+------------------------------------------------------------------+

bool LabelCreate(const long              chart_ID=0,               // chart's ID

                 const string            name="Label",             // label name

                 const int               sub_window=0,             // subwindow index

                 const int               x=0,                      // X coordinate

                 const int               y=0,                      // Y coordinate

                 const ENUM_BASE_CORNER  corner=CORNER_LEFT_UPPER, // chart corner for anchoring

                 const string            text="Label",             // text

                 const string            font="Arial",             // font

                 const int               font_size=10,             // font size

                 const color             clr=clrRed,               // color

                 const double            angle=0.0,                // text slope

                 const ENUM_ANCHOR_POINT anchor=ANCHOR_LEFT_UPPER, // anchor type

                 const bool              back=false,               // in the background

                 const bool              selection=false,          // highlight to move

                 const bool              hidden=true,              // hidden in the object list

                 const long              z_order=0)                // priority for mouse click

  {

//--- reset the error value

   ResetLastError();

//--- create a text label

   if(!ObjectCreate(chart_ID,name,OBJ_LABEL,sub_window,0,0))

     {

      Print(__FUNCTION__,

            ": failed to create text label! Error code = ",GetLastError());

      return(false);

     }

//--- set label coordinates

   ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x);

   ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y);

//--- set the chart's corner, relative to which point coordinates are defined

   ObjectSetInteger(chart_ID,name,OBJPROP_CORNER,corner);

//--- set the text

   ObjectSetString(chart_ID,name,OBJPROP_TEXT,text);

//--- set text font

   ObjectSetString(chart_ID,name,OBJPROP_FONT,font);

//--- set font size

   ObjectSetInteger(chart_ID,name,OBJPROP_FONTSIZE,font_size);

//--- set the slope angle of the text

   ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle);

//--- set anchor type

   ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,anchor);

//--- set color

   ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);

//--- display in the foreground (false) or background (true)

   ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);

//--- enable (true) or disable (false) the mode of moving the label by mouse

   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);

   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);

//--- hide (true) or display (false) graphical object name in the object list

   ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);

//--- set the priority for receiving the event of a mouse click in the chart

   ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);

//--- successful execution

   return(true);

  }

//+------------------------------------------------------------------+

//| Change the label text                                            |

//+------------------------------------------------------------------+

bool LabelTextChange(const long   chart_ID=0,   // chart's ID

                     const string name="Label", // object name

                     const string text="Text")  // text

  {

//--- reset the error value

   ResetLastError();

//--- change object text

   if(!ObjectSetString(chart_ID,name,OBJPROP_TEXT,text))

     {

      Print(__FUNCTION__,

            ": failed to change the text! Error code = ",GetLastError());

      return(false);

     }

//--- successful execution

   return(true);

  }

//+------------------------------------------------------------------+