Bulls Smoothed MA

ÿþ//+------------------------------------------------------------------+

//|                                            Bulls Smoothed MA.mq5 |

//|                              Copyright © 2022, Vladimir Karputov |

//|                      https://www.mql5.com/en/users/barabashkakvn |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2022, Vladimir Karputov"

#property link      "https://www.mql5.com/en/users/barabashkakvn"

#property version   "1.001"

#property indicator_separate_window

#property indicator_buffers 2

#property indicator_plots   2

//--- plot RSI

#property indicator_label1  "Bulls"

#property indicator_type1   DRAW_HISTOGRAM

#property indicator_color1  clrSilver

#property indicator_style1  STYLE_SOLID

#property indicator_width1  2

//--- plot RSIOnMA

#property indicator_label2  "Bulls Smoothed"

#property indicator_type2   DRAW_LINE

#property indicator_color2  clrViolet

#property indicator_style2  STYLE_SOLID

#property indicator_width2  2

//--- input parameters

input group             "Bulls Power"

input int                  Inp_Bulls_ma_period           = 13;             // Bulls Power: averaging period

input group             "MA"

input int                  Inp_MA_ma_period              = 3;              // MA: averaging period

input ENUM_MA_METHOD       Inp_MA_ma_method              = MODE_SMA;       // MA: smoothing type

input ENUM_APPLIED_PRICE   Inp_MA_applied_price          = PRICE_CLOSE;    // MA: type of price

//--- indicator buffers

double   BullsBuffer[];

double   MAOnBullsBuffer[];

//---

int      handle_iMA;                            // variable for storing the handle of the iMA indicator

int      handle_iBullsPower;                    // variable for storing the handle of the iBullsPower indicator



int      bars_calculated      = 0;              // we will keep the number of values in indicators

bool     m_init_error         = false;          // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,BullsBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,MAOnBullsBuffer,INDICATOR_DATA);

//--- name for DataWindow and indicator subwindow label

   string text_method="";

   switch(Inp_MA_ma_method)

     {

      case  MODE_SMA:

         text_method="SMA";

         break;

      case  MODE_EMA:

         text_method="EMA";

         break;

      case  MODE_SMMA:

         text_method="SMMA";

         break;

      default: // MODE_LWMA

         text_method="LWMA";

         break;

     }

   string text_price="";

   switch(Inp_MA_applied_price)

     {

      case  PRICE_CLOSE:

         text_price="Close";

         break;

      case PRICE_OPEN:

         text_price="Open";

         break;

      case  PRICE_HIGH:

         text_price="High";

         break;

      case PRICE_LOW:

         text_price="Low";

         break;

      case  PRICE_MEDIAN:

         text_price="Median";

         break;

      case PRICE_TYPICAL:

         text_price="Typical";

         break;

      case  PRICE_WEIGHTED:

         text_price="Weighted";

         break;

     }

   IndicatorSetString(INDICATOR_SHORTNAME,"Bulls("+IntegerToString(Inp_Bulls_ma_period)+")"+

                      " Smoothed("+IntegerToString(Inp_MA_ma_period)+","+text_method+","+text_price+")");

//--- create handle of the indicator iBullsPower

   handle_iBullsPower=iBullsPower(Symbol(),Period(),Inp_Bulls_ma_period);

//--- if the handle is not created

   if(handle_iBullsPower==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iBullsPower indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//--- create handle of the indicator iMA

   handle_iMA=iMA(Symbol(),Period(),Inp_MA_ma_period,0,

                  Inp_MA_ma_method,handle_iBullsPower);

//--- if the handle is not created

   if(handle_iMA==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iMA indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(m_init_error)

      return(0);

//--- number of values copied from the iRSI indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iMA);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iRSI indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iRSIBuffer array is greater than the number of values in the iRSI indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iBullsPowerBuffer array with values of the Bulls Power indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(BullsBuffer,handle_iBullsPower,values_to_copy))

      return(0);

//--- fill the iMABuffer array with values of the Moving Average indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(MAOnBullsBuffer,0,handle_iMA,values_to_copy))

      return(0);

//--- memorize the number of values in the Relative Strength Index indicator

   bars_calculated=calculated;

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iBullsPower indicator         |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],  // indicator buffer for Bulls Power values

                         int ind_handle,    // handle of the iBullsPower indicator

                         int amount         // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iBullsPowerBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iBullsPower indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the MA indicator                  |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],   // indicator buffer of Moving Average values

                         int shift,          // shift

                         int ind_handle,     // handle of the iMA indicator

                         int amount          // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iMABuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,-shift,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iMA indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iMA!=INVALID_HANDLE)

      IndicatorRelease(handle_iMA);

   if(handle_iBullsPower!=INVALID_HANDLE)

      IndicatorRelease(handle_iBullsPower);

  }

//+------------------------------------------------------------------+