WeightOscillator_Alert

ÿþ//+---------------------------------------------------------------------+

//|                                          WeightOscillator_Alert.mq5 | 

//|                                  Copyright © 2016, Nikolay Kositsin | 

//|                                 Khabarovsk,   farria@mail.redcom.ru | 

//+---------------------------------------------------------------------+ 

//| ;O @01>BK  8=48:0B>@0  A;54C5B  ?>;>68BL D09; SmoothAlgorithms.mqh |

//| 2 ?0?:C (48@5:B>@8N): :0B0;>3_40==KE_B5@<8=0;0\\MQL5\Include        |

//+---------------------------------------------------------------------+

#property copyright "Copyright © 2016, Nikolay Kositsin"

#property link "farria@mail.redcom.ru"

#property description  "AF8;;OB>@, ?@54AB02;ONI89 2725H5==CN A3;065==CN AC<<C G5BK@QE 8=48:0B>@>2 - RSI, MFI, WPR 8 DeMarker."

//---- =><5@ 25@A88 8=48:0B>@0

#property version   "1.00"

//---- >B@8A>2:0 8=48:0B>@0 2 >B45;L=>< >:=5

#property indicator_separate_window 

//---- :>;8G5AB2> 8=48:0B>@=KE 1CD5@>2 3

#property indicator_buffers 3 

//---- 8A?>;L7>20=> >4=> 3@0D8G5A:>5 ?>AB@>5=85

#property indicator_plots   1

//+----------------------------------------------------+

//|  0@0<5B@K >B@8A>2:8 8=48:0B>@0                    |

//+----------------------------------------------------+

//---- >B@8A>2:0 8=48:0B>@0 2 2845 38AB>3@0<<K

#property indicator_type1   DRAW_COLOR_HISTOGRAM2

//---- 2 :0G5AB25 F25B>2 8=48:0B>@0 8A?>;L7>20=K

#property indicator_color1  clrDodgerBlue,clrPaleTurquoise,clrGray,clrGold,clrOrange

//---- ;8=8O 8=48:0B>@0 - A?;>H=0O

#property indicator_style1 STYLE_SOLID

//---- B>;I8=0 ;8=88 8=48:0B>@0 @02=0 2

#property indicator_width1 2

//---- >B>1@065=85 <5B:8 8=48:0B>@0

#property indicator_label1  "WeightOscillator_Alert"

//+----------------------------------------------------+

//| 0@0<5B@K >B>1@065=8O 3>@87>=B0;L=KE C@>2=59       |

//+----------------------------------------------------+

#property indicator_level1  0

#property indicator_levelcolor clrRed

#property indicator_levelstyle STYLE_SOLID

//+----------------------------------------------------+

//|  >1JO2;5=85 :>=AB0=B                               |

//+----------------------------------------------------+

#define RESET  0 // >=AB0=B0 4;O 2>72@0B0 B5@<8=0;C :><0=4K =0 ?5@5AGQB 8=48:0B>@0

//+----------------------------------------------------+

//|  ?8A0=85 :;0AA0 CXMA                              |

//+----------------------------------------------------+

#include <SmoothAlgorithms.mqh> 

//+----------------------------------------------------+



//---- >1JO2;5=85 ?5@5<5==KE :;0AA0 CXMA 87 D09;0 SmoothAlgorithms.mqh

CXMA XMA1;

//+----------------------------------------------------+

//|  >1JO2;5=85 ?5@5G8A;5=89                           |

//+----------------------------------------------------+

/*enum Smooth_Method - ?5@5G8A;5=85 >1JO2;5=> 2 D09;5 SmoothAlgorithms.mqh

  {

   MODE_SMA_,  //SMA

   MODE_EMA_,  //EMA

   MODE_SMMA_, //SMMA

   MODE_LWMA_, //LWMA

   MODE_JJMA,  //JJMA

   MODE_JurX,  //JurX

   MODE_ParMA, //ParMA

   MODE_T3,    //T3

   MODE_VIDYA, //VIDYA

   MODE_AMA,   //AMA

  }; */

//+----------------------------------------------------+

//| ?5@5G8A;5=85 4;O 20@80=B>2 B@0=A;8@C5<KE A83=0;>2  |

//+----------------------------------------------------+

enum ENUM_SIGNAL_MODE

  {

   MODE_SIGNAL,  //!83=0;K ?@>1>O

   MODE_TREND    //!83=0;K ?@>1>O 8 B@5=40

  };

//+----------------------------------------------------+

//|  %+  " + "                       |

//+----------------------------------------------------+

//---- 0@0<5B@K RSI

input double RSIWeight=1.0;

input uint   RSIPeriod=14;

input ENUM_APPLIED_PRICE   RSIPrice=PRICE_CLOSE;

//---- 0@0<5B@K MFI

input double MFIWeight=1.0;

input uint   MFIPeriod=14;

input ENUM_APPLIED_VOLUME MFIVolumeType=VOLUME_TICK;

//---- 0@0<5B@K WPR

input double WPRWeight=1.0;

input uint   WPRPeriod=14;

//---- 0@0<5B@K DeMarker

input double DeMarkerWeight=1.0;

input uint   DeMarkerPeriod=14;

//---- :;NG5=85 A3;06820=8O 2>;=K

input Smooth_Method bMA_Method=MODE_JJMA; //<5B>4 CA@54=5=8O

input uint bLength=5; //3;C18=0 A3;06820=8O                    

input int bPhase=100; //?0@0<5B@ A3;06820=8O,

//---- 4;O JJMA 87<5=ONI89AO 2 ?@545;0E -100 ... +100, 2;8O5B =0 :0G5AB2> ?5@5E>4=>3> ?@>F5AA0;

//---- ;O VIDIA MB> ?5@8>4 CMO, 4;O AMA MB> ?5@8>4 <54;5==>9 A:>;L7OI59

input uint HighLevel=70;         // C@>25=L ?5@570:C?0

input uint LowLevel=30;          // C@>25=L ?5@5?@>40==>AB8

//---- E>4=K5 ?5@5<5==K5 4;O 0;5@B>2

input ENUM_SIGNAL_MODE SignMode=MODE_SIGNAL; //0@80=B ?>40G8 A83=0;0 

input uint NumberofBar=1;                    //><5@ 10@0 4;O ?>40G8 A83=0;0

input bool SoundON=true;                     // 07@5H5=85 0;5@B0

input uint NumberofAlerts=2;                 //>;8G5AB2> 0;5@B>2

input bool EMailON=false;                    // 07@5H5=85 ?>GB>2>9 >B?@02:8 A83=0;0

input bool PushON=false;                     // 07@5H5=85 >B?@02:8 A83=0;0 =0 <>18;L=K9

//+----------------------------------------------------+

//---- >1JO2;5=85 48=0<8G5A:8E <0AA82>2, :>B>@K5 1C4CB 2 40;L=59H5< 8A?>;L7>20=K 2 :0G5AB25 8=48:0B>@=KE 1CD5@>2

double UpBuffer[],DnBuffer[],ColorBuffer[];

//---- 1JO2;5=85 F5;KE ?5@5<5==KE =0G0;0 >BAGQB0 40==KE

int min_rates_total,min_rates_total_1;

//---- 1JO2;5=85 ?5@5<5==>9 4;O AC<<0@=>3> 25A>2>3> :>MDD8F85=B0

double SumWeight;

//---- 1JO2;5=85 F5;KE ?5@5<5==KE 4;O E5=4;>2 8=48:0B>@>2

int RSI_Handle,MFI_Handle,WPR_Handle,DeMarker_Handle;

//+------------------------------------------------------------------+   

//| Custom indicator initialization function                         | 

//+------------------------------------------------------------------+ 

int OnInit()

  {

//---- @>25@:0 7=0G5=8O C@>2=O ?5@5:C?;5==>AB8 :>@@5:B=>ABL

   if(HighLevel<50)

     {

      Print(" =0G5=85 C@>2=O ?5@5:C?;5==>AB8 4>;6=> 1KBL =5 <5=LH5 50");

      return(INIT_FAILED);

     }

//---- @>25@:0 7=0G5=8O C@>2=O ?5@5?@>40==>AB8 =0 :>@@5:B=>ABL

   if(LowLevel>50)

     {

      Print(" =0G5=85 C@>2=O ?5@5?@>40==>AB8 4>;6=> 1KBL =5 1>;LH5 50");

      return(INIT_FAILED);

     }



//---- =8F80;870F8O ?5@5<5==KE =0G0;0 >BAGQB0 40==KE

   min_rates_total_1=int(MathMax(RSIPeriod,MathMax(MFIPeriod,MathMax(WPRPeriod,DeMarkerPeriod))))+1;

   min_rates_total=min_rates_total_1+GetStartBars(bMA_Method,bLength,bPhase);

   SumWeight=RSIWeight+MFIWeight+WPRWeight+DeMarkerWeight;



//---- CAB0=>2:0 0;5@B>2 =0 =54>?CAB8<K5 7=0G5=8O 2=5H=8E ?5@5<5==KE

   XMA1.XMALengthCheck("bLength",bLength);

   XMA1.XMAPhaseCheck("bPhase",bPhase,bMA_Method);



//---- ?>;CG5=85 E5=4;0 8=48:0B>@0 iRSI

   RSI_Handle=iRSI(NULL,0,RSIPeriod,RSIPrice);

   if(RSI_Handle==INVALID_HANDLE)

     {

      Print(" 5 C40;>AL ?>;CG8BL E5=4; 8=48:0B>@0 iRSI");

      return(INIT_FAILED);

     }

//---- ?>;CG5=85 E5=4;0 8=48:0B>@0 iMFI

   MFI_Handle=iMFI(NULL,0,MFIPeriod,MFIVolumeType);

   if(MFI_Handle==INVALID_HANDLE)

     {

      Print(" 5 C40;>AL ?>;CG8BL E5=4; 8=48:0B>@0 iMFI");

      return(INIT_FAILED);

     }

//---- ?>;CG5=85 E5=4;0 8=48:0B>@0 iWPR

   WPR_Handle=iWPR(NULL,0,WPRPeriod);

   if(WPR_Handle==INVALID_HANDLE)

     {

      Print(" 5 C40;>AL ?>;CG8BL E5=4; 8=48:0B>@0 iWPR");

      return(INIT_FAILED);

     }

//---- ?>;CG5=85 E5=4;0 8=48:0B>@0 iDeMarker

   DeMarker_Handle=iDeMarker(NULL,0,DeMarkerPeriod);

   if(DeMarker_Handle==INVALID_HANDLE)

     {

      Print(" 5 C40;>AL ?>;CG8BL E5=4; 8=48:0B>@0 iDeMarker");

      return(INIT_FAILED);

     }

//---- ?@52@0I5=85 48=0<8G5A:>3> <0AA820 2 8=48:0B>@=K9 1CD5@

   SetIndexBuffer(0,UpBuffer,INDICATOR_DATA);

//---- >ACI5AB2;5=85 A42830 =0G0;0 >BAGQB0 >B@8A>2:8 8=48:0B>@0

   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);

//---- CAB0=>2:0 7=0G5=89 8=48:0B>@0, :>B>@K5 =5 1C4CB 2848<K =0 3@0D8:5

   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,EMPTY_VALUE);

//---- 8=45:A0F8O M;5<5=B>2 2 1CD5@5 :0: 2 B09<A5@88

//---- 70?@5B =0 >B>1@065=85 7=0G5=89 8=48:0B>@0 2 ;52>< 25@E=5< C3;C >:=0 8=48:0B>@0

   PlotIndexSetInteger(0,PLOT_SHOW_DATA,false);

   ArraySetAsSeries(UpBuffer,true);



//---- ?@52@0I5=85 48=0<8G5A:>3> <0AA820 2 8=48:0B>@=K9 1CD5@

   SetIndexBuffer(1,DnBuffer,INDICATOR_DATA);

//---- 8=45:A0F8O M;5<5=B>2 2 1CD5@5 :0: 2 B09<A5@88

   ArraySetAsSeries(DnBuffer,true);

//---- ?@52@0I5=85 48=0<8G5A:>3> <0AA820 2 F25B>2>9, 8=45:A=K9 1CD5@   

   SetIndexBuffer(2,ColorBuffer,INDICATOR_COLOR_INDEX);

//---- 8=45:A0F8O M;5<5=B>2 2 1CD5@5 :0: 2 B09<A5@88

   ArraySetAsSeries(ColorBuffer,true);



//---- 8=8F80;870F88 ?5@5<5==>9 4;O :>@>B:>3> 8<5=8 8=48:0B>@0

   string shortname;

   string Smooth1=XMA1.GetString_MA_Method(bMA_Method);

   StringConcatenate(shortname,"WeightOscillator_Alert(",bLength,", ",Smooth1,")");

//--- A>740=85 8<5=8 4;O >B>1@065=8O 2 >B45;L=>< ?>4>:=5 8 2> 2A?;K20NI59 ?>4A:07:5

   IndicatorSetString(INDICATOR_SHORTNAME,shortname);



//--- >?@545;5=85 B>G=>AB8 >B>1@065=8O 7=0G5=89 8=48:0B>@0

   IndicatorSetInteger(INDICATOR_DIGITS,0);

//---- :>;8G5AB2>  3>@87>=B0;L=KE C@>2=59 8=48:0B>@0 3   

   IndicatorSetInteger(INDICATOR_LEVELS,3);

//---- 7=0G5=8O 3>@87>=B0;L=KE C@>2=59 8=48:0B>@0   

   IndicatorSetDouble(INDICATOR_LEVELVALUE,0,HighLevel);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,1,50);

   IndicatorSetDouble(INDICATOR_LEVELVALUE,2,LowLevel);

//---- 2 :0G5AB25 F25B>2 ;8=89 3>@87>=B0;L=KE C@>2=59 8A?>;L7>20=K 

   IndicatorSetInteger(INDICATOR_LEVELCOLOR,0,clrLimeGreen);

   IndicatorSetInteger(INDICATOR_LEVELCOLOR,1,clrGray);

   IndicatorSetInteger(INDICATOR_LEVELCOLOR,2,clrRed);

//---- 2 ;8=88 3>@87>=B0;L=>3> C@>2=O 8A?>;L7>20= :>@>B:89 HB@8E-?C=:B8@  

   IndicatorSetInteger(INDICATOR_LEVELSTYLE,0,STYLE_DASHDOTDOT);

   IndicatorSetInteger(INDICATOR_LEVELSTYLE,1,STYLE_DASHDOTDOT);

   IndicatorSetInteger(INDICATOR_LEVELSTYLE,2,STYLE_DASHDOTDOT);

//---- 7025@H5=85 8=8F80;870F88

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+ 

//| Custom indicator iteration function                              | 

//+------------------------------------------------------------------+ 

int OnCalculate(

                const int rates_total,    // :>;8G5AB2> 8AB>@88 2 10@0E =0 B5:CI5< B8:5

                const int prev_calculated,// :>;8G5AB2> 8AB>@88 2 10@0E =0 ?@54K4CI5< B8:5

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[]

                )

  {

//---- ?@>25@:0 :>;8G5AB20 10@>2 =0 4>AB0B>G=>ABL 4;O @0AGQB0

   if(BarsCalculated(RSI_Handle)<rates_total

      || BarsCalculated(MFI_Handle)<rates_total

      || BarsCalculated(WPR_Handle)<rates_total

      || BarsCalculated(DeMarker_Handle)<rates_total

      || rates_total<min_rates_total) return(RESET);



//---- >1JO2;5=8O ;>:0;L=KE ?5@5<5==KE 

   int to_copy,limit,bar,maxbar;

   double RSI[],MFI[],WPR[],DeMarker[],WeightOscillator;



//---- @0AGQBK =5>1E>48<>3> :>;8G5AB20 :>?8@C5<KE 40==KE 8

//AB0@B>2>3> =><5@0 limit 4;O F8:;0 ?5@5AGQB0 10@>2

   if(prev_calculated>rates_total || prev_calculated<=0)// ?@>25@:0 =0 ?5@2K9 AB0@B @0AGQB0 8=48:0B>@0

     {

      limit=rates_total-1; // AB0@B>2K9 =><5@ 4;O @0AGQB0 2A5E 10@>2

     }

   else

     {

      limit=rates_total-prev_calculated; // AB0@B>2K9 =><5@ 4;O @0AGQB0 =>2KE 10@>2

     }

   to_copy=limit+1;



//---- :>?8@C5< 2=>2L ?>O282H85AO 40==K5 2 <0AA82K

   if(CopyBuffer(RSI_Handle,0,0,to_copy,RSI)<=0) return(RESET);

   if(CopyBuffer(MFI_Handle,0,0,to_copy,MFI)<=0) return(RESET);

   if(CopyBuffer(WPR_Handle,0,0,to_copy,WPR)<=0) return(RESET);

   if(CopyBuffer(DeMarker_Handle,0,0,to_copy,DeMarker)<=0) return(RESET);



//---- 8=45:A0F8O M;5<5=B>2 2 <0AA820E :0: 2 B09<A5@8OE  

   ArraySetAsSeries(RSI,true);

   ArraySetAsSeries(MFI,true);

   ArraySetAsSeries(WPR,true);

   ArraySetAsSeries(DeMarker,true);

//----   

   maxbar=rates_total-min_rates_total_1-1;



//---- >A=>2=>9 F8:; @0AGQB0 8=48:0B>@0

   for(bar=limit; bar>=0 && !IsStopped(); bar--)

     {

      WeightOscillator=(RSIWeight*RSI[bar]+MFIWeight*MFI[bar]+WPRWeight*(WPR[bar]+100)+DeMarkerWeight*100*DeMarker[bar])/SumWeight;

      UpBuffer[bar]=XMA1.XMASeries(maxbar,prev_calculated,rates_total,bMA_Method,bPhase,bLength,WeightOscillator,bar,true);

      DnBuffer[bar]=50.0;

      int clr=2.0;

      if(UpBuffer[bar]>HighLevel) clr=0.0;

      else if(UpBuffer[bar]>50) clr=1.0;

      else if(UpBuffer[bar]<LowLevel) clr=4.0;

      else if(UpBuffer[bar]<50) clr=3.0;

      ColorBuffer[bar]=clr;

     }

//---     

   BuySignal("WeightOscillator_Alert",ColorBuffer,0,rates_total,prev_calculated,close,spread);

   SellSignal("WeightOscillator_Alert",ColorBuffer,4,rates_total,prev_calculated,close,spread);

//---      

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Buy signal function                                              |

//+------------------------------------------------------------------+

void BuySignal(string SignalSirname,// B5:AB 8<5=8 8=48:0B>@0 4;O ?>GB>2KE 8 ?CH-A83=0;>2

               double &ColorArray[],// F25B>2>9 8=45:A=K9 1CD5@

               int ColorIndex,// 8=45:A F25B0 2 F25B>2>< 8=45A:=>< 1CD5@5 4;O ?>40G8 A83=0;0 

               const int Rates_total,     // B5:CI55 :>;8G5AB2> 10@>2

               const int Prev_calculated, // :>;8G5AB2> 10@>2 =0 ?@54K4CI5< B8:5

               const double &Close[],     // F5=0 70:@KB8O

               const int &Spread[])       // A?@54

  {

//---

   static uint counter=0;

   if(Rates_total!=Prev_calculated) counter=0;



   bool BuySignal=false;

   bool SeriesTest=ArrayGetAsSeries(ColorArray);

   int index,index1;

   if(SeriesTest)

     {

      index=int(NumberofBar);

      index1=index+1;

     }

   else

     {

      index=Rates_total-int(NumberofBar)-1;

      index1=index-1;

     }

   if(SignMode==MODE_SIGNAL)

     {

      if(ColorArray[index1]!=ColorIndex && ColorArray[index]==ColorIndex) BuySignal=true;

     }

   else

     {

      if(ColorArray[index]==ColorIndex) BuySignal=true;

     }

   if(BuySignal && counter<=NumberofAlerts)

     {

      counter++;

      MqlDateTime tm;

      TimeToStruct(TimeCurrent(),tm);

      string text=TimeToString(TimeCurrent(),TIME_DATE)+" "+string(tm.hour)+":"+string(tm.min);

      SeriesTest=ArrayGetAsSeries(Close);

      if(SeriesTest) index=int(NumberofBar);

      else index=Rates_total-int(NumberofBar)-1;

      double Ask=Close[index];

      double Bid=Close[index];

      SeriesTest=ArrayGetAsSeries(Spread);

      if(SeriesTest) index=int(NumberofBar);

      else index=Rates_total-int(NumberofBar)-1;

      Bid+=_Point*Spread[index];

      string sAsk=DoubleToString(Ask,_Digits);

      string sBid=DoubleToString(Bid,_Digits);

      string sPeriod=GetStringTimeframe(ChartPeriod());

      if(SignMode==MODE_SIGNAL || (SignMode==MODE_TREND && ColorArray[index1]!=ColorIndex))

        {

         if(SoundON) Alert("BUY signal \n Ask=",Ask,"\n Bid=",Bid,"\n currtime=",text,"\n Symbol=",Symbol()," Period=",sPeriod);

         if(EMailON) SendMail(SignalSirname+": BUY signal alert","BUY signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);

         if(PushON) SendNotification(SignalSirname+": BUY signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);

        }

      else

        {

         if(SoundON) Alert("Up Trend signal \n Ask=",Ask,"\n Bid=",Bid,"\n currtime=",text,"\n Symbol=",Symbol()," Period=",sPeriod);

         if(EMailON) SendMail(SignalSirname+": Up Trend signal alert","BUY signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);

         if(PushON) SendNotification(SignalSirname+": Up Trend signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);

        }

     }



//---

  }

//+------------------------------------------------------------------+

//| Sell signal function                                             |

//+------------------------------------------------------------------+

void SellSignal(string SignalSirname,// B5:AB 8<5=8 8=48:0B>@0 4;O ?>GB>2KE 8 ?CH-A83=0;>2

                double &ColorArray[],       // F25B>2>9 8=45:A=K9 1CD5@

                int ColorIndex,             // 8=45:A F25B0 2 F25B>2>< 8=45A:=>< 1CD5@5 4;O ?>40G8 A83=0;0 

                const int Rates_total,     // B5:CI55 :>;8G5AB2> 10@>2

                const int Prev_calculated, // :>;8G5AB2> 10@>2 =0 ?@54K4CI5< B8:5

                const double &Close[],     // F5=0 70:@KB8O

                const int &Spread[])       // A?@54

  {

//---

   static uint counter=0;

   if(Rates_total!=Prev_calculated) counter=0;



   bool SellSignal=false;

   bool SeriesTest=ArrayGetAsSeries(ColorArray);

   int index,index1;

   if(SeriesTest)

     {

      index=int(NumberofBar);

      index1=index+1;

     }

   else

     {

      index=Rates_total-int(NumberofBar)-1;

      index1=index-1;

     }



   if(SignMode==MODE_SIGNAL)

     {

      if(ColorArray[index1]!=ColorIndex && ColorArray[index]==ColorIndex) SellSignal=true;

     }

   else

     {

      if(ColorArray[index]==ColorIndex) SellSignal=true;

     }

   if(SellSignal && counter<=NumberofAlerts)

     {

      counter++;

      MqlDateTime tm;

      TimeToStruct(TimeCurrent(),tm);

      string text=TimeToString(TimeCurrent(),TIME_DATE)+" "+string(tm.hour)+":"+string(tm.min);

      SeriesTest=ArrayGetAsSeries(Close);

      if(SeriesTest) index=int(NumberofBar);

      else index=Rates_total-int(NumberofBar)-1;

      double Ask=Close[index];

      double Bid=Close[index];

      SeriesTest=ArrayGetAsSeries(Spread);

      if(SeriesTest) index=int(NumberofBar);

      else index=Rates_total-int(NumberofBar)-1;

      Bid+=_Point*Spread[index];

      string sAsk=DoubleToString(Ask,_Digits);

      string sBid=DoubleToString(Bid,_Digits);

      string sPeriod=GetStringTimeframe(ChartPeriod());

      if(SignMode==MODE_SIGNAL || (SignMode==MODE_TREND && ColorArray[index1]!=ColorIndex))

        {

         if(SoundON) Alert("SELL signal \n Ask=",Ask,"\n Bid=",Bid,"\n currtime=",text,"\n Symbol=",Symbol()," Period=",sPeriod);

         if(EMailON) SendMail(SignalSirname+": SELL signal alert","SELL signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);

         if(PushON) SendNotification(SignalSirname+": SELL signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);

        }

      else

        {

         if(SoundON) Alert("Down trend signal \n Ask=",Ask,"\n Bid=",Bid,"\n currtime=",text,"\n Symbol=",Symbol()," Period=",sPeriod);

         if(EMailON) SendMail(SignalSirname+": Down trend signal alert","SELL signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);

         if(PushON) SendNotification(SignalSirname+": Down trend signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);

        }

     }

//---

  }

//+------------------------------------------------------------------+

//|  >;CG5=85 B09<D@59<0 2 2845 AB@>:8                              |

//+------------------------------------------------------------------+

string GetStringTimeframe(ENUM_TIMEFRAMES timeframe)

  {

//----

   return(StringSubstr(EnumToString(timeframe),7,-1));

//----

  }

//+------------------------------------------------------------------+

//|  RightPrice creation                                             |

//+------------------------------------------------------------------+

void CreateRightPrice(long chart_id,// chart ID

                      string   name,              // object name

                      int      nwin,              // window index

                      datetime time,              // price level time

                      double   price,             // price level

                      color    Color              // Text color

                      )

//---- 

  {

//----

   ObjectCreate(chart_id,name,OBJ_ARROW_RIGHT_PRICE,nwin,time,price);

   ObjectSetInteger(chart_id,name,OBJPROP_COLOR,Color);

   ObjectSetInteger(chart_id,name,OBJPROP_BACK,true);

   ObjectSetInteger(chart_id,name,OBJPROP_WIDTH,2);

//----

  }

//+------------------------------------------------------------------+

//|  RightPrice reinstallation                                       |

//+------------------------------------------------------------------+

void SetRightPrice(long chart_id,// chart ID

                   string   name,              // object name

                   int      nwin,              // window index

                   datetime time,              // price level time

                   double   price,             // price level

                   color    Color              // Text color

                   )

//---- 

  {

//----

   if(ObjectFind(chart_id,name)==-1) CreateRightPrice(chart_id,name,nwin,time,price,Color);

   else ObjectMove(chart_id,name,0,time,price);

//----

  }

//+------------------------------------------------------------------+