AO Saucer

ÿþ//+------------------------------------------------------------------+

//|                                                    AO Saucer.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                      https://www.mql5.com/en/users/barabashkakvn |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/en/users/barabashkakvn"

#property version   "1.000"

#property indicator_chart_window

#property indicator_buffers 4

#property indicator_plots   2

//--- bars minimum for calculation

#define DATA_LIMIT 33

//--- plot Buy Saucer

#property indicator_label1  "Buy Saucer"

#property indicator_type1   DRAW_ARROW

#property indicator_color1  clrBlue

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot Sell Saucer

#property indicator_label2  "Sell Saucer"

#property indicator_type2   DRAW_ARROW

#property indicator_color2  clrRed

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- input parameters

input group    "Buy Saucer"

input uchar       InpBuySaucerCode     = 174;   // Buy Saucer: Arrow code (font Wingdings)

input int         InpBuySaucerShift    = 10;    // Buy Saucer: Vertical shift of arrows in pixel

input group    "Sell Saucer"

input uchar       InpSellSaucerCode    = 174;   // Sell Saucer: Arrow code (font Wingdings)

input int         InpSellSaucerShift   = -10;   // Sell Saucer: Vertical shift of arrows in pixel

//--- indicator buffers

double   BuySaucerBuffer[];

double   SellSaucerBuffer[];

double   AOBuffer[];

double   AOColors[];

//---

int      handle_iAO;                // variable for storing the handle of the iAO indicator

int      bars_calculated   = 0;     // we will keep the number of values in the Awesome Oscillator indicator

bool     m_init_error      = false; // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,BuySaucerBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,SellSaucerBuffer,INDICATOR_DATA);

   SetIndexBuffer(2,AOBuffer,INDICATOR_CALCULATIONS);

   SetIndexBuffer(3,AOColors,INDICATOR_CALCULATIONS);

//--- setting a code from the Wingdings charset as the property of PLOT_ARROW

   PlotIndexSetInteger(0,PLOT_ARROW,InpBuySaucerCode);

   PlotIndexSetInteger(1,PLOT_ARROW,InpSellSaucerCode);;

//--- set the vertical shift of arrows in pixels

   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,InpBuySaucerShift);

   PlotIndexSetInteger(1,PLOT_ARROW_SHIFT,InpSellSaucerShift);

//--- set as an empty value 0.0

   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,EMPTY_VALUE);

   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,EMPTY_VALUE);

//--- create handle of the indicator iAO

   handle_iAO=iAO(Symbol(),Period());

//--- if the handle is not created

   if(handle_iAO==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iAO indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- check for rates total

   if(rates_total<=DATA_LIMIT)

      return(0);// not enough bars for calculation

   if(m_init_error)

      return(0);

//--- number of values copied from the iAO indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iAO);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iAO indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iAOBuffer array is greater than the number of values in the iAO indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iAOBuffer and iAOColors arrays with values from the Awesome Oscillator indicator

//--- if FillArraysFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArraysFromBuffer(AOBuffer,AOColors,handle_iAO,values_to_copy))

      return(0);

//--- memorize the number of values in the Awesome Oscillator indicator

   bars_calculated=calculated;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      limit=DATA_LIMIT;

      for(int i=0; i<limit; i++)

        {

         BuySaucerBuffer[i]=EMPTY_VALUE;

         SellSaucerBuffer[i]=EMPTY_VALUE;

        }

     }

   for(int i=rates_total-1; i>=limit; i--)

     {

      BuySaucerBuffer[i]=EMPTY_VALUE;

      SellSaucerBuffer[i]=EMPTY_VALUE;

      //--- Buy Saucer

      if(AOBuffer[i-1]>0.0 && AOBuffer[i-2]>0.0 && AOBuffer[i-3]>0.0)

         if(AOBuffer[i-1]>AOBuffer[i-2] && AOBuffer[i-2]<AOBuffer[i-3])

           {

            BuySaucerBuffer[i]=low[i];

            continue;

           }

      //--- Sell Saucer

      if(AOBuffer[i-1]<0.0 && AOBuffer[i-2]<0.0 && AOBuffer[i-3]<0.0)

         if(AOBuffer[i-1]<AOBuffer[i-2] && AOBuffer[i-2]>AOBuffer[i-3])

           {

            SellSaucerBuffer[i]=high[i];

            continue;

           }

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iAO indicator                 |

//+------------------------------------------------------------------+

bool FillArraysFromBuffer(double &values[],        // indicator buffer of Awesome Oscillator values

                          double &color_indexes[], // color buffer (for storing of color indexes)

                          int ind_handle,          // handle of the iAO indicator

                          int amount               // number of copied values

                         )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iAOBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iAO indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- now copy the indexes of colors

   if(CopyBuffer(ind_handle,1,0,amount,color_indexes)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy color values from the iAO indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iAO!=INVALID_HANDLE)

      IndicatorRelease(handle_iAO);

////--- clear the chart after deleting the indicator

//   Comment("");

  }

//+------------------------------------------------------------------+