Heiken Ashi MA T3 new_lines[Alert].
Download scriptThis script is a sophisticated technical analysis tool designed to smooth out market "noise" and identify clear trends in price action. It combines two advanced mathematical concepts—Heiken Ashi candles and T3 Moving Averages—to provide a cleaner, more readable visual of the market's direction.
Core Logic Breakdown
1. Data Smoothing (The T3 Foundation) Instead of using standard moving averages, which can often be jumpy or lag significantly behind the price, this script utilizes the T3 Moving Average. The T3 is known for being exceptionally smooth while remaining responsive to new price changes. The logic calculates these averages across different price points (Open, High, Low, and Close) to create a stable base for analysis.
2. Price Transformation (Heiken Ashi Logic) The script takes the smoothed data from the T3 and converts it into Heiken Ashi values. Heiken Ashi is a specialized type of price candle where each bar represents an average of previous price movements rather than just the raw high/low of the current minute or hour. This transformation helps "filter out" minor fluctuations, making it easier for a trader to see if the momentum is truly shifting or if the market is simply vibrating in place.
3. Trend Identification & Visualization The script draws two primary lines on your chart representing these smoothed averages:
- Trend Lines: These provide a continuous visual of the current trend flow.
- Visual Cues: It identifies "Bullish" and "Bearish" zones based on the relationship between the opening and closing values of the transformed data.
4. Stability and Noise Filtering A key feature of this logic is the Step Filter. This ensures that the lines on your chart don't move erratically for tiny, insignificant price changes. The script requires a specific "Step" or threshold of movement to be met before it updates the trend line. If the price movement is smaller than this threshold, the line remains steady, preventing "false starts" in the visual data.
5. Automated Alerts and Signals The script actively monitors the interaction between these moving components:
- Buy Signals: Triggered when the data indicates a crossover from a bearish trend to a bullish one (an upward turn).
- Sell Signals: Triggered when the data shows a shift from a bullish trend to a bearish one (a downward turn).
- Notifications: When these specific crossovers occur, the script can generate an immediate alert on your screen, notifying you of the potential change in market sentiment.
Summary for the User
In plain terms, this tool acts as a "lens" that clears up a blurry chart. It takes messy price data, smooths it out using high-quality mathematics (T3), translates it into a trend-focused format (Heiken Ashi), and then draws clear lines and arrows to tell you exactly when the momentum is shifting in your favor.
//+------------------------------------------------------------------+
//| Heiken Ashi Ma T3.mq4 |
//+------------------------------------------------------------------+
//| mod by Raff |
//| 2009 mod by mladen |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2008,Forex-TSD.com"
#property link "http://www.forex-tsd.com/"
#property indicator_chart_window
#property indicator_buffers 6
#property indicator_color1 Pink
#property indicator_color2 SkyBlue
#property indicator_color3 Pink
#property indicator_color4 SkyBlue
#property indicator_color5 Lime
#property indicator_color6 Orange
#property indicator_width1 1
#property indicator_width2 1
#property indicator_width3 2
#property indicator_width4 2
#property indicator_width5 1
#property indicator_width6 1
//
//
//
//
//
extern int MaPeriod = 5;
extern int MaMetod = 1;
extern int Step = 10;
extern bool BetterFormula = false;
extern bool T3Average = true;
extern double T3Hot = 0.618;
extern bool T3Original = false;
extern bool Alerts = true;
//
//
//
//
//
double ExtMapBuffer1[];
double ExtMapBuffer2[];
double ExtMapBuffer3[];
double ExtMapBuffer4[];
double UpArrow[];
double DnArrow[];
//
//
//
//
//
double emas[][24];
double alpha;
double c1;
double c2;
double c3;
double c4;
static bool TurnedUp = false;
static bool TurnedDown = false;
datetime timeprev = 0;
//+------------------------------------------------------------------+
//| |
//|------------------------------------------------------------------|
//
//
//
//
//
int init()
{
SetIndexBuffer(0, ExtMapBuffer1); SetIndexStyle(0,DRAW_NONE);
SetIndexBuffer(1, ExtMapBuffer2); SetIndexStyle(1,DRAW_NONE);
SetIndexBuffer(2, ExtMapBuffer3); SetIndexStyle(2,DRAW_LINE, 2, 0, Pink);
SetIndexBuffer(3, ExtMapBuffer4); SetIndexStyle(3,DRAW_LINE, 2, 0, SkyBlue);
SetIndexBuffer(4, UpArrow); SetIndexStyle(4,DRAW_ARROW); SetIndexArrow(4,241);
SetIndexBuffer(5, DnArrow); SetIndexStyle(5,DRAW_ARROW); SetIndexArrow(5,242);
//
//
//
//
//
double a = T3Hot;
c1 = -a*a*a;
c2 = 3*(a*a+a*a*a);
c3 = -3*(2*a*a+a+a*a*a);
c4 = 1+3*a+a*a*a+3*a*a;
MaPeriod = MathMax(1,MaPeriod);
if (T3Original)
alpha = 2.0/(1.0 + MaPeriod);
else alpha = 2.0/(2.0 + (MaPeriod-1.0)/2.0);
return(0);
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
//
//
//
//
//
int start()
{
double maOpen, maClose, maLow, maHigh;
double haOpen, haClose, haLow, haHigh;
int counted_bars=IndicatorCounted();
int pointModifier;
int i,limit;
//
//
//
//
//
if(timeprev<iTime(NULL,0,0)) {TurnedDown=false; TurnedUp=false;timeprev=iTime(NULL,0,0);}
if(counted_bars<0) return(-1);
if(counted_bars>0) counted_bars--;
limit = Bars-counted_bars;
if (ArrayRange(emas,0) != Bars) ArrayResize(emas,Bars);
if (Digits==3 || Digits==5)
pointModifier = 10;
else pointModifier = 1;
//
//
//
//
//
for(int pos=limit; pos >= 0; pos--)
{
if (T3Average)
{
maOpen = iT3(Open[pos] ,pos, 0);
maClose = iT3(Close[pos],pos, 6);
maLow = iT3(Low[pos] ,pos,12);
maHigh = iT3(High[pos] ,pos,18);
}
else
{
maOpen = iMA(NULL,0,MaPeriod,0,MaMetod,PRICE_OPEN ,pos);
maClose = iMA(NULL,0,MaPeriod,0,MaMetod,PRICE_CLOSE,pos);
maLow = iMA(NULL,0,MaPeriod,0,MaMetod,PRICE_LOW ,pos);
maHigh = iMA(NULL,0,MaPeriod,0,MaMetod,PRICE_HIGH ,pos);
}
//
//
//
//
//
if (BetterFormula) {
if (maHigh!=maLow)
haClose = (maOpen+maClose)/2+(((maClose-maOpen)/(maHigh-maLow))*MathAbs((maClose-maOpen)/2));
else haClose = (maOpen+maClose)/2; }
else haClose = (maOpen+maHigh+maLow+maClose)/4;
haOpen = (ExtMapBuffer3[pos+1]+ExtMapBuffer4[pos+1])/2;
haHigh = MathMax(maHigh, MathMax(haOpen,haClose));
haLow = MathMin(maLow, MathMin(haOpen,haClose));
if (haOpen<haClose) { ExtMapBuffer1[pos]=haLow; ExtMapBuffer2[pos]=haHigh; }
else { ExtMapBuffer1[pos]=haHigh; ExtMapBuffer2[pos]=haLow; }
ExtMapBuffer3[pos]=haOpen;
ExtMapBuffer4[pos]=haClose;
//
//
//
//
//
if (Step>0)
{
if( MathAbs(ExtMapBuffer1[pos]-ExtMapBuffer1[pos+1]) < Step*pointModifier*Point ) ExtMapBuffer1[pos]=ExtMapBuffer1[pos+1];
if( MathAbs(ExtMapBuffer2[pos]-ExtMapBuffer2[pos+1]) < Step*pointModifier*Point ) ExtMapBuffer2[pos]=ExtMapBuffer2[pos+1];
if( MathAbs(ExtMapBuffer3[pos]-ExtMapBuffer3[pos+1]) < Step*pointModifier*Point ) ExtMapBuffer3[pos]=ExtMapBuffer3[pos+1];
if( MathAbs(ExtMapBuffer4[pos]-ExtMapBuffer4[pos+1]) < Step*pointModifier*Point ) ExtMapBuffer4[pos]=ExtMapBuffer4[pos+1];
if (Alerts==true)
{
UpArrow[pos]=EMPTY_VALUE; DnArrow[pos]=EMPTY_VALUE;
if (ExtMapBuffer3[pos]<ExtMapBuffer4[pos] && ExtMapBuffer4[pos+1]<ExtMapBuffer3[pos+1])
{
UpArrow[pos]=ExtMapBuffer4[pos+1]-(Ask-Bid);
if (UpArrow[0]!=EMPTY_VALUE && TurnedUp==false)
{
Alert("HAMa BUY: ",Symbol()," - ",Period()," at ", Close[0]," - ", TimeToStr(CurTime(),TIME_SECONDS));
TurnedDown=false;
TurnedUp=true;
}
}
if (ExtMapBuffer3[pos]>ExtMapBuffer4[pos] && ExtMapBuffer4[pos+1]>ExtMapBuffer3[pos+1])
{
DnArrow[pos]=ExtMapBuffer4[pos+1]+(Ask-Bid);
if (DnArrow[0]!=EMPTY_VALUE && TurnedDown==false)
{
Alert("HAMa SELL: ",Symbol()," - ",Period()," at ", Close[0]," - ", TimeToStr(CurTime(),TIME_SECONDS));
TurnedUp=false;
TurnedDown=true;
}
}
}
}
}
return(0);
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
//
//
//
//
//
double iT3(double price,int shift,int buffer)
{
int i = Bars-shift-1;
if (i < 1)
{
emas[i][0+buffer] = price;
emas[i][1+buffer] = price;
emas[i][2+buffer] = price;
emas[i][3+buffer] = price;
emas[i][4+buffer] = price;
emas[i][5+buffer] = price;
}
else
{
emas[i][0+buffer] = emas[i-1][0+buffer]+alpha*(price -emas[i-1][0+buffer]);
emas[i][1+buffer] = emas[i-1][1+buffer]+alpha*(emas[i][0+buffer]-emas[i-1][1+buffer]);
emas[i][2+buffer] = emas[i-1][2+buffer]+alpha*(emas[i][1+buffer]-emas[i-1][2+buffer]);
emas[i][3+buffer] = emas[i-1][3+buffer]+alpha*(emas[i][2+buffer]-emas[i-1][3+buffer]);
emas[i][4+buffer] = emas[i-1][4+buffer]+alpha*(emas[i][3+buffer]-emas[i-1][4+buffer]);
emas[i][5+buffer] = emas[i-1][5+buffer]+alpha*(emas[i][4+buffer]-emas[i-1][5+buffer]);
}
return(c1*emas[i][5+buffer] + c2*emas[i][4+buffer] + c3*emas[i][3+buffer] + c4*emas[i][2+buffer]);
}
Comments