gbpusd_m1

//+-------------------------------------------------------------------------+
//|                                                                 SSB.mq4 |
//|                Copyright © 2009, Yury V. Reshetov  http://ssb.bigfx.ru/ |
//|                                                    http://ssb.bigfx.ru/ |
//+-------------------------------------------------------------------------+
#property copyright "Copyright © 2009, Yury V. Reshetov http://ssb.bigfx.ru"
#property link      "http://ssb.bigfx.ru"

/*
This program is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation, either version 3 of the License, or
any later version.

This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
GNU General Public License for more details.

You should have received a copy of the GNU General Public License
along with this program.  If not, see http://www.gnu.org/licenses/.
*/

extern double lots = 1;
extern int prsi = 86;
extern int fastmacd = 11;
extern int slowmacd = 53;
extern int signalmacd = 26;
extern int stochD = 23;
extern int stochK = 40;
extern int stochS = 82;
extern int magic = 888;
extern int slippage = 0;
static int prevtime = 0;

int init() {
   prevtime = Time[0];
   return(0);
}

int start() {

   if (! IsTradeAllowed()) {
      return(0);
   }

   if (Time[0] == prevtime) {
      return(0);
   }
   prevtime = Time[0];

   int ticket = -1;
   int total = OrdersTotal();
   for (int i = total - 1; i >= 0; i--) {
      OrderSelect(i, SELECT_BY_POS, MODE_TRADES);
      if ((OrderSymbol() == Symbol()) && (OrderMagicNumber() == magic)) {
         int prevticket = OrderTicket();
         if (OrderType() == OP_BUY) {
            if (shortsignal()) {
               ticket = OrderSend(Symbol(), OP_SELL, 2.0 * lots, Bid, slippage, 0, 0, WindowExpertName(), magic, 0, Red);
               Sleep(30000);
               if (ticket < 0) {
                  prevtime = Time[1];
                  return(0);
               } else {
                  OrderCloseBy(ticket, prevticket, Red);
               }
            }
          } else {
            if (longsignal()) {
               ticket = OrderSend(Symbol(), OP_BUY, 2.0 * lots, Ask, slippage, 0, 0, WindowExpertName(), magic, 0, Blue);
               Sleep(30000);
               if (ticket < 0) {
                  prevtime = Time[1];
                  return(0);
               } else {
                  OrderCloseBy(ticket, prevticket, Blue);
               }
            }
          }
          return(0);
      }
   }

   if (longsignal()) {
      ticket = OrderSend(Symbol(), OP_BUY, lots, Ask, slippage, 0, 0, WindowExpertName(), magic, 0, Blue);
      Sleep(30000);
      if (ticket < 0) {
         prevtime = Time[1];
      }
      return(0);
   }
   if (shortsignal()) {
      ticket = OrderSend(Symbol(), OP_SELL, lots, Bid, slippage, 0, 0, WindowExpertName(), magic, 0, Red);
      Sleep(30000);
      if (ticket < 0) {
         prevtime = Time[1];
      }
      return(0);
   }
   return(0);
}

bool longsignal() {
   if (fcandle() < 0) {
      return(false);
   }
   if (frsi() < 0) {
      return(false);
   }
   if (fao() < 0) {
      return(false);
   }
   if (fmacd1() < 0) {
      return(false);
   }
   if (fosma() < 0) {
      return(false);
   }
   if (fosma1() < 0) {
      return(false);
   }
   if (fstoch2() < 0) {
      return(false);
   }
   return(true);
}

bool shortsignal() {
   if (fcandle() > 0) {
      return(false);
   }
   if (frsi() > 0) {
      return(false);
   }
   if (fao() > 0) {
      return(false);
   }
   if (fmacd1() > 0) {
      return(false);
   }
   if (fosma() > 0) {
      return(false);
   }
   if (fosma1() > 0) {
      return(false);
   }
   if (fstoch2() > 0) {
      return(false);
   }
   return(true);
}
int fcandle() {
   int result = 0;
   if (Open[0] > Open[1]) {
      result = 1;
   }
   if (Open[0] < Open[1]) {
      result = -1;
   }
   return(result);
}
int frsi() {
   int result = 0;
   double ind = iRSI(Symbol(), 0, prsi, PRICE_OPEN, 0) - 50.0;
   if (ind < 0) {
      result = 1;
   }
   if (ind > 0) {
      result = -1;
   }
   return(result);
}



int fao() {
   int result = 0;
   double ind = iAO(Symbol(), 0, 0);
   if (ind < 0) {
      result = 1;
   }
   if (ind > 0) {
      result = -1;
   }
   return(result);
}


int fmacd1() {
   int result = 0;
   double ind = iMACD(Symbol(), 0, fastmacd, slowmacd, signalmacd, PRICE_OPEN, MODE_MAIN, 0);
   double ind1 = iMACD(Symbol(), 0, fastmacd, slowmacd, signalmacd, PRICE_OPEN, MODE_MAIN, 1);
   if ((ind - ind1) < 0) {
      result = 1;
   }
   if ((ind - ind1) > 0) {
      result = -1;
   }
   return(result);
}
int fosma() {
   int result = 0;
   double ind = iOsMA(Symbol(), 0, fastmacd, slowmacd, signalmacd, PRICE_OPEN, 0);
   if (ind < 0) {
      result = 1;
   }
   if (ind > 0) {
      result = -1;
   }
   return(result);
}

int fosma1() {
   int result = 0;
   double ind = iOsMA(Symbol(), 0, fastmacd, slowmacd, signalmacd, PRICE_OPEN, 0);
   double ind1 = iOsMA(Symbol(), 0, fastmacd, slowmacd, signalmacd, PRICE_OPEN, 1);
   if ((ind - ind1) > 0) {
      result = 1;
   }
   if ((ind - ind1) < 0) {
      result = -1;
   }
   return(result);
}











int fstoch2() {
   int result = 0;
   double ind = iStochastic(Symbol(), 0, stochK, stochD, stochS, MODE_SMMA, 0,MODE_SIGNAL, 0) - 50.0;
   if (ind < 0) {
      result = 1;
   }
   if (ind > 0) {
      result = -1;
   }
   return(result);
}