MA Alert Crossing Price or Line

ÿþ//+------------------------------------------------------------------+

//|                              MA Alert Crossing Price or Line.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43161 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43161"

#property version   "1.000"

#property description "Alert when the iMA indicator crosses the price or line on bar #0"

#property description "---"

#property description "Play sound: The file must be located in terminal_directory \\Sounds or its sub-directory. Only WAV files are played"

#property description "---"

#property description "Send mail: Sends an email at the address specified in the settings window of the \"Email\" tab"

#property description "---"

#property description "Send notification: Sends push notifications to mobile terminals, whose MetaQuotes ID are specified in the \"Notifications\" tab"

#property indicator_chart_window

#property indicator_buffers 1

#property indicator_plots   1

//--- plot MA

#property indicator_label1  "MA"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrLimeGreen

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//+------------------------------------------------------------------+

//| Enum Price Or Line                                               |

//+------------------------------------------------------------------+

enum ENUM_PRICE_OR_LINE

  {

   price=0, // Price

   line=1,  // Line (Horizontal Line or Trend Line)

  };

//--- input parameters

input ENUM_PRICE_OR_LINE   InpPriceOrLine       = line;        // Price Or Line

input double               InpVolumePriceOrLine = 110.90;      // The value for "Price Or Line"

input group             "MA"

input int                  Inp_MA_ma_period     = 12;          // MA: averaging period

input int                  Inp_MA_ma_shift      = 0;           // MA: horizontal shift

input ENUM_MA_METHOD       Inp_MA_ma_method     = MODE_SMA;    // MA: smoothing type

input ENUM_APPLIED_PRICE   Inp_MA_applied_price = PRICE_CLOSE; // MA: type of price

input group             "Line"

input string               InpName              = "MAACPL";    // Line name

input group             "Alerts"

input string               InpSoundName         = "alert.wav"; // Sound Name

input uchar                InpSoundRepetitions  = 3;           // Repetitions

input uchar                InpSoundPause        = 3;           // Pause, in seconds

input bool                 InpAlert             = true;        // Alert

input bool                 InpMail              = true;        // Send mail

input bool                 InpNotification      = true;        // Send notification

//--- indicator buffers

double   MABuffer[];

//---

int      handle_iMA;                            // variable for storing the handle of the iMA indicator

int      bars_calculated=0;                     // we will keep the number of values in the MA indicators

datetime m_last_sound               = 0;        // "0" -> D'1970.01.01 00:00';

uchar    m_repetitions              = 0;        //

string   m_text                     = "";       //

datetime m_prev_bars                = 0;        // "0" -> D'1970.01.01 00:00';

bool     m_init_error               = false;    // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,MABuffer,INDICATOR_DATA);

//--- create handle of the indicator iMA

   handle_iMA=iMA(Symbol(),Period(),Inp_MA_ma_period,Inp_MA_ma_shift,

                  Inp_MA_ma_method,Inp_MA_applied_price);

//--- if the handle is not created

   if(handle_iMA==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iMA indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(m_init_error)

      return(0);

   if(rates_total<=Inp_MA_ma_period+Inp_MA_ma_shift)

      return(0);

//---

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iMA);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iMA indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iMABuffer array is greater than the number of values in the iMA indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iMABuffer array with values of the Moving Average indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(MABuffer,Inp_MA_ma_shift,handle_iMA,values_to_copy))

      return(0);

//--- memorize the number of values in the Moving Average indicator

   bars_calculated=calculated;

//--- main loop

//--- we work only at the time of the birth of new bar

   datetime time_0=time[rates_total-1];

   if(time_0!=m_prev_bars)

     {

      m_last_sound   = 0;  // "0" -> D'1970.01.01 00:00';

      m_repetitions  = 0;  //

      m_text         = "";

      m_prev_bars    = time_0;

     }

//---

   if(InpPriceOrLine==line)

     {

      if(ObjectFind(ChartID(),InpName)<0)

         return(0);

      ENUM_OBJECT obj_type=(ENUM_OBJECT)ObjectGetInteger(ChartID(),InpName,OBJPROP_TYPE);

      double obj_price=-1.0;

      if(obj_type!=OBJ_HLINE && obj_type!=OBJ_TREND)

         return(0);

      if(obj_type==OBJ_HLINE)

         obj_price=ObjectGetDouble(ChartID(),InpName,OBJPROP_PRICE);

      else

         obj_price=ObjectGetValueByTime(ChartID(),InpName,time[rates_total-1]);

      //---

      if(m_repetitions>=InpSoundRepetitions)

         return(rates_total);

      //---

      datetime time_current=TimeCurrent();

      if(time_current-m_last_sound>InpSoundPause)

        {

         int i=rates_total-1;

         if(open[i]<obj_price && close[i]>obj_price)

           {

            PlaySound(InpSoundName);

            m_text=Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" MA crossing line UP, "+TimeToString(time[i]);

            if(InpAlert)

               Alert(m_text);

            m_last_sound=time_current;

            m_repetitions++;

            //---

            if(InpMail)

              {

               SendMail(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1),m_text);

              }

            if(InpNotification)

              {

               SendNotification(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" "+m_text);

              }

           }

         else

            if(open[i]>obj_price && close[i]<obj_price)

              {

               PlaySound(InpSoundName);

               m_text=Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" MA crossing line DOWN, "+TimeToString(time[i]);

               if(InpAlert)

                  Alert(m_text);

               m_last_sound=time_current;

               m_repetitions++;

               //---

               if(InpMail)

                 {

                  SendMail(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1),m_text);

                 }

               if(InpNotification)

                 {

                  SendNotification(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" "+m_text);

                 }

              }

        }

     }

   else

     {

      if(m_repetitions>=InpSoundRepetitions)

         return(rates_total);

      //---

      datetime time_current=TimeCurrent();

      if(time_current-m_last_sound>InpSoundPause)

        {

         int i=rates_total-1;

         if(open[i]<InpVolumePriceOrLine && close[i]>InpVolumePriceOrLine)

           {

            PlaySound(InpSoundName);

            m_text=Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" MA crossing price UP, "+TimeToString(time[i]);

            if(InpAlert)

               Alert(m_text);

            m_last_sound=time_current;

            m_repetitions++;

            //---

            if(InpMail)

              {

               SendMail(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1),m_text);

              }

            if(InpNotification)

              {

               SendNotification(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" "+m_text);

              }

           }

         else

            if(open[i]>InpVolumePriceOrLine && close[i]<InpVolumePriceOrLine)

              {

               PlaySound(InpSoundName);

               m_text=Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" MA crossing price DOWN, "+TimeToString(time[i]);

               if(InpAlert)

                  Alert(m_text);

               m_last_sound=time_current;

               m_repetitions++;

               //---

               if(InpMail)

                 {

                  SendMail(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1),m_text);

                 }

               if(InpNotification)

                 {

                  SendNotification(Symbol()+","+StringSubstr(EnumToString(Period()),7,-1)+" "+m_text);

                 }

              }

        }

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the MA indicator                  |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],   // indicator buffer of Moving Average values

                         int shift,          // shift

                         int ind_handle,     // handle of the iMA indicator

                         int amount          // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iMABuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,-shift,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iMA indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iMA!=INVALID_HANDLE)

      IndicatorRelease(handle_iMA);

  }

//+------------------------------------------------------------------+