CCIOnMA Histogram

ÿþ//+------------------------------------------------------------------+

//|                                            CCIOnMA Histogram.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43161 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43161"

#property version   "1.000"

#property indicator_separate_window

#property indicator_buffers 1

#property indicator_plots   1

//--- plot CCIOnMA

#property indicator_label1  "CCIOnMA"

#property indicator_type1   DRAW_HISTOGRAM

#property indicator_color1  clrSpringGreen

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- input parameters

input group             "MA"

input int                  Inp_MA_ma_period     = 12;             // MA: averaging period

input ENUM_MA_METHOD       Inp_MA_ma_method     = MODE_SMA;       // MA: smoothing type

input ENUM_APPLIED_PRICE   Inp_MA_applied_price = PRICE_CLOSE;    // MA: type of price

input group             "iCCI"

input int                  Inp_CCI_ma_period    = 14;             // CCI: averaging period

input ENUM_APPLIED_PRICE   Inp_CCI_applied_price= PRICE_TYPICAL;  // CCI: type of price

//--- indicator buffers

double   CCIBuffer[];

//---

int      handle_iCCI;                           // variable for storing the handle of the iCCI indicator

int      handle_iMA;                            // variable for storing the handle of the iMA indicator

int      bars_calculated            = 0;        // we will keep the number of values in the Commodity Channel Index indicator

bool     m_init_error               = false;    // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,CCIBuffer,INDICATOR_DATA);

//--- indicator name

   string MA_ma_method;

   switch(Inp_MA_ma_method)

     {

      case MODE_EMA:

         MA_ma_method="EMA";

         break;

      case MODE_LWMA:

         MA_ma_method="LWMA";

         break;

      case MODE_SMA:

         MA_ma_method="SMA";

         break;

      case MODE_SMMA:

         MA_ma_method="SMMA";

         break;

      default :

         MA_ma_method="unknown ma method";

     }

   string MA_applied_price;

   switch(Inp_MA_applied_price)

     {

      case PRICE_CLOSE:

         MA_applied_price="Close";

         break;

      case PRICE_OPEN:

         MA_applied_price="Open";

         break;

      case PRICE_HIGH:

         MA_applied_price="High";

         break;

      case PRICE_LOW:

         MA_applied_price="Low";

         break;

      case PRICE_MEDIAN:

         MA_applied_price="Median";

         break;

      case PRICE_TYPICAL:

         MA_applied_price="Typical";

         break;

      case PRICE_WEIGHTED:

         MA_applied_price="Weighted";

         break;

      default:

         MA_applied_price="unknown ma price";

     }

   string CCI_applied_price;

   switch(Inp_CCI_applied_price)

     {

      case PRICE_CLOSE:

         CCI_applied_price="Close";

         break;

      case PRICE_OPEN:

         CCI_applied_price="Open";

         break;

      case PRICE_HIGH:

         CCI_applied_price="High";

         break;

      case PRICE_LOW:

         CCI_applied_price="Low";

         break;

      case PRICE_MEDIAN:

         CCI_applied_price="Median";

         break;

      case PRICE_TYPICAL:

         CCI_applied_price="Typical";

         break;

      case PRICE_WEIGHTED:

         CCI_applied_price="Weighted";

         break;

      default:

         CCI_applied_price="unknown cci price";

     }

   string short_name=StringFormat("CCI(%d,%s)OnMA(%d,%s,%s)",Inp_CCI_ma_period,CCI_applied_price,Inp_MA_ma_period,MA_ma_method,MA_applied_price);

   IndicatorSetString(INDICATOR_SHORTNAME,short_name);

//--- create handle of the indicator iMA

   handle_iMA=iMA(Symbol(),Period(),Inp_MA_ma_period,0,

                  Inp_MA_ma_method,Inp_MA_applied_price);

//--- if the handle is not created

   if(handle_iMA==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iMA indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//--- create handle of the indicator iCCI

   handle_iCCI=iCCI(Symbol(),Period(),Inp_CCI_ma_period,handle_iMA);

//--- if the handle is not created

   if(handle_iCCI==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iCCI indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(m_init_error)

      return(0);

//---

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iCCI);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated('handle_iCCI') returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iCCI indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iCCIBuffer array is greater than the number of values in the iCCI indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iCCIBuffer array with values of the Commodity Channel Index indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(CCIBuffer,handle_iCCI,values_to_copy))

      return(0);

//--- memorize the number of values in the Commodity Channel Index indicator

   bars_calculated=calculated;

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iCCI indicator                |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],  // indicator buffer of Commodity Channel Index values

                         int ind_handle,    // handle of the iCCI indicator

                         int amount         // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iCCIBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iCCI indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iCCI!=INVALID_HANDLE)

      IndicatorRelease(handle_iCCI);

  }

//+------------------------------------------------------------------+