Ichimoku Tenkan Kijun Intersection

ÿþ//+------------------------------------------------------------------+

//|                           Ichimoku Tenkan Kijun Intersection.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                      https://www.mql5.com/en/users/barabashkakvn |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/en/users/barabashkakvn"

#property version   "1.000"

#property indicator_chart_window

#property indicator_buffers 4

#property indicator_plots   2

//--- plot Ichimoku_Up

#property indicator_label1  "Ichimoku Up"

#property indicator_type1   DRAW_ARROW

#property indicator_color1  clrBlue

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot Ichimoku_Dn

#property indicator_label2  "Ichimoku_Dn"

#property indicator_type2   DRAW_ARROW

#property indicator_color2  clrRed

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- input parameters

input group             "Ichimoku"

input int                  Inp_Ichimoku_tenkan_sen       = 9;     // Ichimoku: period of Tenkan-sen

input int                  Inp_Ichimoku_kijun_sen        = 26;    // Ichimoku: period of Kijun-sen

input int                  Inp_Ichimoku_senkou_span_b    = 52;    // Ichimoku: period of Senkou Span B

input group             "Arrow"

input uchar                InpCodeUpArrow                = 233;   // Arrow code for 'Ichimoku Up' (font Wingdings)

input uchar                InpCodeDnArrow                = 234;   // Arrow code for 'Ichimoku Dn' (font Wingdings)

input int                  InpShift                      = 10;    // Vertical shift of arrows in pixel

//--- indicator buffers

double   UpBuffer[];

double   DnBuffer[];

double   TenkanBuffer[];

double   KijunBuffer[];

//---

int      handle_iIchimoku;             // variable for storing the handle of the iIchimoku indicator

bool     m_init_error      = false;    // error on InInit

int      bars_calculated   = 0;        // we will keep the number of values in the Ichimoku Kinko Hyo indicator

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,UpBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,DnBuffer,INDICATOR_DATA);

   SetIndexBuffer(2,TenkanBuffer,INDICATOR_CALCULATIONS);

   SetIndexBuffer(3,KijunBuffer,INDICATOR_CALCULATIONS);

//--- setting a code from the Wingdings charset as the property of PLOT_ARROW

   PlotIndexSetInteger(0,PLOT_ARROW,InpCodeUpArrow);

   PlotIndexSetInteger(1,PLOT_ARROW,InpCodeDnArrow);

//--- set the vertical shift of arrows in pixels

   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,InpShift);

   PlotIndexSetInteger(1,PLOT_ARROW_SHIFT,-InpShift);

//--- sets drawing line empty value--

   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,EMPTY_VALUE);

   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,EMPTY_VALUE);

//--- create handle of the indicator iIchimoku

   handle_iIchimoku=iIchimoku(Symbol(),Period(),Inp_Ichimoku_tenkan_sen,

                              Inp_Ichimoku_kijun_sen,Inp_Ichimoku_senkou_span_b);

//--- if the handle is not created

   if(handle_iIchimoku==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iIchimoku indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//---

   if(m_init_error)

      return(0);

   if(rates_total<Inp_Ichimoku_kijun_sen)

      return(0);

//--- number of values copied from the iIchimoku indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iIchimoku);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iIchimoku indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the Tenkan_sen_Buffer array is greater than the number of values in the iIchimoku indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the arrays with values of the Ichimoku Kinko Hyo indicator

//--- if FillArraysFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArraysFromBuffers(TenkanBuffer,KijunBuffer,Inp_Ichimoku_kijun_sen,handle_iIchimoku,values_to_copy))

      return(0);

//--- memorize the number of values in the Ichimoku Kinko Hyo indicator

   bars_calculated=calculated;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      limit=Inp_Ichimoku_kijun_sen;

      ArrayInitialize(UpBuffer,EMPTY_VALUE);

      ArrayInitialize(DnBuffer,EMPTY_VALUE);

     }

   for(int i=limit; i<rates_total; i++)

     {

      if(TenkanBuffer[i-1]<=KijunBuffer[i-1] && TenkanBuffer[i]>KijunBuffer[i])

         UpBuffer[i]=low[i];

      else

         UpBuffer[i]=EMPTY_VALUE;

      if(TenkanBuffer[i-1]>=KijunBuffer[i-1] && TenkanBuffer[i]<KijunBuffer[i])

         DnBuffer[i]=high[i];

      else

         DnBuffer[i]=EMPTY_VALUE;

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iIchimoku indicator           |

//+------------------------------------------------------------------+

bool FillArraysFromBuffers(double &tenkan_sen_buffer[],     // indicator buffer of the Tenkan-sen line

                           double &kijun_sen_buffer[],      // indicator buffer of the Kijun_sen line

                           int senkou_span_shift,           // shift of the Senkou Span lines in the future direction

                           int ind_handle,                  // handle of the iIchimoku indicator

                           int amount                       // number of copied values

                          )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the Tenkan_sen_Buffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,tenkan_sen_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("1.Failed to copy data from the iIchimoku indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- fill a part of the Kijun_sen_Buffer array with values from the indicator buffer that has index 1

   if(CopyBuffer(ind_handle,1,0,amount,kijun_sen_buffer)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("2.Failed to copy data from the iIchimoku indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iIchimoku!=INVALID_HANDLE)

      IndicatorRelease(handle_iIchimoku);

  }

//+------------------------------------------------------------------+