Bollinger_Bandwidth_Delta

ÿþ//+------------------------------------------------------------------+

//|                                    Bollinger_Bandwidth_Delta.mq5 |

//|                        Copyright 2018, MetaQuotes Software Corp. |

//|                                                 https://mql5.com |

//+------------------------------------------------------------------+

#property copyright "Copyright 2018, MetaQuotes Software Corp."

#property link      "https://mql5.com"

#property version   "1.00"

#property description "Bollinger Bandwidth Delta oscillator"

#property indicator_separate_window

#property indicator_buffers 5

#property indicator_plots   1

//--- plot BBD

#property indicator_label1  "BBD"

#property indicator_type1   DRAW_COLOR_HISTOGRAM

#property indicator_color1  clrGreen,clrRed,clrDarkGray

#property indicator_style1  STYLE_SOLID

#property indicator_width1  2

//--- enums

enum ENUM_INPUT_YES_NO

  {

   INPUT_YES   =  1, // Yes

   INPUT_NO    =  0  // No

  };

//--- input parameters

input uint                 InpPeriodBB       =  20;            // BB period

input double               InpDeviation      =  2.0;           // BB deviation

input uint                 InpPeriodDelta    =  20;            // Delta period

input ENUM_APPLIED_PRICE   InpAppliedPrice   =  PRICE_CLOSE;   // Applied price

input ENUM_INPUT_YES_NO    InpPercent        =  INPUT_NO;      // Show data in percentage

//--- indicator buffers

double         BufferBBD[];

double         BufferColors[];

double         BufferWidth[];

double         BufferMA[];

double         BufferDev[];

//--- global variables

double         deviation;

int            period_bb;

int            delta;

int            handle_ma;

int            handle_dev;

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- set global variables

   period_bb=int(InpPeriodBB<1 ? 1 : InpPeriodBB);

   delta=int(InpPeriodDelta<1 ? 1 : InpPeriodDelta);

   deviation=InpDeviation;

//--- indicator buffers mapping

   SetIndexBuffer(0,BufferBBD,INDICATOR_DATA);

   SetIndexBuffer(1,BufferColors,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(2,BufferWidth,INDICATOR_CALCULATIONS);

   SetIndexBuffer(3,BufferMA,INDICATOR_CALCULATIONS);

   SetIndexBuffer(4,BufferDev,INDICATOR_CALCULATIONS);

//--- setting indicator parameters

   IndicatorSetString(INDICATOR_SHORTNAME,"BB width delta ("+(string)period_bb+","+DoubleToString(deviation,2)+(string)delta+")");

   IndicatorSetInteger(INDICATOR_DIGITS,Digits());

//--- setting plot buffer parameters

   PlotIndexSetInteger(2,PLOT_SHOW_DATA,false);

//--- setting buffer arrays as timeseries

   ArraySetAsSeries(BufferBBD,true);

   ArraySetAsSeries(BufferColors,true);

   ArraySetAsSeries(BufferWidth,true);

   ArraySetAsSeries(BufferMA,true);

   ArraySetAsSeries(BufferDev,true);

//--- create handles

   ResetLastError();

   handle_ma=iMA(NULL,PERIOD_CURRENT,period_bb,0,MODE_SMA,InpAppliedPrice);

   if(handle_ma==INVALID_HANDLE)

     {

      Print("The iMA(",(string)period_bb,") object was not created: Error ",GetLastError());

      return INIT_FAILED;

     }

   handle_dev=iStdDev(NULL,PERIOD_CURRENT,period_bb,0,MODE_SMA,InpAppliedPrice);

   if(handle_dev==INVALID_HANDLE)

     {

      Print("The iStdDev(",(string)period_bb,") object was not created: Error ",GetLastError());

      return INIT_FAILED;

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- @>25@:0 8 @0AGQB :>;8G5AB20 ?@>AG8BK205<KE 10@>2

   if(rates_total<fmax(delta,4) || Point()==0) return 0;

//--- @>25@:0 8 @0AGQB :>;8G5AB20 ?@>AG8BK205<KE 10@>2

   int limit=rates_total-prev_calculated;

   if(limit>1)

     {

      limit=rates_total-delta-2;

      ArrayInitialize(BufferBBD,EMPTY_VALUE);

      ArrayInitialize(BufferColors,2);

      ArrayInitialize(BufferWidth,0);

      ArrayInitialize(BufferMA,0);

      ArrayInitialize(BufferDev,0);

     }

//--- >43>B>2:0 40==KE

   int count=(limit>1 ? rates_total : 1),copied=0;

   copied=CopyBuffer(handle_ma,0,0,count,BufferMA);

   if(copied!=count) return 0;

   copied=CopyBuffer(handle_dev,0,0,count,BufferDev);

   if(copied!=count) return 0;



//---  0AGQB 8=48:0B>@0

   for(int i=limit; i>=0 && !IsStopped(); i--)

     {

      if(BufferMA[i]!=0)

        {

         BufferWidth[i]=2*deviation*BufferDev[i]/BufferMA[i];

         if(InpPercent)

            BufferBBD[i]=(BufferWidth[i+delta-1]!=0 ? BufferBBD[i]=100.0*(BufferWidth[i]-BufferWidth[i+delta-1])/BufferWidth[i+delta-1] : 0);

         else

            BufferBBD[i]=(BufferWidth[i]-BufferWidth[i+delta-1])/Point();

        }

      else

         BufferBBD[i]=0;

      BufferColors[i]=(BufferBBD[i]>BufferBBD[i+1] ? 0 : BufferBBD[i]<BufferBBD[i+1] ? 1 : 2);

     }



//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+